Save and expose additional data about the previous application session.

Adds device thermal state, low power mode, and whether or not the OS was updated
between the previous and current session.

Bug: 965393
Change-Id: Ibb91efe391a10daa983aafe56e93a9d4e02fa114
Reviewed-on: https://chromium-review.googlesource.com/c/chromium/src/+/1621710
Commit-Queue: Mike Dougherty <michaeldo@chromium.org>
Reviewed-by: Olivier Robin <olivierrobin@chromium.org>
Cr-Commit-Position: refs/heads/master@{#662714}

ios/chrome/browser/metrics/previous_session_info.h

@@ -10,6 +10,18 @@
 namespace previous_session_info_constants {
 // Key in the UserDefaults for a boolean value keeping track of memory warnings.
 extern NSString* const kDidSeeMemoryWarningShortlyBeforeTerminating;
+
+// The values of this enum are persisted representing the state of the last
+// session (which may have been running a different version of the application).
+// Therefore, entries should not be renumbered and numeric values should never
+// be reused.
+enum class DeviceThermalState {
+  kUnknown = 0,
+  kNominal = 1,
+  kFair = 2,
+  kSerious = 3,
+  kCritical = 4,
+};
 }  // namespace previous_session_info_constants
 
 // PreviousSessionInfo has two jobs:
@@ -19,10 +31,21 @@ extern NSString* const kDidSeeMemoryWarningShortlyBeforeTerminating;
 // - Persist information about the current session, for use in a next session.
 @interface PreviousSessionInfo : NSObject
 
+// The thermal state of the device at the end of the previous session.
+@property(nonatomic, assign, readonly)
+    previous_session_info_constants::DeviceThermalState deviceThermalState;
+
+// Whether the device was in low power mode at the end of the previous session.
+@property(nonatomic, assign, readonly) BOOL deviceWasInLowPowerMode;
+
 // Whether the app received a memory warning seconds before being terminated.
 @property(nonatomic, assign, readonly)
     BOOL didSeeMemoryWarningShortlyBeforeTerminating;
 
+// Whether or not the system OS was updated between the previous and the
+// current session.
+@property(nonatomic, assign, readonly) BOOL isFirstSessionAfterOSUpgrade;
+
 // Whether the app was updated between the previous and the current session.
 @property(nonatomic, assign, readonly) BOOL isFirstSessionAfterUpgrade;
 
@@ -39,6 +62,12 @@ extern NSString* const kDidSeeMemoryWarningShortlyBeforeTerminating;
 // persisting information about the current session, for use in a next session.
 - (void)beginRecordingCurrentSession;
 
+// Updates the saved last known low power mode setting of the device.
+- (void)updateStoredLowPowerMode;
+
+// Updates the saved last known thermal state of the device.
+- (void)updateStoredThermalState;
+
 // When a session has begun, records that a memory warning was received.
 - (void)setMemoryWarningFlag;
 

ios/chrome/browser/metrics/previous_session_info.mm

@@ -6,6 +6,7 @@
 
 #include "base/logging.h"
 #include "base/strings/sys_string_conversions.h"
+#include "base/system/sys_info.h"
 #include "components/version_info/version_info.h"
 #import "ios/chrome/browser/metrics/previous_session_info_private.h"
 
@@ -13,15 +14,41 @@
 #error "This file requires ARC support."
 #endif
 
+using previous_session_info_constants::DeviceThermalState;
+
 namespace {
 
-// Key in the NSUserDefaults for a string value that stores the version of the
-// last session.
-NSString* const kLastRanVersion = @"LastRanVersion";
+// Translates a NSProcessInfoThermalState value to DeviceThermalState value.
+DeviceThermalState GetThermalStateFromNSProcessInfoThermalState(
+    NSProcessInfoThermalState process_info_thermal_state) {
+  switch (process_info_thermal_state) {
+    case NSProcessInfoThermalStateNominal:
+      return DeviceThermalState::kNominal;
+    case NSProcessInfoThermalStateFair:
+      return DeviceThermalState::kFair;
+    case NSProcessInfoThermalStateSerious:
+      return DeviceThermalState::kSerious;
+    case NSProcessInfoThermalStateCritical:
+      return DeviceThermalState::kCritical;
+  }
 
-// Key in the NSUserDefaults for a string value that stores the language of the
-// last session.
+  return DeviceThermalState::kUnknown;
+}
+
+// NSUserDefaults keys.
+// - The (string) application version.
+NSString* const kLastRanVersion = @"LastRanVersion";
+// - The (string) device language.
 NSString* const kLastRanLanguage = @"LastRanLanguage";
+// - The (string) OS version.
+NSString* const kPreviousSessionInfoOSVersion = @"PreviousSessionInfoOSVersion";
+// - The (integer) underlying value of the DeviceThermalState enum representing
+//   the device thermal state.
+NSString* const kPreviousSessionInfoThermalState =
+    @"PreviousSessionInfoThermalState";
+// - A (boolean) describing whether or not low power mode is enabled.
+NSString* const kPreviousSessionInfoLowPowerMode =
+    @"PreviousSessionInfoLowPowerMode";
 
 }  // namespace
 
@@ -36,7 +63,10 @@ NSString* const kDidSeeMemoryWarningShortlyBeforeTerminating =
 @property(nonatomic, assign) BOOL didBeginRecordingCurrentSession;
 
 // Redefined to be read-write.
+@property(nonatomic, assign) DeviceThermalState deviceThermalState;
+@property(nonatomic, assign) BOOL deviceWasInLowPowerMode;
 @property(nonatomic, assign) BOOL didSeeMemoryWarningShortlyBeforeTerminating;
+@property(nonatomic, assign) BOOL isFirstSessionAfterOSUpgrade;
 @property(nonatomic, assign) BOOL isFirstSessionAfterUpgrade;
 @property(nonatomic, assign) BOOL isFirstSessionAfterLanguageChange;
 
@@ -44,9 +74,12 @@ NSString* const kDidSeeMemoryWarningShortlyBeforeTerminating =
 
 @implementation PreviousSessionInfo
 
+@synthesize deviceThermalState = _deviceThermalState;
+@synthesize deviceWasInLowPowerMode = _deviceWasInLowPowerMode;
 @synthesize didBeginRecordingCurrentSession = _didBeginRecordingCurrentSession;
 @synthesize didSeeMemoryWarningShortlyBeforeTerminating =
     _didSeeMemoryWarningShortlyBeforeTerminating;
+@synthesize isFirstSessionAfterOSUpgrade = _isFirstSessionAfterOSUpgrade;
 @synthesize isFirstSessionAfterUpgrade = _isFirstSessionAfterUpgrade;
 @synthesize isFirstSessionAfterLanguageChange =
     _isFirstSessionAfterLanguageChange;
@@ -63,6 +96,18 @@ static PreviousSessionInfo* gSharedInstance = nil;
     gSharedInstance.didSeeMemoryWarningShortlyBeforeTerminating =
         [defaults boolForKey:previous_session_info_constants::
                                  kDidSeeMemoryWarningShortlyBeforeTerminating];
+    gSharedInstance.deviceWasInLowPowerMode =
+        [defaults boolForKey:kPreviousSessionInfoLowPowerMode];
+    gSharedInstance.deviceThermalState = static_cast<DeviceThermalState>(
+        [defaults integerForKey:kPreviousSessionInfoThermalState]);
+
+    NSString* versionOfOSAtLastRun =
+        [defaults stringForKey:kPreviousSessionInfoOSVersion];
+    NSString* currentOSVersion =
+        base::SysUTF8ToNSString(base::SysInfo::OperatingSystemVersion());
+    gSharedInstance.isFirstSessionAfterOSUpgrade =
+        ![versionOfOSAtLastRun isEqualToString:currentOSVersion];
+
     NSString* lastRanVersion = [defaults stringForKey:kLastRanVersion];
     NSString* currentVersion =
         base::SysUTF8ToNSString(version_info::GetVersionNumber());
@@ -88,12 +133,17 @@ static PreviousSessionInfo* gSharedInstance = nil;
 
   NSUserDefaults* defaults = [NSUserDefaults standardUserDefaults];
 
-  // Set the new version.
+  // Set the current Chrome version.
   NSString* currentVersion =
       base::SysUTF8ToNSString(version_info::GetVersionNumber());
   [defaults setObject:currentVersion forKey:kLastRanVersion];
 
-  // Set the new language.
+  // Set the current OS version.
+  NSString* currentOSVersion =
+      base::SysUTF8ToNSString(base::SysInfo::OperatingSystemVersion());
+  [defaults setObject:currentOSVersion forKey:kPreviousSessionInfoOSVersion];
+
+  // Set the current language.
   NSString* currentLanguage = [[NSLocale preferredLanguages] objectAtIndex:0];
   [defaults setObject:currentLanguage forKey:kLastRanLanguage];
 
@@ -102,10 +152,46 @@ static PreviousSessionInfo* gSharedInstance = nil;
       removeObjectForKey:previous_session_info_constants::
                              kDidSeeMemoryWarningShortlyBeforeTerminating];
 
+  [self updateStoredLowPowerMode];
+  [[NSNotificationCenter defaultCenter]
+      addObserver:self
+         selector:@selector(updateStoredLowPowerMode)
+             name:NSProcessInfoPowerStateDidChangeNotification
+           object:nil];
+
+  [self updateStoredThermalState];
+  [[NSNotificationCenter defaultCenter]
+      addObserver:self
+         selector:@selector(updateStoredThermalState)
+             name:NSProcessInfoThermalStateDidChangeNotification
+           object:nil];
+
   // Save critical state information for crash detection.
   [defaults synchronize];
 }
 
+- (void)updateStoredLowPowerMode {
+  BOOL isLowPoweredModeEnabled =
+      [[NSProcessInfo processInfo] isLowPowerModeEnabled];
+  [[NSUserDefaults standardUserDefaults]
+      setInteger:isLowPoweredModeEnabled
+          forKey:kPreviousSessionInfoLowPowerMode];
+}
+
+- (void)updateStoredThermalState {
+  NSProcessInfo* processInfo = [NSProcessInfo processInfo];
+  // Translate value to an app defined enum as the system could change the
+  // underlying values of NSProcessInfoThermalState between OS versions.
+  DeviceThermalState thermalState =
+      GetThermalStateFromNSProcessInfoThermalState([processInfo thermalState]);
+  NSInteger thermalStateValue =
+      static_cast<std::underlying_type<DeviceThermalState>::type>(thermalState);
+
+  [[NSUserDefaults standardUserDefaults]
+      setInteger:thermalStateValue
+          forKey:kPreviousSessionInfoThermalState];
+}
+
 - (void)setMemoryWarningFlag {
   if (!self.didBeginRecordingCurrentSession)
     return;