Refactor QR scanner camera controller to subclass a QR scanner camera controller.

Aim: Remove the QR Scanner Specific methods out of the camera controller so that a similar subclass of the generic camera controller super class can be implemented for the credit card scanner.

Architecture:
Superclass - cameraController
Subclasses - qrScannerCameraController

Methods shifted:

1. - (void)continueLoadCaptureSession:(AVCaptureVideoPreviewLayer*)previewLayer;
Modifies the method to move the section that configures the QR scanner metadata output to a separate method 'configureScannerWithSession', implemented in the QR Scanner Camera Controller.

2. - (void)captureOutput:(AVCaptureOutput*)captureOutput
    didOutputMetadataObjects:(NSArray*)metadataObjects
              fromConnection:(AVCaptureConnection*)connection;
Moves this method to the QR Scanner Camera Controller. It reads and processes the scanned QR code data.

Bug: 990744

Change-Id: If07340c62b0c5c11c70a1e6c4d0a6782dd2c774e
Reviewed-on: https://chromium-review.googlesource.com/c/chromium/src/+/1754008
Commit-Queue: Tanisha Mandre <tanishamandre@google.com>
Reviewed-by: Javier Ernesto Flores Robles <javierrobles@chromium.org>
Reviewed-by: Rohit Rao <rohitrao@chromium.org>
Cr-Commit-Position: refs/heads/master@{#688503}

ios/chrome/browser/ui/qr_scanner/BUILD.gn

@@ -5,6 +5,9 @@
 source_set("qr_scanner") {
   configs += [ "//build/config/compiler:enable_arc" ]
   sources = [
+    "qr_scanner_camera_controller.h",
+    "qr_scanner_camera_controller.mm",
+    "qr_scanner_camera_controller_delegate.h",
     "qr_scanner_view.h",
     "qr_scanner_view.mm",
     "qr_scanner_view_controller.h",

ios/chrome/browser/ui/qr_scanner/qr_scanner_camera_controller.h

+// Copyright 2019 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#ifndef IOS_CHROME_BROWSER_UI_QR_SCANNER_QR_SCANNER_CAMERA_CONTROLLER_H_
+#define IOS_CHROME_BROWSER_UI_QR_SCANNER_QR_SCANNER_CAMERA_CONTROLLER_H_
+
+#import "ios/chrome/browser/ui/qr_scanner/qr_scanner_camera_controller_delegate.h"
+
+// The QRScannerCameraController manages the AVCaptureSession, its inputs,
+// outputs, and notifications for the QRScannerViewController.
+@interface QRScannerCameraController : CameraController
+
+// Initializes the QR scanner camera controller with the camera controller
+// delegate and the QR scanner delegate.
+- (instancetype)initWithCameraControllerDelegate:
+                    (id<CameraControllerDelegate>)cameraControllerDelegate
+                               qrScannerDelegate:
+                                   (id<QRScannerCameraControllerDelegate>)
+                                       qrScannerDelegate
+    NS_DESIGNATED_INITIALIZER;
+
+- (instancetype)initWithDelegate:(id<CameraControllerDelegate>)delegate
+    NS_UNAVAILABLE;
+
+@end
+
+#endif  // IOS_CHROME_BROWSER_UI_QR_SCANNER_QR_SCANNER_CAMERA_CONTROLLER_H_

ios/chrome/browser/ui/qr_scanner/qr_scanner_camera_controller.mm

+// Copyright 2019 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "ios/chrome/browser/ui/qr_scanner/qr_scanner_camera_controller.h"
+
+#include "base/logging.h"
+#include "base/mac/foundation_util.h"
+
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
+@interface QRScannerCameraController () <AVCaptureMetadataOutputObjectsDelegate>
+
+// The delegate which receives the QR scanned result.
+@property(nonatomic, weak) id<QRScannerCameraControllerDelegate>
+    qrScannerDelegate;
+
+@end
+
+@implementation QRScannerCameraController
+
+#pragma mark - Lifecycle
+
+- (instancetype)initWithCameraControllerDelegate:
+                    (id<CameraControllerDelegate>)cameraControllerDelegate
+                               qrScannerDelegate:
+                                   (id<QRScannerCameraControllerDelegate>)
+                                       qrScannerDelegate {
+  self = [super initWithDelegate:cameraControllerDelegate];
+  if (self) {
+    _qrScannerDelegate = qrScannerDelegate;
+  }
+  return self;
+}
+
+#pragma mark - CameraController
+
+- (void)configureScannerWithSession:(AVCaptureSession*)session {
+  // Configure metadata output.
+  AVCaptureMetadataOutput* metadataOutput =
+      [[AVCaptureMetadataOutput alloc] init];
+  [metadataOutput setMetadataObjectsDelegate:self
+                                       queue:dispatch_get_main_queue()];
+  if (![session canAddOutput:metadataOutput]) {
+    [self setCameraState:scanner::CAMERA_UNAVAILABLE];
+    return;
+  }
+  [session addOutput:metadataOutput];
+  NSArray* availableCodeTypes = [metadataOutput availableMetadataObjectTypes];
+
+  // Require QR code recognition to be available.
+  if (![availableCodeTypes containsObject:AVMetadataObjectTypeQRCode]) {
+    [self setCameraState:scanner::CAMERA_UNAVAILABLE];
+    return;
+  }
+  [metadataOutput setMetadataObjectTypes:availableCodeTypes];
+  self.metadataOutput = metadataOutput;
+}
+
+#pragma mark - AVCaptureMetadataOutputObjectsDelegate
+
+- (void)captureOutput:(AVCaptureOutput*)captureOutput
+    didOutputMetadataObjects:(NSArray*)metadataObjects
+              fromConnection:(AVCaptureConnection*)connection {
+  AVMetadataObject* metadataResult = [metadataObjects firstObject];
+  if (![metadataResult
+          isKindOfClass:[AVMetadataMachineReadableCodeObject class]]) {
+    return;
+  }
+  NSString* resultString =
+      [base::mac::ObjCCastStrict<AVMetadataMachineReadableCodeObject>(
+          metadataResult) stringValue];
+  if (resultString.length == 0) {
+    return;
+  }
+  __weak CameraController* weakSelf = self;
+  dispatch_async(self.sessionQueue, ^{
+    CameraController* strongSelf = weakSelf;
+    if (strongSelf && [strongSelf.captureSession isRunning]) {
+      [strongSelf.captureSession stopRunning];
+    }
+  });
+
+  // Check if the barcode can only contain digits. In this case, the result can
+  // be loaded immediately.
+  NSString* resultType = metadataResult.type;
+  BOOL isAllDigits =
+      [resultType isEqualToString:AVMetadataObjectTypeUPCECode] ||
+      [resultType isEqualToString:AVMetadataObjectTypeEAN8Code] ||
+      [resultType isEqualToString:AVMetadataObjectTypeEAN13Code] ||
+      [resultType isEqualToString:AVMetadataObjectTypeInterleaved2of5Code] ||
+      [resultType isEqualToString:AVMetadataObjectTypeITF14Code];
+
+  // Note: |captureOutput| is called on the main queue. This is specified by
+  // |setMetadataObjectsDelegate:queue:|.
+  [self.qrScannerDelegate receiveQRScannerResult:resultString
+                                 loadImmediately:isAllDigits];
+}
+
+@end

ios/chrome/browser/ui/qr_scanner/qr_scanner_camera_controller_delegate.h

+// Copyright 2019 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#ifndef IOS_CHROME_BROWSER_UI_QR_SCANNER_QR_SCANNER_CAMERA_CONTROLLER_DELEGATE_H_
+#define IOS_CHROME_BROWSER_UI_QR_SCANNER_QR_SCANNER_CAMERA_CONTROLLER_DELEGATE_H_
+
+#import "ios/chrome/browser/ui/scanner/camera_controller.h"
+
+// Receives the QR scanner results.
+@protocol QRScannerCameraControllerDelegate <CameraControllerDelegate>
+
+// Called when the scanner detects a valid code. The camera controller stops
+// recording when a result is scanned. A valid code is any non-empty string. If
+// |load| is YES, the result should be loaded immediately without requiring
+// additional user input. The value of |load| will only be YES for barcodes
+// which can only encode digits.
+- (void)receiveQRScannerResult:(NSString*)result loadImmediately:(BOOL)load;
+
+@end
+
+#endif  // IOS_CHROME_BROWSER_UI_QR_SCANNER_QR_SCANNER_CAMERA_CONTROLLER_DELEGATE_H_

ios/chrome/browser/ui/qr_scanner/qr_scanner_view_controller.h

@@ -5,12 +5,14 @@
 #ifndef IOS_CHROME_BROWSER_UI_QR_SCANNER_QR_SCANNER_VIEW_CONTROLLER_H_
 #define IOS_CHROME_BROWSER_UI_QR_SCANNER_QR_SCANNER_VIEW_CONTROLLER_H_
 
+#include "ios/chrome/browser/ui/qr_scanner/qr_scanner_camera_controller.h"
 #import "ios/chrome/browser/ui/scanner/scanner_view_controller.h"
 
 @protocol LoadQueryCommands;
 
 // View controller for the QR Scanner.
-@interface QRScannerViewController : ScannerViewController
+@interface QRScannerViewController
+    : ScannerViewController <QRScannerCameraControllerDelegate>
 
 - (instancetype)initWithPresentationProvider:
                     (id<ScannerPresenting>)presentationProvider
@@ -18,9 +20,7 @@
     NS_DESIGNATED_INITIALIZER;
 
 - (instancetype)initWithPresentationProvider:
-                    (id<ScannerPresenting>)presentationProvider
-                            cameraController:(CameraController*)cameraController
-    NS_UNAVAILABLE;
+    (id<ScannerPresenting>)presentationProvider NS_UNAVAILABLE;
 
 - (instancetype)initWithNibName:(NSString*)name
                          bundle:(NSBundle*)bundle NS_UNAVAILABLE;

ios/chrome/browser/ui/qr_scanner/qr_scanner_view_controller.mm

@@ -8,6 +8,7 @@
 #include "base/metrics/user_metrics.h"
 #include "base/metrics/user_metrics_action.h"
 #include "ios/chrome/browser/ui/commands/load_query_commands.h"
+#import "ios/chrome/browser/ui/qr_scanner/qr_scanner_camera_controller.h"
 #include "ios/chrome/browser/ui/qr_scanner/qr_scanner_view.h"
 #include "ios/chrome/browser/ui/scanner/scanner_alerts.h"
 #include "ios/chrome/browser/ui/scanner/scanner_presenting.h"
@@ -43,10 +44,7 @@ using base::UserMetricsAction;
 - (instancetype)
     initWithPresentationProvider:(id<ScannerPresenting>)presentationProvider
                      queryLoader:(id<LoadQueryCommands>)queryLoader {
-  self = [super
-      initWithPresentationProvider:presentationProvider
-                  cameraController:[CameraController
-                                       cameraControllerWithDelegate:self]];
+  self = [super initWithPresentationProvider:presentationProvider];
   if (self) {
     _queryLoader = queryLoader;
   }
@@ -59,6 +57,12 @@ using base::UserMetricsAction;
   return [[QRScannerView alloc] initWithFrame:self.view.frame delegate:self];
 }
 
+- (CameraController*)buildCameraController {
+  return
+      [[QRScannerCameraController alloc] initWithCameraControllerDelegate:self
+                                                        qrScannerDelegate:self];
+}
+
 - (void)dismissForReason:(scannerViewController::DismissalReason)reason
           withCompletion:(void (^)(void))completion {
   switch (reason) {
@@ -78,4 +82,27 @@ using base::UserMetricsAction;
   [super dismissForReason:reason withCompletion:completion];
 }
 
+#pragma mark - QRScannerCameraControllerDelegate
+
+- (void)receiveQRScannerResult:(NSString*)result loadImmediately:(BOOL)load {
+  if (UIAccessibilityIsVoiceOverRunning()) {
+    // Post a notification announcing that a code was scanned. QR scanner will
+    // be dismissed when the UIAccessibilityAnnouncementDidFinishNotification is
+    // received.
+    _result = [result copy];
+    _loadResultImmediately = load;
+    UIAccessibilityPostNotification(
+        UIAccessibilityAnnouncementNotification,
+        l10n_util::GetNSString(
+            IDS_IOS_SCANNER_SCANNED_ACCESSIBILITY_ANNOUNCEMENT));
+  } else {
+    [self.scannerView animateScanningResultWithCompletion:^void(void) {
+      [self dismissForReason:scannerViewController::SCANNED_CODE
+              withCompletion:^{
+                [self.queryLoader loadQuery:result immediately:load];
+              }];
+    }];
+  }
+}
+
 @end

ios/chrome/browser/ui/qr_scanner/qr_scanner_view_controller_egtest.mm

@@ -16,6 +16,7 @@
 #import "ios/chrome/browser/ui/location_bar/location_bar_coordinator.h"
 #import "ios/chrome/browser/ui/location_bar/location_bar_url_loader.h"
 #include "ios/chrome/browser/ui/omnibox/location_bar_delegate.h"
+#include "ios/chrome/browser/ui/qr_scanner/qr_scanner_camera_controller.h"
 #include "ios/chrome/browser/ui/qr_scanner/qr_scanner_view.h"
 #include "ios/chrome/browser/ui/qr_scanner/qr_scanner_view_controller.h"
 #include "ios/chrome/browser/ui/scanner/camera_controller.h"
@@ -394,16 +395,17 @@ void TapKeyboardReturnKeyInOmniboxWithText(std::string text) {
 #pragma mark -
 #pragma mark Helpers for mocks
 
-// Swizzles the CameraController method cameraControllerWithDelegate: to return
+// Swizzles the QRScannerViewController property cameraController: to return
 // |cameraControllerMock| instead of a new instance of CameraController.
 - (void)swizzleCameraController:(id)cameraControllerMock {
-  CameraController* (^swizzleCameraControllerBlock)(
-      id<CameraControllerDelegate>) = ^(id<CameraControllerDelegate> delegate) {
-    return cameraControllerMock;
-  };
+  QRScannerCameraController* (^swizzleCameraControllerBlock)(
+      id<QRScannerCameraControllerDelegate>) =
+      ^(id<QRScannerCameraControllerDelegate> delegate) {
+        return cameraControllerMock;
+      };
 
   camera_controller_swizzler_.reset(new ScopedBlockSwizzler(
-      [CameraController class], @selector(cameraControllerWithDelegate:),
+      [QRScannerViewController class], @selector(cameraController),
       swizzleCameraControllerBlock));
 }
 
@@ -435,7 +437,7 @@ void TapKeyboardReturnKeyInOmniboxWithText(std::string text) {
 // |granted| is set to YES.
 - (id)getCameraControllerMockWithAuthorizationStatus:
     (AVAuthorizationStatus)authorizationStatus {
-  id mock = [OCMockObject mockForClass:[CameraController class]];
+  id mock = [OCMockObject mockForClass:[QRScannerCameraController class]];
   [[[mock stub] andReturnValue:OCMOCK_VALUE(authorizationStatus)]
       getAuthorizationStatus];
   return mock;

ios/chrome/browser/ui/scanner/camera_controller.h

@@ -51,27 +51,21 @@ enum CameraState {
 - (void)torchStateChanged:(BOOL)torchIsOn;
 // Called on the main queue when the torch availability changes.
 - (void)torchAvailabilityChanged:(BOOL)torchIsAvailable;
-// Called when the scanner detects a valid code. The camera controller stops
-// recording when a result is scanned. A valid code is any non-empty string. If
-// |load| is YES, the result should be loaded immediately without requiring
-// additional user input. The value of |load| will only be YES for barcodes
-// which can only encode digits.
-- (void)receiveQRScannerResult:(NSString*)result loadImmediately:(BOOL)load;
 
 @end
 
 // The CameraController manages the AVCaptureSession, its inputs, outputs, and
-// notifications for the QRScannerViewController.
+// notifications for the ScannerViewController.
 @interface CameraController : NSObject
 
 // The current state of the torch.
 @property(nonatomic, readonly, assign, getter=isTorchActive) BOOL torchActive;
 
-- (instancetype)init NS_UNAVAILABLE;
+// Initializes the controller with the |delegate|.
+- (instancetype)initWithDelegate:(id<CameraControllerDelegate>)delegate
+    NS_DESIGNATED_INITIALIZER;
 
-// Returns a new controller with the |delegate|.
-+ (instancetype)cameraControllerWithDelegate:
-    (id<CameraControllerDelegate>)delegate;
+- (instancetype)init NS_UNAVAILABLE;
 
 // Returns the app's authorization in regards to the camera.
 - (AVAuthorizationStatus)getAuthorizationStatus;
@@ -109,4 +103,25 @@ enum CameraState {
 
 @end
 
+@interface CameraController (Subclassing)
+
+// The queue for dispatching calls to |_captureSession|.
+@property(nonatomic, readonly) dispatch_queue_t sessionQueue;
+
+// The capture session for recording video and detecting QR codes or credit
+// cards.
+@property(nonatomic, readwrite) AVCaptureSession* captureSession;
+
+// The metadata output attached to the capture session.
+@property(nonatomic, readwrite) AVCaptureMetadataOutput* metadataOutput;
+
+// Set camera state.
+- (void)setCameraState:(scanner::CameraState)state;
+
+// Configures the scanner specific capture session elements, i.e. either QR code
+// or credit card scanner. Must be overridden in the subclass.
+- (void)configureScannerWithSession:(AVCaptureSession*)session;
+
+@end
+
 #endif  // IOS_CHROME_BROWSER_UI_SCANNER_CAMERA_CONTROLLER_H_

ios/chrome/browser/ui/scanner/camera_controller.mm

@@ -13,11 +13,14 @@
 #error "This file requires ARC support."
 #endif
 
-@interface CameraController () <AVCaptureMetadataOutputObjectsDelegate> {
-  // The queue for dispatching calls to |_captureSession|.
-  dispatch_queue_t _sessionQueue;
-}
+@interface CameraController ()
 
+// The queue for dispatching calls to |_captureSession|.
+@property(nonatomic, readonly) dispatch_queue_t sessionQueue;
+// The capture session for recording video and detecting QR codes.
+@property(nonatomic, readwrite) AVCaptureSession* captureSession;
+// The metadata output attached to the capture session.
+@property(nonatomic, readwrite) AVCaptureMetadataOutput* metadataOutput;
 // The delegate which receives the scanned result. All methods of this
 // delegate should be called on the main queue.
 @property(nonatomic, readwrite, weak) id<CameraControllerDelegate> delegate;
@@ -32,16 +35,8 @@
 // The state of KVO for the camera. Used to stop observing on dealloc.
 @property(nonatomic, readwrite, assign, getter=isObservingCamera)
     BOOL observingCamera;
-// The capture session for recording video and detecting QR codes.
-@property(nonatomic, readwrite) AVCaptureSession* captureSession;
-// The metadata output attached to the capture session.
-@property(nonatomic, readwrite) AVCaptureMetadataOutput* metadataOutput;
 @property(nonatomic, readwrite, assign) CGRect viewportRect;
 
-// Initializes the controller with the |delegate|.
-- (instancetype)initWithDelegate:(id<CameraControllerDelegate>)delegate
-    NS_DESIGNATED_INITIALIZER;
-
 // YES if |cameraState| is CAMERA_AVAILABLE.
 - (BOOL)isCameraAvailable;
 // Starts receiving notfications about changes to the capture session and to the
@@ -61,13 +56,6 @@
 
 #pragma mark - Lifecycle
 
-+ (instancetype)cameraControllerWithDelegate:
-    (id<CameraControllerDelegate>)delegate {
-  CameraController* cameraController =
-      [[CameraController alloc] initWithDelegate:delegate];
-  return cameraController;
-}
-
 - (instancetype)initWithDelegate:(id<CameraControllerDelegate>)delegate {
   self = [super init];
   if (self) {
@@ -245,25 +233,7 @@
   }
   [session addInput:videoInput];
 
-  // Configure metadata output.
-  AVCaptureMetadataOutput* metadataOutput =
-      [[AVCaptureMetadataOutput alloc] init];
-  [metadataOutput setMetadataObjectsDelegate:self
-                                       queue:dispatch_get_main_queue()];
-  if (![session canAddOutput:metadataOutput]) {
-    [self setCameraState:scanner::CAMERA_UNAVAILABLE];
-    return;
-  }
-  [session addOutput:metadataOutput];
-  NSArray* availableCodeTypes = [metadataOutput availableMetadataObjectTypes];
-
-  // Require QR code recognition to be available.
-  if (![availableCodeTypes containsObject:AVMetadataObjectTypeQRCode]) {
-    [self setCameraState:scanner::CAMERA_UNAVAILABLE];
-    return;
-  }
-  [metadataOutput setMetadataObjectTypes:availableCodeTypes];
-  _metadataOutput = metadataOutput;
+  [self configureScannerWithSession:session];
 
   _captureSession = session;
   [self setCameraState:scanner::CAMERA_AVAILABLE];
@@ -288,6 +258,10 @@
   [self startRecording];
 }
 
+- (void)configureScannerWithSession:(AVCaptureSession*)session {
+  NOTREACHED();
+}
+
 - (void)startReceivingNotifications {
   // Start receiving notifications about changes to the capture session.
   [[NSNotificationCenter defaultCenter]
@@ -466,43 +440,4 @@
   });
 }
 
-#pragma mark - AVCaptureMetadataOutputObjectsDelegate
-
-- (void)captureOutput:(AVCaptureOutput*)captureOutput
-    didOutputMetadataObjects:(NSArray*)metadataObjects
-              fromConnection:(AVCaptureConnection*)connection {
-  AVMetadataObject* metadataResult = [metadataObjects firstObject];
-  if (![metadataResult
-          isKindOfClass:[AVMetadataMachineReadableCodeObject class]]) {
-    return;
-  }
-  NSString* resultString =
-      [base::mac::ObjCCastStrict<AVMetadataMachineReadableCodeObject>(
-          metadataResult) stringValue];
-  if (resultString.length == 0) {
-    return;
-  }
-  __weak CameraController* weakSelf = self;
-  dispatch_async(_sessionQueue, ^{
-    CameraController* strongSelf = weakSelf;
-    if (strongSelf && [strongSelf.captureSession isRunning]) {
-      [strongSelf.captureSession stopRunning];
-    }
-  });
-
-  // Check if the barcode can only contain digits. In this case, the result can
-  // be loaded immediately.
-  NSString* resultType = metadataResult.type;
-  BOOL isAllDigits =
-      [resultType isEqualToString:AVMetadataObjectTypeUPCECode] ||
-      [resultType isEqualToString:AVMetadataObjectTypeEAN8Code] ||
-      [resultType isEqualToString:AVMetadataObjectTypeEAN13Code] ||
-      [resultType isEqualToString:AVMetadataObjectTypeInterleaved2of5Code] ||
-      [resultType isEqualToString:AVMetadataObjectTypeITF14Code];
-
-  // Note: |captureOutput| is called on the main queue. This is specified by
-  // |setMetadataObjectsDelegate:queue:|.
-  [_delegate receiveQRScannerResult:resultString loadImmediately:isAllDigits];
-}
-
 @end

ios/chrome/browser/ui/scanner/scanner_view_controller.h

@@ -33,14 +33,16 @@ enum DismissalReason {
 // Stores the camera controller for the scanner.
 @property(nonatomic, readwrite, strong) CameraController* cameraController;
 
+// Stores the view for the scanner. Can be subclassed as a QR code or Credit
+// Card scanner view.
+@property(nonatomic, readwrite) ScannerView* scannerView;
+
 // Stores the presentation provider.
 @property(nonatomic, readwrite, weak) id<ScannerPresenting>
     presentationProvider;
 
 - (instancetype)initWithPresentationProvider:
-                    (id<ScannerPresenting>)presentationProvider
-                            cameraController:(CameraController*)cameraController
-    NS_DESIGNATED_INITIALIZER;
+    (id<ScannerPresenting>)presentationProvider NS_DESIGNATED_INITIALIZER;
 
 - (instancetype)initWithNibName:(NSString*)name
                          bundle:(NSBundle*)bundle NS_UNAVAILABLE;
@@ -55,6 +57,9 @@ enum DismissalReason {
 // Builds the scanner view. Must be overridden in the subclass.
 - (ScannerView*)buildScannerView;
 
+// Builds the camera controller. Must be overridden in the subclass.
+- (CameraController*)buildCameraController;
+
 // Dismiss scanner. Subclass can override to update metrics.
 // implementation.
 - (void)dismissForReason:(scannerViewController::DismissalReason)reason

ios/chrome/browser/ui/scanner/scanner_view_controller.mm

@@ -34,23 +34,17 @@ using base::UserMetricsAction;
 
 @property(nonatomic, readwrite, weak) id<LoadQueryCommands> queryLoader;
 
-// Stores the view for the scanner. Can be subclassed as a QR code or Credit
-// Card scanner view.
-@property(nonatomic, readwrite) ScannerView* scannerView;
-
 @end
 
 @implementation ScannerViewController
 
 #pragma mark - lifecycle
 
-- (instancetype)
-    initWithPresentationProvider:(id<ScannerPresenting>)presentationProvider
-                cameraController:(CameraController*)cameraController {
+- (instancetype)initWithPresentationProvider:
+    (id<ScannerPresenting>)presentationProvider {
   self = [super initWithNibName:nil bundle:nil];
   if (self) {
     _presentationProvider = presentationProvider;
-    _cameraController = cameraController;
   }
   return self;
 }
@@ -67,7 +61,7 @@ using base::UserMetricsAction;
 
 - (void)viewDidLoad {
   [super viewDidLoad];
-  DCHECK(_cameraController);
+  DCHECK(self.cameraController);
 
   [self.view addSubview:self.scannerView];
 
@@ -85,13 +79,13 @@ using base::UserMetricsAction;
   ]];
 
   AVCaptureVideoPreviewLayer* previewLayer = [self.scannerView getPreviewLayer];
-  switch ([_cameraController getAuthorizationStatus]) {
+  switch ([self.cameraController getAuthorizationStatus]) {
     case AVAuthorizationStatusNotDetermined:
-      [_cameraController
+      [self.cameraController
           requestAuthorizationAndLoadCaptureSession:previewLayer];
       break;
     case AVAuthorizationStatusAuthorized:
-      [_cameraController loadCaptureSession:previewLayer];
+      [self.cameraController loadCaptureSession:previewLayer];
       break;
     case AVAuthorizationStatusRestricted:
     case AVAuthorizationStatusDenied:
@@ -108,7 +102,7 @@ using base::UserMetricsAction;
 - (void)viewWillAppear:(BOOL)animated {
   [super viewWillAppear:animated];
   [self startReceivingNotifications];
-  [_cameraController startRecording];
+  [self.cameraController startRecording];
 
   // Reset torch.
   [self setTorchMode:AVCaptureTorchModeOff];
@@ -144,14 +138,14 @@ using base::UserMetricsAction;
     // Reset the size of the preview if the bounds of the view controller
     // changed. This can happen if entering or leaving Split View mode on iPad.
     [self.scannerView resetPreviewFrame:size];
-    [_cameraController
+    [self.cameraController
         resetVideoOrientation:[self.scannerView getPreviewLayer]];
   }
 }
 
 - (void)viewDidDisappear:(BOOL)animated {
   [super viewDidDisappear:animated];
-  [_cameraController stopRecording];
+  [self.cameraController stopRecording];
   [self stopReceivingNotifications];
 
   // Reset torch.
@@ -165,8 +159,8 @@ using base::UserMetricsAction;
 #pragma mark - public methods
 
 - (UIViewController*)getViewControllerToPresent {
-  DCHECK(_cameraController);
-  switch ([_cameraController getAuthorizationStatus]) {
+  DCHECK(self.cameraController);
+  switch ([self.cameraController getAuthorizationStatus]) {
     case AVAuthorizationStatusNotDetermined:
     case AVAuthorizationStatusAuthorized:
       _transitioningDelegate = [[ScannerTransitioningDelegate alloc] init];
@@ -190,6 +184,11 @@ using base::UserMetricsAction;
   return nil;
 }
 
+- (CameraController*)buildCameraController {
+  NOTIMPLEMENTED();
+  return nil;
+}
+
 #pragma mark - private methods
 
 // Starts receiving notifications about the UIApplication going to background.
@@ -213,10 +212,10 @@ using base::UserMetricsAction;
   [[NSNotificationCenter defaultCenter] removeObserver:self];
 }
 
-// Requests the torch mode to be set to |mode| by the |_cameraController|
+// Requests the torch mode to be set to |mode| by the |self.cameraController|
 // and the icon of the torch button to be changed by the |self.scannerView|.
 - (void)setTorchMode:(AVCaptureTorchMode)mode {
-  [_cameraController setTorchMode:mode];
+  [self.cameraController setTorchMode:mode];
 }
 
 - (ScannerView*)scannerView {
@@ -226,6 +225,13 @@ using base::UserMetricsAction;
   return _scannerView;
 }
 
+- (CameraController*)cameraController {
+  if (!_cameraController) {
+    _cameraController = [self buildCameraController];
+  }
+  return _cameraController;
+}
+
 #pragma mark - notification handlers
 
 - (void)handleUIApplicationWillResignActiveNotification {
@@ -252,7 +258,7 @@ using base::UserMetricsAction;
 #pragma mark - CameraControllerDelegate
 
 - (void)captureSessionIsConnected {
-  [_cameraController setViewport:[self.scannerView viewportRectOfInterest]];
+  [self.cameraController setViewport:[self.scannerView viewportRectOfInterest]];
 }
 
 - (void)cameraStateChanged:(scanner::CameraState)state {
@@ -297,27 +303,6 @@ using base::UserMetricsAction;
   [self.scannerView enableTorchButton:torchIsAvailable];
 }
 
-- (void)receiveQRScannerResult:(NSString*)result loadImmediately:(BOOL)load {
-  if (UIAccessibilityIsVoiceOverRunning()) {
-    // Post a notification announcing that a code was scanned. QR scanner will
-    // be dismissed when the UIAccessibilityAnnouncementDidFinishNotification is
-    // received.
-    _result = [result copy];
-    _loadResultImmediately = load;
-    UIAccessibilityPostNotification(
-        UIAccessibilityAnnouncementNotification,
-        l10n_util::GetNSString(
-            IDS_IOS_SCANNER_SCANNED_ACCESSIBILITY_ANNOUNCEMENT));
-  } else {
-    [self.scannerView animateScanningResultWithCompletion:^void(void) {
-      [self dismissForReason:scannerViewController::SCANNED_CODE
-              withCompletion:^{
-                [self.queryLoader loadQuery:result immediately:load];
-              }];
-    }];
-  }
-}
-
 #pragma mark - ScannerViewDelegate
 
 - (void)dismissScannerView:(id)sender {
@@ -326,7 +311,7 @@ using base::UserMetricsAction;
 }
 
 - (void)toggleTorch:(id)sender {
-  if ([_cameraController isTorchActive]) {
+  if ([self.cameraController isTorchActive]) {
     [self setTorchMode:AVCaptureTorchModeOff];
   } else {
     base::RecordAction(UserMetricsAction("MobileQRScannerTorchOn"));