[iOS] Upstream UpdatableConfig test provider

BUG=429756
R=droger

Review URL: https://codereview.chromium.org/1102833003

Cr-Commit-Position: refs/heads/master@{#326904}

ios/ios_tests.gyp

@@ -18,6 +18,8 @@
         'public/test/test_chrome_browser_provider.mm',
         'public/test/test_chrome_provider_initializer.cc',
         'public/test/test_chrome_provider_initializer.h',
+        'public/test/test_updatable_resource_provider.h',
+        'public/test/test_updatable_resource_provider.mm',
       ],
       'dependencies': [
         '../base/base.gyp:base',

ios/public/test/test_updatable_resource_provider.h

+// Copyright 2015 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#ifndef IOS_PUBLIC_TEST_TEST_UPDATABLE_RESOURCE_PROVIDER_H_
+#define IOS_PUBLIC_TEST_TEST_UPDATABLE_RESOURCE_PROVIDER_H_
+
+#import "ios/public/provider/chrome/browser/updatable_resource_provider.h"
+
+namespace ios {
+
+// Dummy UpdatableResourceProvider implementation that simply loads data from
+// the specified plist file.
+class TestUpdatableResourceProvider : public ios::UpdatableResourceProvider {
+ private:
+  // UpdatableResourceProvider implementation.
+  NSString* GetUpdateNotificationName() override;
+  id<UpdatableResourceBridge> CreateUpdatableResource(
+      NSString* resource_identifier,
+      id<UpdatableResourceDelegate> delegate) override;
+};
+
+}  // namespace ios
+
+#endif  // IOS_PUBLIC_TEST_TEST_UPDATABLE_RESOURCE_PROVIDER_H_

ios/public/test/test_updatable_resource_provider.mm

+// Copyright 2015 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "ios/public/test/test_updatable_resource_provider.h"
+
+#include "base/logging.h"
+#include "base/mac/scoped_nsobject.h"
+
+#pragma mark - TestUpdatabeResourceDescriptor
+
+// Dummy UpdatableResourceDescriptorBridge implementation.
+@interface TestUpdatabeResourceDescriptor
+    : NSObject<UpdatableResourceDescriptorBridge>
+@property(nonatomic, readonly) NSURL* updateURL;
+@property(nonatomic, copy) NSString* applicationIdentifier;
+@property(nonatomic, copy) NSString* applicationVersion;
+@property(nonatomic, copy) NSString* bundleResourcePath;
+@property(nonatomic, copy) NSString* updateResourcePath;
+@end
+
+@implementation TestUpdatabeResourceDescriptor
+@synthesize updateURL;
+@synthesize applicationIdentifier;
+@synthesize applicationVersion;
+@synthesize bundleResourcePath;
+@synthesize updateResourcePath;
+
+- (void)updateCheckDidFinishWithSuccess:(BOOL)wasSuccessful {
+}
+
+- (NSString*)resourcePath {
+  return nil;
+}
+@end
+
+#pragma mark - TestUpdatableResource
+
+// Dummy UpdatableResourceDescriptorBridge implementation that simply loads data
+// from the specified plist file.
+@interface TestUpdatableResource : NSObject<UpdatableResourceBridge>
+@property(nonatomic, readonly) id<UpdatableResourceDescriptorBridge> descriptor;
+- (instancetype)initWithDelegate:(id<UpdatableResourceDelegate>)delegate
+                           plist:(NSString*)resource_identifier
+    NS_DESIGNATED_INITIALIZER;
+@end
+
+@implementation TestUpdatableResource {
+  base::scoped_nsprotocol<id<UpdatableResourceDelegate>> _delegate;
+  base::scoped_nsprotocol<id<UpdatableResourceDescriptorBridge>> _descriptor;
+}
+
+- (instancetype)initWithDelegate:(id<UpdatableResourceDelegate>)delegate
+                           plist:(NSString*)resourceIdentifier {
+  if (self = [super init]) {
+    _delegate.reset([delegate retain]);
+    _descriptor.reset([[TestUpdatabeResourceDescriptor alloc] init]);
+    DCHECK([resourceIdentifier hasSuffix:@".plist"])
+        << "TestUpdatableResource supports only the plist format";
+    [_descriptor setBundleResourcePath:resourceIdentifier];
+  }
+  return self;
+}
+
+- (id<UpdatableResourceDescriptorBridge>)descriptor {
+  return _descriptor.get();
+}
+
+- (id<UpdatableResourceDelegate>)delegate {
+  return _delegate;
+}
+
+- (NSDictionary*)resourceData {
+  return [NSDictionary
+      dictionaryWithContentsOfFile:[_descriptor bundleResourcePath]];
+}
+- (void)loadDefaults {
+  [_delegate loadDefaults:self];
+}
+
+@end
+
+#pragma mark - TestUpdatableResourceProvider
+
+namespace ios {
+
+NSString* TestUpdatableResourceProvider::GetUpdateNotificationName() {
+  return @"ResourceUpdatedTest";
+}
+
+id<UpdatableResourceBridge>
+TestUpdatableResourceProvider::CreateUpdatableResource(
+    NSString* resource_identifier,
+    id<UpdatableResourceDelegate> delegate) {
+  NSString* path =
+      [NSString stringWithFormat:@"%@/gm-config/ANY/%@",
+                                 [[NSBundle mainBundle] resourcePath],
+                                 resource_identifier];
+  return [[TestUpdatableResource alloc] initWithDelegate:delegate plist:path];
+}
+
+}  // namespace ios