Split blink/public/common/tokens to its own build target.

This lets it be depended on by components that are indirect
dependencies of blink/public/common itself, severing the circular
dependency that otherwise arises.

Change-Id: I8b0bed42775f8e17dd800ee425d701c9d85986fe
Reviewed-on: https://chromium-review.googlesource.com/c/chromium/src/+/2503230
Commit-Queue: Chris Hamilton <chrisha@chromium.org>
Reviewed-by: Kentaro Hara <haraken@chromium.org>
Cr-Commit-Position: refs/heads/master@{#822698}

third_party/blink/common/BUILD.gn

@@ -159,7 +159,6 @@ source_set("common") {
     "service_worker/service_worker_type_converters.cc",
     "switches.cc",
     "thread_safe_browser_interface_broker_proxy.cc",
-    "tokens/tokens_mojom_traits.cc",
     "unique_name/unique_name_helper.cc",
     "user_agent/user_agent_metadata.cc",
     "web_package/signed_exchange_consts.cc",
@@ -292,6 +291,7 @@ source_set("common_unittests_sources") {
     "//testing/gtest",
     "//third_party/blink/public/common:headers",
     "//third_party/blink/public/mojom/frame:frame_blink_headers",
+    "//third_party/blink/public/mojom/tokens:tokens_traits_headers",
     "//third_party/boringssl",
     "//url/mojom:url_mojom_gurl",
     "//v8",

third_party/blink/public/common/BUILD.gn

@@ -185,11 +185,6 @@ source_set("headers") {
     "sms/webotp_service_outcome.h",
     "switches.h",
     "thread_safe_browser_interface_broker_proxy.h",
-    "tokens/multi_token.h",
-    "tokens/multi_token_internal.h",
-    "tokens/token_mojom_traits_helper.h",
-    "tokens/tokens.h",
-    "tokens/tokens_mojom_traits.h",
     "unique_name/unique_name_helper.h",
     "user_agent/user_agent_metadata.h",
     "web_cache/web_cache_resource_type_stats.h",
@@ -208,6 +203,7 @@ source_set("headers") {
     "//skia",
     "//skia/public/mojom:shared_typemap_traits",
     "//third_party/blink/public/common/privacy_budget",
+    "//third_party/blink/public/common/tokens:tokens_headers",
     "//third_party/blink/public/mojom:mojom_modules_headers",
     "//third_party/blink/public/mojom:mojom_platform_shared",
     "//third_party/blink/public/mojom:web_bluetooth_mojo_bindings_headers",

third_party/blink/public/common/tokens/BUILD.gn

+# Copyright 2020 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+source_set("tokens_headers") {
+  configs += [ "//third_party/blink/common:blink_common_implementation" ]
+
+  # Note that tokens_mojom_traits.h and tokens_mojom_traits_helper.h
+  # are in the //third_party/blink/public/mojom/tokens:tokens_traits target.
+  public = [
+    "multi_token.h",
+    "multi_token_internal.h",
+    "tokens.h",
+  ]
+
+  public_deps = [
+    "//base",
+    "//mojo/public/cpp/base",
+    "//mojo/public/cpp/bindings",
+    "//mojo/public/cpp/system",
+    "//mojo/public/mojom/base",
+    "//third_party/blink/public/common:common_export",
+  ]
+}

third_party/blink/public/mojom/tokens/BUILD.gn

@@ -84,8 +84,11 @@ mojom_component("tokens") {
           cpp = "::blink::V8ContextToken"
         },
       ]
-      traits_headers =
-          [ "//third_party/blink/public/common/tokens/tokens_mojom_traits.h" ]
+      traits_headers = [
+        "//third_party/blink/public/common/tokens/token_mojom_traits_helper.h",
+        "//third_party/blink/public/common/tokens/tokens_mojom_traits.h",
+      ]
+      traits_public_deps = [ ":tokens_traits" ]
     },
   ]
 
@@ -104,3 +107,25 @@ mojom_component("tokens") {
 
   generate_java = true
 }
+
+source_set("tokens_traits_headers") {
+  configs += [ "//third_party/blink/common:blink_common_implementation" ]
+
+  sources = [
+    "//third_party/blink/public/common/tokens/token_mojom_traits_helper.h",
+    "//third_party/blink/public/common/tokens/tokens_mojom_traits.h",
+  ]
+
+  public_deps = [
+    ":tokens_shared",
+    "//third_party/blink/public/common/tokens:tokens_headers",
+  ]
+}
+
+component("tokens_traits") {
+  configs += [ "//third_party/blink/common:blink_common_implementation" ]
+
+  sources = [ "//third_party/blink/common/tokens/tokens_mojom_traits.cc" ]
+
+  public_deps = [ ":tokens_traits_headers" ]
+}