GN: Start of //third_party/WebKit/Source/web

The make_file_arrays template should probably go in Source/build/ since it
is also used in modules and on mac I'm getting override errors in clang,
but this is a start. Most things compile.

R=brettw@chromium.org

Review URL: https://codereview.chromium.org/337703003

git-svn-id: svn://svn.chromium.org/blink/trunk@176346 bbb929c8-8fbe-4397-9dbb-9b2b20218538

third_party/WebKit/Source/build/make_file_arrays.gni

+# Copyright 2014 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+template("make_file_arrays") {
+  assert(defined(invoker.resources), "Need resources in %target_name")
+  assert(defined(invoker.filename), "Need filename in %target_name")
+
+  code_gen_target_name = target_name + "_code_gen"
+
+  action(code_gen_target_name) {
+    source_prereqs = invoker.resources
+    script = "//third_party/WebKit/Source/build/scripts/make-file-arrays.py"
+    sources = [ script ]
+    sources += invoker.resources
+    outputs = [
+      "$root_gen_dir/blink/" + invoker.filename + ".h",
+      "$root_gen_dir/blink/" + invoker.filename + ".cpp",
+    ]
+    args = [
+      "--out-h=gen/blink/" + invoker.filename + ".h",
+      "--out-cpp=gen/blink/" + invoker.filename + ".cpp",
+    ]
+    args += rebase_path(invoker.resources, root_build_dir, ".")
+  }
+
+  source_set(target_name) {
+    sources = get_target_outputs(":$code_gen_target_name")
+    deps = [ ":$code_gen_target_name" ]
+  }
+}
+
+

third_party/WebKit/Source/web/BUILD.gn

+# Copyright 2014 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//build/config/ui.gni")
+import("//third_party/WebKit/Source/config.gni")
+import("//third_party/WebKit/Source/build/make_file_arrays.gni")
+
+web_gypi = exec_script(
+    "//build/gypi_to_gn.py",
+    [ rebase_path("web.gypi") ],
+    "scope",
+    [ "web.gypi" ])
+
+component("web") {
+  output_name = "blink_web"
+
+  deps = [
+    ":calendar_picker",
+    ":picker_common",
+    ":color_suggestion_picker",
+    "//third_party/WebKit/Source/core",
+    "//third_party/WebKit/Source/platform",
+#"//third_party/WebKit/Source/modules",
+    "//skia",
+    "//third_party/icu",
+    "//v8",
+    "//third_party/angle:translator",
+  ]
+
+  include_dirs = [
+    "//third_party/skia/include/utils",
+  ]
+
+  configs -= [ "//build/config/compiler:chromium_code" ]
+  configs += [
+    "//build/config/compiler:no_chromium_code",
+    "//third_party/WebKit/Source:config",
+    "//third_party/WebKit/Source:inside_blink",
+    "//third_party/WebKit/Source:non_test_config",
+  ]
+
+  sources = web_gypi.web_files
+}
+
+make_file_arrays("picker_common") {
+  resources = [
+    "resources/pickerCommon.css",
+    "resources/pickerCommon.js",
+  ]
+  filename = "PickerCommon"
+}
+
+make_file_arrays("color_suggestion_picker") {
+  resources = [
+    "resources/colorSuggestionPicker.css",
+    "resources/colorSuggestionPicker.js",
+  ]
+  filename = "ColorSuggestionPicker"
+}
+
+make_file_arrays("calendar_picker") {
+  resources = [
+    "resources/calendarPicker.css",
+    "resources/calendarPicker.js",
+    "resources/pickerButton.css",
+    "resources/suggestionPicker.css",
+    "resources/suggestionPicker.js",
+  ]
+  filename = "CalendarPicker"
+}