Port android_webview_tests.gypi to GN.

BUG=532905

Review URL: https://codereview.chromium.org/1547683003

Cr-Commit-Position: refs/heads/master@{#367035}

BUILD.gn

@@ -310,6 +310,7 @@ group("both_gn_and_gyp") {
     if (!is_chromecast) {
       deps += [
         "//android_webview",
+        "//android_webview/test",
         "//chrome/android:chrome_junit_tests",
         "//chrome/android:chrome_public_apk",
         "//chrome/android:chrome_public_test_apk",

android_webview/BUILD.gn

@@ -112,7 +112,7 @@ repack("repack_pack") {
 
 webview_license_path = "$target_gen_dir/webview_licenses.notice"
 
-android_assets("uncompressed_assets") {
+android_assets("pak_file_assets") {
   sources = [
     "$target_gen_dir/webviewchromium.pak",
   ]
@@ -128,7 +128,7 @@ android_assets("assets") {
   ]
   deps = [
     ":generate_webview_license_notice",
-    ":uncompressed_assets",
+    ":pak_file_assets",
     "//third_party/icu:icu_assets",
     "//v8:v8_external_startup_data_assets",
   ]

android_webview/android_webview_tests.gypi

@@ -3,6 +3,7 @@
 # found in the LICENSE file.
 {
   'targets': [
+    # GN: //android_webview/test:android_webview_apk
     {
       'target_name': 'android_webview_apk',
       'type': 'none',
@@ -93,6 +94,7 @@
       ],
       'includes': [ '../build/apk_fake_jar.gypi' ],
     },
+    # GN: //android_webview/test:android_webview_test_apk
     {
       'target_name': 'android_webview_test_apk',
       'type': 'none',
@@ -117,6 +119,7 @@
         '../build/android/test_runner.gypi',
       ],
     },
+    # GN: //android_webview/test:android_webview_unittests
     {
       'target_name': 'android_webview_unittests',
       'type': '<(gtest_target_type)',
@@ -157,6 +160,7 @@
         'native/state_serializer_unittest.cc',
       ],
     },
+    # GN: //android_webview/test:android_webview_unittest_java
     {
       'target_name': 'android_webview_unittest_java',
       'type': 'none',
@@ -170,6 +174,7 @@
       },
       'includes': [ '../build/java.gypi' ],
     },
+    # GN: //android_webview/test:android_webview_unittests_jni
     {
       'target_name': 'android_webview_unittests_jni',
       'type': 'none',
@@ -182,6 +187,7 @@
       },
       'includes': [ '../build/jni_generator.gypi' ],
     },
+    # GN: //android_webview/test:android_webview_unittests_apk
     {
       'target_name': 'android_webview_unittests_apk',
       'type': 'none',
@@ -205,6 +211,7 @@
       ],
       'includes': [ '../build/apk_test.gypi' ],
     },
+    # GN: //android_webview/test:libdrawgl
     {
       'target_name': 'libdrawgl',
       'type': 'shared_library',
@@ -222,6 +229,7 @@
           '../android_webview/test/shell/src/draw_gl/draw_gl.cc',
       ],
     },
+    # GN: //android_webview/test:libstandalonelibwebviewchromium
     {
       'target_name': 'libstandalonelibwebviewchromium',
       'includes': [

android_webview/test/BUILD.gn

+# Copyright 2015 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//build/config/android/rules.gni")
+import("//testing/test.gni")
+
+# Mark all targets as test only.
+testonly = true
+
+group("test") {
+  deps = [
+    ":android_webview_test_apk",
+    ":android_webview_unittests",
+  ]
+}
+
+# GYP: //android_webview/android_webview_tests.gypi:android_webview_apk
+android_apk("android_webview_apk") {
+  deps = [
+    ":android_webview_apk_assets",
+    ":android_webview_apk_resources",
+    ":libdrawgl",
+    ":libstandalonelibwebviewchromium",
+    "//android_webview:android_webview_java",
+    "//base:base_java",
+    "//base:base_java_test_support",
+    "//components/policy/android:policy_java_test_support",
+    "//content/public/android:content_java",
+    "//ui/android:ui_java",
+  ]
+
+  apk_name = "AndroidWebView"
+  android_manifest = "shell/AndroidManifest.xml"
+  DEPRECATED_java_in_dir = "shell/src"
+  native_libs = [
+    "libdrawgl.so",
+    "libstandalonelibwebviewchromium.so",
+  ]
+
+  native_lib_version_rule = "//build/util:chrome_version_json"
+  _native_lib_file =
+      rebase_path("$root_gen_dir/CHROME_VERSION.json", root_build_dir)
+  native_lib_version_arg = "@FileArg($_native_lib_file:full-quoted)"
+
+  extensions_to_not_compress = ".dat,.bin,.pak,.lpak"
+}
+
+android_resources("android_webview_apk_resources") {
+  resource_dirs = [ "shell/res" ]
+  custom_package = "org.chromium.android_webview.shell"
+}
+
+android_assets("android_webview_apk_assets") {
+  deps = [
+    "//android_webview:pak_file_assets",
+    "//third_party/icu:icu_assets",
+    "//v8:v8_external_startup_data_assets",
+  ]
+  sources = [
+    "shell/assets/asset_file.html",
+    "shell/assets/asset_icon.png",
+    "shell/assets/cookie_test.html",
+    "shell/assets/full_screen_video.js",
+    "shell/assets/full_screen_video_inside_div_test.html",
+    "shell/assets/full_screen_video_test.html",
+    "shell/assets/multiple_videos_test.html",
+    "shell/assets/video.mp4",
+    "shell/assets/visual_state_during_fullscreen_test.html",
+    "shell/assets/visual_state_on_page_commit_visible_test.html",
+    "shell/assets/visual_state_waits_for_js_detached_test.html",
+    "shell/assets/visual_state_waits_for_js_test.html",
+  ]
+}
+
+# GYP: //android_webview/android_webview_tests.gypi:libstandalonelibwebviewchromium
+shared_library("libstandalonelibwebviewchromium") {
+  sources = [
+    "../lib/main/webview_entry_point.cc",
+  ]
+  ldflags = [ "-Wl,-shared,-Bsymbolic" ]
+  deps = [
+    "//android_webview:common",
+  ]
+  configs -= [ "//build/config/android:hide_native_jni_exports" ]
+}
+
+# GYP: //android_webview/android_webview_tests.gypi:android_webview_test_apk
+instrumentation_test_apk("android_webview_test_apk") {
+  apk_name = "AndroidWebViewTest"
+  apk_under_test = ":android_webview_apk"
+  android_manifest = "../javatests/AndroidManifest.xml"
+  deps = [
+    "//android_webview:android_webview_java",
+    "//base:base_java",
+    "//base:base_java_test_support",
+    "//components/external_video_surface:java",
+    "//components/policy/android:policy_java",
+    "//components/policy/android:policy_java_test_support",
+    "//components/web_contents_delegate_android:web_contents_delegate_android_java",
+    "//content/public/android:content_java",
+    "//content/public/test/android:content_java_test_support",
+    "//net/android:net_java",
+    "//net/android:net_java_test_support",
+    "//third_party/android_tools:legacy_http_javalib",
+    "//ui/android:ui_java",
+  ]
+  DEPRECATED_java_in_dir = "../javatests/src"
+  isolate_file = "../android_webview_test_apk.isolate"
+}
+
+# GYP: //android_webview/android_webview_tests.gypi:android_webview_unittests
+test("android_webview_unittests") {
+  deps = [
+    ":android_webview_unittests_assets",
+    ":android_webview_unittests_java",
+    ":android_webview_unittests_jni",
+    "//android_webview:common",
+    "//base/test:test_support",
+    "//content/test:test_support",
+    "//net:test_support",
+    "//ui/base:ui_base_jni_headers",
+    "//ui/gl",
+    "//ui/gl:test_support",
+  ]
+
+  sources = [
+    "../browser/aw_form_database_service_unittest.cc",
+    "../browser/aw_static_cookie_policy_unittest.cc",
+    "../browser/browser_view_renderer_unittest.cc",
+    "../browser/net/android_stream_reader_url_request_job_unittest.cc",
+    "../browser/net/input_stream_reader_unittest.cc",
+    "../browser/test/fake_window.cc",
+    "../browser/test/fake_window.h",
+    "../browser/test/rendering_test.cc",
+    "../browser/test/rendering_test.h",
+    "../lib/main/webview_tests.cc",
+    "../native/aw_contents_client_bridge_unittest.cc",
+    "../native/aw_media_url_interceptor_unittest.cc",
+    "../native/input_stream_unittest.cc",
+    "../native/permission/media_access_permission_request_unittest.cc",
+    "../native/permission/permission_request_handler_unittest.cc",
+    "../native/state_serializer_unittest.cc",
+  ]
+}
+
+android_assets("android_webview_unittests_assets") {
+  sources = [
+    "unittest/assets/asset_file.ogg",
+  ]
+}
+
+# GYP: //android_webview/android_webview_tests.gypi:android_webview_unittests_java
+android_library("android_webview_unittests_java") {
+  deps = [
+    "//android_webview:android_webview_java",
+    "//base:base_java",
+    "//base:base_java_test_support",
+    "//content/public/test/android:content_java_test_support",
+  ]
+  DEPRECATED_java_in_dir = "../unittestjava/src"
+}
+
+# GYP: //android_webview/android_webview_tests.gypi:android_webview_unittests_jni
+generate_jni("android_webview_unittests_jni") {
+  jni_package = "android_webview_unittests"
+  sources = [
+    "../unittestjava/src/org/chromium/android_webview/unittest/InputStreamUnittest.java",
+    "../unittestjava/src/org/chromium/android_webview/unittest/MockAwContentsClientBridge.java",
+  ]
+}
+
+# GYP: //android_webview/android_webview_tests.gypi:libdrawgl
+shared_library("libdrawgl") {
+  sources = [
+    "shell/src/draw_gl/draw_gl.cc",
+  ]
+  configs -= [ "//build/config/android:hide_native_jni_exports" ]
+}