Add GN buildfiles for ui/compositor and snapshot.

Rename "//ui/base:ui_base" to "//ui/base:base" to make it easier to specify

BUG=
R=jamesr@chromium.org

Review URL: https://codereview.chromium.org/306113002

git-svn-id: svn://svn.chromium.org/chrome/trunk/src@273883 0039d316-1c4b-4281-b951-d872f2087c98

BUILD.gn

@@ -74,12 +74,13 @@ group("root") {
     "//third_party:jpeg",
     "//tools/gn",
     "//ui/accessibility",
-    "//ui/base:ui_base",
+    "//ui/base",
     "//ui/events",
     "//ui/gfx",
     "//ui/gl",
     "//ui/native_theme",
     "//ui/resources",
+    "//ui/snapshot",
     "//ui/strings",
     "//ui/surface",
     "//url",
@@ -113,6 +114,7 @@ group("root") {
       # generators (ui/gl/gl.gyp:surface_jni_headers).
       "//ui/gl",
       "//gpu",
+      "//ui/snapshot",
       "//ui/surface",
     ]
   }

components/translate/BUILD.gn

@@ -43,7 +43,7 @@ static_library("translate_core_browser") {
     # of this writing.
     deps += [
       "//net",
-      "//ui/base:ui_base",
+      "//ui/base",
     ]
   }
 }

content/browser/BUILD.gn

@@ -43,7 +43,7 @@ source_set("browser") {
     "//third_party/zlib:zip",
     "//ui/accessibility",
     "//ui/accessibility:ax_gen",
-    "//ui/base:ui_base",
+    "//ui/base",
     "//ui/events",
     "//ui/events:gesture_detection",
     "//ui/gfx",

content/common/BUILD.gn

@@ -33,7 +33,7 @@ source_set("common") {
     "//skia",
     "//third_party/icu",
     "//ui/accessibility",
-    "//ui/base:ui_base",
+    "//ui/base",
     "//ui/gfx",
     "//ui/gfx/geometry",
     "//url",

ui/base/BUILD.gn

@@ -9,7 +9,8 @@ if (is_android) {
   import("//build/config/android/rules.gni")
 }
 
-component("ui_base") {
+component("base") {
+  output_name = "ui_base"
   sources = [
     "accelerators/accelerator.cc",
     "accelerators/accelerator.h",

ui/compositor/BUILD.gn

+# Copyright 2014 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//build/config/ui.gni")
+
+component("compositor") {
+  sources = [
+    "compositor.cc",
+    "compositor.h",
+    "compositor_export.h",
+    "compositor_observer.h",
+    "compositor_vsync_manager.cc",
+    "compositor_vsync_manager.h",
+    "compositor_switches.cc",
+    "compositor_switches.h",
+    "debug_utils.cc",
+    "debug_utils.h",
+    "dip_util.cc",
+    "dip_util.h",
+    "float_animation_curve_adapter.cc",
+    "float_animation_curve_adapter.h",
+    "layer.cc",
+    "layer.h",
+    "layer_animation_delegate.h",
+    "layer_animation_element.cc",
+    "layer_animation_element.h",
+    "layer_animation_observer.cc",
+    "layer_animation_observer.h",
+    "layer_animation_sequence.cc",
+    "layer_animation_sequence.h",
+    "layer_animator.cc",
+    "layer_animator.h",
+    "layer_delegate.h",
+    "layer_owner.cc",
+    "layer_owner.h",
+    "layer_tree_owner.cc",
+    "layer_tree_owner.h",
+    "layer_type.h",
+    "reflector.h",
+    "scoped_animation_duration_scale_mode.cc",
+    "scoped_animation_duration_scale_mode.h",
+    "scoped_layer_animation_settings.cc",
+    "scoped_layer_animation_settings.h",
+    "transform_animation_curve_adapter.cc",
+    "transform_animation_curve_adapter.h",
+  ]
+
+  defines = [ "COMPOSITOR_IMPLEMENTATION" ]
+
+  deps = [
+    "//base",
+    "//base/third_party/dynamic_annotations",
+    "//cc",
+    "//gpu/command_buffer/common",
+    "//skia",
+    "//ui/gfx",
+    "//ui/gfx/geometry",
+    "//ui/gl",
+  ]
+
+  if (is_win && use_aura) {
+    # TODO(sky): before we make this real need to remove
+    # IDR_BITMAP_BRUSH_IMAGE.
+    deps += [
+      "//ui/resources",
+      "//third_party/angle:libEGL",
+      "//third_party/angle:libGLESv2",
+    ]
+  }
+}
+
+source_set("test_support") {
+  sources = [
+    "test/context_factories_for_test.cc",
+    "test/context_factories_for_test.h",
+    "test/draw_waiter_for_test.cc",
+    "test/draw_waiter_for_test.h",
+    "test/in_process_context_factory.cc",
+    "test/in_process_context_factory.h",
+    "test/layer_animator_test_controller.cc",
+    "test/layer_animator_test_controller.h",
+    "test/test_compositor_host.h",
+    "test/test_compositor_host_mac.mm",
+    "test/test_compositor_host_ozone.cc",
+    "test/test_compositor_host_win.cc",
+    "test/test_compositor_host_x11.cc",
+    "test/test_layer_animation_delegate.cc",
+    "test/test_layer_animation_delegate.h",
+    "test/test_layer_animation_observer.cc",
+    "test/test_layer_animation_observer.h",
+    "test/test_layers.cc",
+    "test/test_layers.h",
+    "test/test_suite.cc",
+    "test/test_suite.h",
+    "test/test_utils.cc",
+    "test/test_utils.h",
+  ]
+
+  deps = [
+    ":compositor",
+    "//base",
+    "//cc",
+    "//cc:test_support",
+    "//skia",
+    "//testing/gtest",
+    #"//third_party/WebKit/public:blink_minimal",  TODO(GYP)
+    "//ui/base",
+    "//ui/gfx",
+    "//ui/gfx/geometry",
+    "//ui/gl",
+    #'<(DEPTH)/webkit/common/gpu/webkit_gpu.gyp:webkit_gpu',  TODO(GYP)
+  ]
+
+  if (use_x11) {
+    configs += [ "//build/config/linux:x11" ]
+    deps += [ "//ui/gfx:gfx_x11" ]
+  }
+}
+
+# TODO(GYP) enable this when all dependencies are complete and it links.
+#test("compositor_unittests") {
+#  sources = [
+#    "layer_animation_element_unittest.cc",
+#    "layer_animation_sequence_unittest.cc",
+#    "layer_animator_unittest.cc",
+#    "layer_owner_unittest.cc",
+#    "layer_unittest.cc",
+#    "run_all_unittests.cc",
+#    "transform_animation_curve_adapter_unittest.cc",
+#  ]
+#
+#  deps = [
+#    ":compositor",
+#    ":test_support",
+#    "//base",
+#    "//base/allocator",
+#    "//base/test:test_support",
+#    "//cc",
+#    "//cc:test_support",
+#    "//skia",
+#    "//testing/gtest",
+#    "//ui/base",
+#    "//ui/gfx",
+#    "//ui/gfx/geometry",
+#    "//ui/gl",
+#    "//ui/resources",
+#  ]
+#
+#  if (is_linux) {
+#    #deps += [ "//third_party/mesa:osmesa" ]  # TODO(GYP)
+#  }
+#}

ui/native_theme/BUILD.gn

@@ -48,7 +48,7 @@ component("native_theme") {
     "//base",
     "//base/third_party/dynamic_annotations",
     "//skia",
-    "//ui/base:ui_base",
+    "//ui/base",
     "//ui/gfx",
     "//ui/gfx/geometry",
     "//ui/resources",

ui/ozone/BUILD.gn

@@ -31,7 +31,7 @@ component("ozone") {
     ":generate_ozone_platform_list",
     "//base",
     "//skia",
-    "//ui/base:ui_base",
+    "//ui/base",
     "//ui/events",
     "//ui/gfx",
     "//ui/gfx/geometry",

ui/snapshot/BUILD.gn

+# Copyright 2014 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//build/config/ui.gni")
+
+component("snapshot") {
+  sources = [
+    "snapshot.h",
+    "snapshot_android.cc",
+    "snapshot_async.cc",
+    "snapshot_async.h",
+    "snapshot_aura.cc",
+    "snapshot_export.h",
+    "snapshot_ios.mm",
+    "snapshot_mac.mm",
+    "snapshot_win.cc",
+    "snapshot_win.h",
+  ]
+
+  defines = [ "SNAPSHOT_IMPLEMENTATION" ]
+
+  deps = [
+    "//base",
+    "//skia",
+    "//ui/base",
+    "//ui/gfx",
+    "//ui/gfx/geometry",
+  ]
+
+  if (use_aura || is_android) {
+    deps += [
+      "//cc",
+      "//gpu/command_buffer/common",
+    ]
+  } else {
+    sources -= [
+      "snapshot_async.cc",
+      "snapshot_async.h",
+    ]
+  }
+
+  if (use_aura) {
+    deps += [
+      #"//ui/aura",  TODO(GYP)
+      "//ui/compositor",
+    ]
+  }
+}
+
+# TODO(GYP) enable this when all targets are converted and it links
+#test("snapshot_unittests") {
+#  sources = [
+#    "snapshot_aura_unittest.cc",
+#    "snapshot_mac_unittest.mm",
+#    "test/run_all_unittests.cc",
+#  ]
+#
+#  deps = [
+#    "//base",
+#    "//base/allocator",
+#    "//base/test:test_support",
+#    "//skia",
+#    "//testing/gtest",
+#    "//ui/base",
+#    "//ui/gfx",
+#    "//ui/gfx/geometry",
+#  ]
+#
+#  if (use_aura) {
+#    deps += [
+#      #"//ui/aura:test_support",  TODO(GYP)
+#      "//ui/compositor",
+#      "//ui/compositor:test_support",
+#    ]
+#  } else {
+#    sources -= [ "snapshot_aura_unittest.cc" ]
+#  }
+#}
+
+if (is_win) {
+  source_set("test_support") {
+    sources = [
+      "test/snapshot_desktop.h",
+      "test/snapshot_desktop_win.cc",
+    ]
+    deps = [
+      ":snapshot",
+    ]
+  }
+}

ui/surface/BUILD.gn

@@ -21,7 +21,7 @@ component("surface") {
     "//base",
     "//base/third_party/dynamic_annotations",
     "//skia",
-    "//ui/base:ui_base",
+    "//ui/base",
     "//ui/gfx/geometry",
     "//ui/gl",
   ]