Import securemessage and ukey2 as third party libraries

in chromium.

Design doc - go/nearby-chrome

The overall import is split into 3 CLs for easier reviews:
- Securemessage and ukey2 import
- Nearby connections import
- Platform implementation for nearby in chrome

Bug: 1037793
Change-Id: I59a58c01c877dd5fb4c7e647c122b633b592fa7a
Reviewed-on: https://chromium-review.googlesource.com/c/chromium/src/+/2274625
Commit-Queue: Himanshu Jaju <himanshujaju@chromium.org>
Reviewed-by: Nico Weber <thakis@chromium.org>
Reviewed-by: Alex Chau <alexchau@chromium.org>
Cr-Commit-Position: refs/heads/master@{#786500}

DEPS

@@ -343,6 +343,14 @@ vars = {
   # the commit queue can handle CLs rolling libavif
   # and whatever else without interference from each other.
   'libavif_revision': 'f48a33827db60223753e637699cef24f034c547d',
+  # Three lines of non-changing comments so that
+  # the commit queue can handle CLs rolling securemessage
+  # and whatever else without interference from each other.
+  'securemessage_revision': '3955ec1700b9381a2562df35d48e42487a33d7a1',
+  # Three lines of non-changing comments so that
+  # the commit queue can handle CLs rolling ukey2
+  # and whatever else without interference from each other.
+  'ukey2_revision': '0275885d8e6038c39b8a8ca55e75d1d4d1727f47',
 
   # TODO(crbug.com/941824): The values below need to be kept in sync
   # between //DEPS and //buildtools/DEPS, so if you're updating one,
@@ -1077,6 +1085,12 @@ deps = {
   'src/third_party/libavif/src':
     Var('chromium_git') + '/external/github.com/AOMediaCodec/libavif.git' + '@' + Var('libavif_revision'),
 
+  'src/third_party/securemessage/src':
+    Var('chromium_git') + '/external/github.com/google/securemessage.git' + '@' + Var('securemessage_revision'),
+
+  'src/third_party/ukey2/src':
+    Var('chromium_git') + '/external/github.com/google/ukey2.git' + '@' + Var('ukey2_revision'),
+
   # Userspace interface to kernel DRM services.
   'src/third_party/libdrm/src': {
       'url': Var('chromium_git') + '/chromiumos/third_party/libdrm.git' + '@' + '0190f49a139e7069d7cad6a6890832831da1aa8b',

third_party/.gitignore

@@ -202,6 +202,7 @@
 /robolectric/robolectric
 /scan-build/src
 /scons-2.0.1
+/securemessage/src
 /shaderc/src
 /skia
 /smhasher/src
@@ -220,6 +221,7 @@
 /turbine/src
 /turbine/*.jar
 /ub-uiautomator/lib
+/ukey2/src
 /usb_ids
 /usrsctp/usrsctplib
 /v8-i18n

third_party/securemessage/BUILD.gn

+# Copyright 2020 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//third_party/protobuf/proto_library.gni")
+
+config("securemessage_config") {
+  include_dirs = [
+    "$root_gen_dir/third_party/securemessage",
+    "src/cpp/include",
+  ]
+}
+
+source_set("securemessage_openssl") {
+  public_configs = [ ":securemessage_config" ]
+
+  sources = [ "src/cpp/src/securemessage/crypto_ops_openssl.cc" ]
+
+  public_deps = [ ":securemessage" ]
+  deps = [ "//third_party/boringssl" ]
+
+  configs -= [ "//build/config/compiler:chromium_code" ]
+  configs += [ "//build/config/compiler:no_chromium_code" ]
+}
+
+source_set("securemessage") {
+  public_configs = [ ":securemessage_config" ]
+
+  sources = [
+    "src/cpp/include/securemessage/secure_message_wrapper.h",
+    "src/cpp/src/securemessage/byte_buffer.cc",
+    "src/cpp/src/securemessage/crypto_ops.cc",
+    "src/cpp/src/securemessage/raw_secure_message_parser.cc",
+    "src/cpp/src/securemessage/util.cc",
+  ]
+
+  public = [
+    "src/cpp/include/securemessage/byte_buffer.h",
+    "src/cpp/include/securemessage/common.h",
+    "src/cpp/include/securemessage/crypto_ops.h",
+    "src/cpp/include/securemessage/raw_secure_message_parser.h",
+    "src/cpp/include/securemessage/util.h",
+  ]
+
+  configs -= [ "//build/config/compiler:chromium_code" ]
+  configs += [ "//build/config/compiler:no_chromium_code" ]
+}
+
+# The c++ protobuf specific code is separated out from the common code in order
+# to make it more clear that the common portion of the library is independent
+# of the c++ protobuf library.
+source_set("securemessage_cpp_protobuf") {
+  public_configs = [ ":securemessage_config" ]
+
+  sources = [
+    "src/cpp/src/securemessage/public_key_proto_util.cc",
+    "src/cpp/src/securemessage/secure_message_builder.cc",
+    "src/cpp/src/securemessage/secure_message_parser.cc",
+    "src/cpp/src/securemessage/secure_message_wrapper.cc",
+  ]
+
+  public = [
+    "src/cpp/include/securemessage/public_key_proto_util.h",
+    "src/cpp/include/securemessage/secure_message_builder.h",
+    "src/cpp/include/securemessage/secure_message_parser.h",
+    "src/cpp/include/securemessage/secure_message_wrapper.h",
+  ]
+
+  public_deps = [
+    ":securemessage",
+    "proto",
+  ]
+
+  configs -= [ "//build/config/compiler:chromium_code" ]
+  configs += [ "//build/config/compiler:no_chromium_code" ]
+}

third_party/securemessage/OWNERS

+alexchau@chromium.org
+hansberry@chromium.org
+vecore@chromium.org
+
+file://chrome/browser/nearby_sharing/OWNERS
+# COMPONENT: UI>Browser>Sharing>Nearby

third_party/securemessage/README.chromium

+Name: Secure Message
+Short Name: Secure Message
+URL: https://github.com/google/securemessage
+Version: 3955ec1700b9381a2562df35d48e42487a33d7a1
+License: Apache 2.0
+License File: LICENSE
+Security Critical: yes
+Description:
+Secure Message library

third_party/securemessage/proto/BUILD.gn

+# Copyright 2020 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//third_party/protobuf/proto_library.gni")
+
+proto_library("proto") {
+  sources = [ "../src/proto/securemessage.proto" ]
+  proto_out_dir = "third_party/securemessage/proto"
+}

third_party/ukey2/BUILD.gn

+# Copyright 2020 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//third_party/protobuf/proto_library.gni")
+
+proto_library("proto") {
+  sources = [
+    "src/src/main/proto/device_to_device_messages.proto",
+    "src/src/main/proto/passwordless_auth_payloads.proto",
+    "src/src/main/proto/proximity_payloads.proto",
+    "src/src/main/proto/securegcm.proto",
+    "src/src/main/proto/ukey.proto",
+  ]
+
+  proto_out_dir = "third_party/ukey2/proto"
+  import_dirs = [ "//third_party/securemessage/proto" ]
+  link_deps = [ "//third_party/securemessage/proto" ]
+  proto_deps = [ "//third_party/securemessage/proto" ]
+}
+
+config("ukey2_config") {
+  include_dirs = [
+    "$root_gen_dir/third_party/ukey2",
+    "src/src/main/cpp/include",
+  ]
+}
+
+source_set("ukey2") {
+  public_configs = [ ":ukey2_config" ]
+
+  sources = [
+    "src/src/main/cpp/src/securegcm/d2d_connection_context_v1.cc",
+    "src/src/main/cpp/src/securegcm/d2d_crypto_ops.cc",
+    "src/src/main/cpp/src/securegcm/java_util.cc",
+    "src/src/main/cpp/src/securegcm/ukey2_handshake.cc",
+  ]
+
+  public = [
+    "src/src/main/cpp/include/securegcm/d2d_connection_context_v1.h",
+    "src/src/main/cpp/include/securegcm/d2d_crypto_ops.h",
+    "src/src/main/cpp/include/securegcm/java_util.h",
+    "src/src/main/cpp/include/securegcm/ukey2_handshake.h",
+  ]
+
+  public_deps = [
+    ":proto",
+    "//third_party/securemessage",
+    "//third_party/securemessage:securemessage_cpp_protobuf",
+    "//third_party/securemessage:securemessage_openssl",
+  ]
+
+  configs -= [ "//build/config/compiler:chromium_code" ]
+  configs += [ "//build/config/compiler:no_chromium_code" ]
+}

third_party/ukey2/OWNERS

+alexchau@chromium.org
+hansberry@chromium.org
+vecore@chromium.org
+
+file://chrome/browser/nearby_sharing/OWNERS
+# COMPONENT: UI>Browser>Sharing>Nearby

third_party/ukey2/README.chromium

+Name: UKey2
+Short Name: Ukey2
+URL: https://github.com/google/ukey2
+Version: 0275885d8e6038c39b8a8ca55e75d1d4d1727f47
+License: Apache 2.0
+License File: LICENSE
+Security Critical: yes
+Description:
+Ukey2 library