Reland "[LPM] Improve process for using the plugin for LITE_RUNTIME."

Add fuzzable_proto_library to wrap proto_libraries used in production
and by LPM.

This is a reland of 2f46bdba

Original change's description:
> [LPM] Improve process for using the plugin for LITE_RUNTIME.
>
>
>
> Bug: 860750,861746
> Change-Id: I43d4c51f686895fc8aafb8bdae368815aee4ace2
> Reviewed-on: https://chromium-review.googlesource.com/1128249
> Reviewed-by: Martin Barbella <mbarbella@chromium.org>
> Commit-Queue: Jonathan Metzman <metzman@chromium.org>
> Cr-Commit-Position: refs/heads/master@{#577035}

Bug: 860750, 861746
Change-Id: I03bae3970b7fd333268a35aa738029ff7549705a
Reviewed-on: https://chromium-review.googlesource.com/1145205Reviewed-by: Martin Barbella <mbarbella@chromium.org>
Commit-Queue: Jonathan Metzman <metzman@chromium.org>
Cr-Commit-Position: refs/heads/master@{#577043}

testing/libfuzzer/libprotobuf-mutator.md

@@ -95,28 +95,18 @@ the full protobuf library, all `.proto` files in Chromium that are used in
 production contain this line: `option optimize_for = LITE_RUNTIME` But this
 line is incompatible with libprotobuf-mutator. Thus, we need to modify the
 `proto_library` build target so that builds when fuzzing are compatible with
-libprotobuf-mutator. We do this by using a protobuf compiler plugin,
-`override_lite_runtime_plugin`. Here's what a `proto_library` build target that
-is configured properly looks like:
+libprotobuf-mutator. To do this, change your `proto_library` to
+`fuzzable_proto_library` (don't worry, this works just like `proto_library` when
+`use_libfuzzer` is `false`) like so:
 
 ```python
-proto_library("my_proto") {
-  ... // These lines (probably) dont need to be changed.
-
-  if (use_libfuzzer && current_toolchain == host_toolchain) {
-    generator_plugin_label =
-      "//third_party/libprotobuf-mutator:override_lite_runtime_plugin"
-    generator_plugin_suffix = ".pb"
-    # The plugin will generate cc, so don't ask for it to be done by protoc.
-    generate_cc = false
-    // If deps is already defined, change "=" to "+=".
-    deps = ["//third_party/libprotobuf-mutator:override_lite_runtime_plugin"]
-  }
+import("//third_party/libprotobuf-mutator/fuzzable_proto_library.gni")
+
+fuzzable_proto_library("my_proto") {
+  ...
 }
 ```
 
-Note that this will not have any affects on the proto_library in production,
-since the plugin is only used when `use_libfuzzer == true`.
 And with that we have completed writing a libprotobuf-mutator fuzz target for
 Chromium code that accepts protobufs.
 

third_party/libprotobuf-mutator/BUILD.gn

 # Copyright 2017 The Chromium Authors. All rights reserved.
 import("//build/config/sanitizers/sanitizers.gni")
 import("//testing/libfuzzer/fuzzer_test.gni")
-import("//third_party/protobuf/proto_library.gni")
+import("//third_party/libprotobuf-mutator/fuzzable_proto_library.gni")
 
 config("include_config") {
   include_dirs = [ "src/" ]
@@ -63,18 +63,9 @@ if (current_toolchain == host_toolchain) {
     ]
     public_configs = [ "//third_party/protobuf:protobuf_config" ]
   }
-  # To use the plugin in a proto_library you want to fuzz, add these lines to
-  # the proto_library definition (note the "=" in second to last line in the
-  # comment will need to be changed to "+=" if you have already defined
-  # deps):
-  # if (use_libfuzzer && current_toolchain == host_toolchain) {
-  #   generator_plugin_label =
-  #     "//third_party/libprotobuf-mutator:override_lite_runtime_plugin"
-  #   generator_plugin_suffix = ".pb"
-  #   # The plugin will generate cc, so don't ask for it to be done by protoc.
-  #   generate_cc = false
-  #   deps = ["//third_party/libprotobuf-mutator:override_lite_runtime_plugin"]
-  # }
+  # To use the plugin in a proto_library you want to fuzz, change the build
+  # target to fuzzable_proto_library (defined in
+  # //third_party/libprotobuf-mutator/fuzzable_proto_library.gni)
 }
 
 # The CQ will try building this target without "use_libfuzzer" if it is defined.
@@ -99,24 +90,21 @@ if (use_libfuzzer) {
 }
 
 # Proto library for override_lite_runtime_plugin_test_fuzzer
-proto_library("override_lite_runtime_plugin_test_fuzzer_proto") {
+fuzzable_proto_library("override_lite_runtime_plugin_test_fuzzer_proto") {
   sources = [
     "protoc_plugin/imported.proto",
     "protoc_plugin/imported_publicly.proto",
     "protoc_plugin/test_fuzzer_input.proto",
   ]
+}
 
-  # TODO(metzman): Figure out how we can avoid using this toolchain check
-  # (maybe remove compilation from the plugin).
-  if (use_libfuzzer && current_toolchain == host_toolchain) {
-    generator_plugin_label =
-        "//third_party/libprotobuf-mutator:override_lite_runtime_plugin"
-    generator_plugin_suffix = ".pb"
-
-    # The plugin will generate cc, so don't ask for it to be done by protoc.
-    generate_cc = false
-    deps = [
-      "//third_party/libprotobuf-mutator:override_lite_runtime_plugin",
-    ]
+# Component that can provide protobuf_full to non-testonly targets
+component("protobuf_full") {
+  # Stop people from using me by accident.
+  if (!use_libfuzzer) {
+    testonly = true
   }
+  public_deps = [
+    "//third_party/protobuf:protobuf_full",
+  ]
 }

third_party/libprotobuf-mutator/fuzzable_proto_library.gni

+import("//third_party/protobuf/proto_library.gni")
+
+template("fuzzable_proto_library") {
+  forward_variables_from(invoker, "*")
+  if (use_libfuzzer) {
+    proto_library("proto_library_" + target_name) {
+      assert(current_toolchain == host_toolchain)
+      if (!defined(deps)) {
+        deps = []
+      }
+      deps +=
+          [ "//third_party/libprotobuf-mutator:override_lite_runtime_plugin" ]
+      generator_plugin_label =
+          "//third_party/libprotobuf-mutator:override_lite_runtime_plugin"
+      generator_plugin_suffix = ".pb"
+
+      # The plugin will generate cc, so don't ask for it to be done by protoc.
+      generate_cc = false
+      generate_python = false
+    }
+
+    # Use a component for the build target with target_name. That way we can
+    # also force dependencies to build using protobuf_full.
+    component(target_name) {
+      public_deps = [
+        ":proto_library_" + target_name,
+        "//third_party/libprotobuf-mutator:protobuf_full",
+      ]
+    }
+  } else {
+    # fuzzable_proto_library should behave like a proto_library when
+    # !use_libfuzzer.
+    proto_library(target_name) {
+    }
+  }
+}