[ios] Add disclosure accessory view to Recent Tabs section headers.

Only adds the accessory. No rotation happens when toggling between collapsing/showing the sections.
Rotation will be in future CL.

Bug: 825017
Cq-Include-Trybots: master.tryserver.chromium.mac:ios-simulator-cronet;master.tryserver.chromium.mac:ios-simulator-full-configs
Change-Id: Idca5bd47ca06db6ef394b40690e2c3dd0c83345b
Reviewed-on: https://chromium-review.googlesource.com/987094
Commit-Queue: Chris Lu <thegreenfrog@google.com>
Reviewed-by: Rohit Rao <rohitrao@chromium.org>
Reviewed-by: Sergio Collazos <sczs@chromium.org>
Cr-Commit-Position: refs/heads/master@{#548593}

ios/chrome/browser/ui/recent_tabs/recent_tabs_table_view_controller.mm

@@ -31,8 +31,8 @@
 #include "ios/chrome/browser/ui/ntp/recent_tabs/synced_sessions.h"
 #import "ios/chrome/browser/ui/settings/sync_utils/sync_presenter.h"
 #import "ios/chrome/browser/ui/signin_interaction/public/signin_presenter.h"
+#import "ios/chrome/browser/ui/table_view/cells/table_view_disclosure_header_footer_item.h"
 #import "ios/chrome/browser/ui/table_view/cells/table_view_signin_promo_item.h"
-#import "ios/chrome/browser/ui/table_view/cells/table_view_text_header_footer_item.h"
 #import "ios/chrome/browser/ui/table_view/cells/table_view_text_item.h"
 #import "ios/chrome/browser/ui/table_view/cells/table_view_url_item.h"
 #include "ios/chrome/browser/ui/ui_util.h"
@@ -178,8 +178,9 @@ const int kRelativeTimeMaxHours = 4;
   [model addSectionWithIdentifier:SectionIdentifierRecentlyClosedTabs];
   [model setSectionIdentifier:SectionIdentifierRecentlyClosedTabs
                  collapsedKey:kRecentlyClosedCollapsedKey];
-  TableViewTextHeaderFooterItem* header = [[TableViewTextHeaderFooterItem alloc]
-      initWithType:ItemTypeRecentlyClosedHeader];
+  TableViewDisclosureHeaderFooterItem* header =
+      [[TableViewDisclosureHeaderFooterItem alloc]
+          initWithType:ItemTypeRecentlyClosedHeader];
   header.text = l10n_util::GetNSString(IDS_IOS_RECENT_TABS_RECENTLY_CLOSED);
   [model setHeader:header
       forSectionWithIdentifier:SectionIdentifierRecentlyClosedTabs];
@@ -283,8 +284,8 @@ const int kRelativeTimeMaxHours = 4;
     NSString* sessionCollapsedKey = base::SysUTF8ToNSString(session->tag);
     [model setSectionIdentifier:sessionIdentifier
                    collapsedKey:sessionCollapsedKey];
-    TableViewTextHeaderFooterItem* header =
-        [[TableViewTextHeaderFooterItem alloc]
+    TableViewDisclosureHeaderFooterItem* header =
+        [[TableViewDisclosureHeaderFooterItem alloc]
             initWithType:ItemTypeSessionHeader];
     header.text = base::SysUTF8ToNSString(session->name);
     header.subtitleText = l10n_util::GetNSStringF(
@@ -374,8 +375,9 @@ const int kRelativeTimeMaxHours = 4;
   [model addSectionWithIdentifier:SectionIdentifierOtherDevices];
   [model setSectionIdentifier:SectionIdentifierOtherDevices
                  collapsedKey:kOtherDeviceCollapsedKey];
-  TableViewTextHeaderFooterItem* header = [[TableViewTextHeaderFooterItem alloc]
-      initWithType:ItemTypeRecentlyClosedHeader];
+  TableViewDisclosureHeaderFooterItem* header =
+      [[TableViewDisclosureHeaderFooterItem alloc]
+          initWithType:ItemTypeRecentlyClosedHeader];
   header.text = l10n_util::GetNSString(IDS_IOS_RECENT_TABS_OTHER_DEVICES);
   [model setHeader:header
       forSectionWithIdentifier:SectionIdentifierOtherDevices];
@@ -776,8 +778,9 @@ const int kRelativeTimeMaxHours = 4;
         sectionForSectionIdentifier:self.lastTappedHeaderSectionIdentifier];
     UITableViewHeaderFooterView* headerView =
         [self.tableView headerViewForSection:section];
-    TableViewTextHeaderFooterView* headerTextView =
-        base::mac::ObjCCastStrict<TableViewTextHeaderFooterView>(headerView);
+    TableViewDisclosureHeaderFooterView* headerTextView =
+        base::mac::ObjCCastStrict<TableViewDisclosureHeaderFooterView>(
+            headerView);
     [headerTextView animateHighlight];
   }
 }
@@ -832,8 +835,9 @@ const int kRelativeTimeMaxHours = 4;
         sectionForSectionIdentifier:self.lastTappedHeaderSectionIdentifier];
     UITableViewHeaderFooterView* headerView =
         [self.tableView headerViewForSection:section];
-    TableViewTextHeaderFooterView* headerTextView =
-        base::mac::ObjCCastStrict<TableViewTextHeaderFooterView>(headerView);
+    TableViewDisclosureHeaderFooterView* headerTextView =
+        base::mac::ObjCCastStrict<TableViewDisclosureHeaderFooterView>(
+            headerView);
     [headerTextView animateHighlight];
 
     web::ContextMenuParams params;

ios/chrome/browser/ui/table_view/cells/BUILD.gn

@@ -4,6 +4,10 @@
 
 source_set("cells") {
   sources = [
+    "table_view_cells_constants.h",
+    "table_view_cells_constants.mm",
+    "table_view_disclosure_header_footer_item.h",
+    "table_view_disclosure_header_footer_item.mm",
     "table_view_header_footer_item.h",
     "table_view_header_footer_item.mm",
     "table_view_item.h",
@@ -19,7 +23,9 @@ source_set("cells") {
   ]
 
   deps = [
+    "resources:table_view_cell_chevron",
     "//base",
+    "//ios/chrome/browser/ui:ui_util",
     "//ios/chrome/browser/ui/authentication:authentication_ui",
     "//ios/chrome/browser/ui/list_model",
     "//ios/chrome/browser/ui/table_view:styler",

ios/chrome/browser/ui/table_view/cells/resources/table_view_cell_chevron.imageset/Contents.json

@@ -8,12 +8,12 @@
         {
             "idiom": "universal",
             "scale": "2x",
-            "filename": "table_view_cell_chevron_@2x.png"
+            "filename": "table_view_cell_chevron@2x.png"
         },
         {
             "idiom": "universal",
             "scale": "3x",
-            "filename": "table_view_cell_chevron_@3x.png"
+            "filename": "table_view_cell_chevron@3x.png"
         }
     ],
     "info": {

ios/chrome/browser/ui/table_view/cells/table_view_cells_constants.h

+// Copyright 2018 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#ifndef IOS_CHROME_BROWSER_UI_TABLE_VIEW_CELLS_TABLE_VIEW_CELLS_CONSTANTS_H_
+#define IOS_CHROME_BROWSER_UI_TABLE_VIEW_CELLS_TABLE_VIEW_CELLS_CONSTANTS_H_
+
+#import <UIKit/UIKit.h>
+
+// The spacing between views inside of a cell.
+extern const CGFloat kTableViewCellViewSpacing;
+
+// The vertical spacing between text labels in a stackView.
+extern const CGFloat kTableViewVerticalLabelStackSpacing;
+
+// Animation Duration for highlighting selected section header.
+extern const CGFloat kTableViewCellSelectionAnimationDuration;
+
+// Color and alpha used to highlight a cell with a middle gray color to
+// represent a user tap.
+extern const CGFloat kTableViewHighlightedCellColor;
+extern const CGFloat kTableViewHighlightedCellColorAlpha;
+
+#endif  // IOS_CHROME_BROWSER_UI_TABLE_VIEW_CELLS_TABLE_VIEW_CELLS_CONSTANTS_H_

ios/chrome/browser/ui/table_view/cells/table_view_cells_constants.mm

+// Copyright 2018 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "ios/chrome/browser/ui/table_view/cells/table_view_cells_constants.h"
+
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
+const CGFloat kTableViewCellViewSpacing = 16.0;
+const CGFloat kTableViewVerticalLabelStackSpacing = 2.0;
+const CGFloat kTableViewCellSelectionAnimationDuration = 0.15;
+const CGFloat kTableViewHighlightedCellColor = 0xA6A6A6;
+const CGFloat kTableViewHighlightedCellColorAlpha = 0.5;

ios/chrome/browser/ui/table_view/cells/table_view_disclosure_header_footer_item.h

+// Copyright 2018 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#ifndef IOS_CHROME_BROWSER_UI_TABLE_VIEW_CELLS_TABLE_VIEW_DISCLOSURE_HEADER_FOOTER_ITEM_H_
+#define IOS_CHROME_BROWSER_UI_TABLE_VIEW_CELLS_TABLE_VIEW_DISCLOSURE_HEADER_FOOTER_ITEM_H_
+
+#import <UIKit/UIKit.h>
+
+#import "ios/chrome/browser/ui/table_view/cells/table_view_header_footer_item.h"
+
+// TableViewDisclosureHeaderFooterItem contains the model data for a
+// TableViewDisclosureHeaderFooterView.
+@interface TableViewDisclosureHeaderFooterItem : TableViewHeaderFooterItem
+// Title of Header.
+@property(nonatomic, readwrite, strong) NSString* text;
+// Header subtitle displayed as a smaller font under title.
+@property(nonatomic, readwrite, strong) NSString* subtitleText;
+@end
+
+// UITableViewHeaderFooterView that displays a text label, subtitle, and a
+// disclosure accessory view.
+@interface TableViewDisclosureHeaderFooterView : UITableViewHeaderFooterView
+// Shows the text of the TableViewDisclosureHeaderFooterItem.
+@property(nonatomic, readwrite, strong) UILabel* titleLabel;
+// Shows the subtitleText of the TableViewDisclosureHeaderFooterItem.
+@property(nonatomic, readwrite, strong) UILabel* subtitleLabel;
+// Animates a change in the backgroundView color and then changes it back to the
+// original backGround color in order to simulate a selection highlight.
+- (void)animateHighlight;
+@end
+
+#endif  // IOS_CHROME_BROWSER_UI_TABLE_VIEW_CELLS_TABLE_VIEW_DISCLOSURE_HEADER_FOOTER_ITEM_H_

ios/chrome/browser/ui/table_view/cells/table_view_disclosure_header_footer_item.mm

+// Copyright 2018 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "ios/chrome/browser/ui/table_view/cells/table_view_disclosure_header_footer_item.h"
+
+#include "base/mac/foundation_util.h"
+#import "ios/chrome/browser/ui/table_view/cells/table_view_cells_constants.h"
+#import "ios/chrome/browser/ui/table_view/chrome_table_view_styler.h"
+#import "ios/chrome/browser/ui/uikit_ui_util.h"
+
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
+@implementation TableViewDisclosureHeaderFooterItem
+@synthesize subtitleText = _subtitleText;
+@synthesize text = _text;
+
+- (instancetype)initWithType:(NSInteger)type {
+  self = [super initWithType:type];
+  if (self) {
+    self.cellClass = [TableViewDisclosureHeaderFooterView class];
+  }
+  return self;
+}
+
+- (void)configureHeaderFooterView:(UITableViewHeaderFooterView*)headerFooter
+                       withStyler:(ChromeTableViewStyler*)styler {
+  [super configureHeaderFooterView:headerFooter withStyler:styler];
+
+  // Set the contentView backgroundColor, not the header's.
+  headerFooter.contentView.backgroundColor = styler.tableViewBackgroundColor;
+
+  TableViewDisclosureHeaderFooterView* header =
+      base::mac::ObjCCastStrict<TableViewDisclosureHeaderFooterView>(
+          headerFooter);
+  header.titleLabel.text = self.text;
+  header.subtitleLabel.text = self.subtitleText;
+}
+
+@end
+
+#pragma mark - TableViewDisclosureHeaderFooterView
+
+@interface TableViewDisclosureHeaderFooterView ()
+// Animator that handles all cell animations.
+@property(strong, nonatomic) UIViewPropertyAnimator* cellAnimator;
+@end
+
+@implementation TableViewDisclosureHeaderFooterView
+@synthesize cellAnimator = _cellAnimator;
+@synthesize subtitleLabel = _subtitleLabel;
+@synthesize titleLabel = _titleLabel;
+
+- (instancetype)initWithReuseIdentifier:(NSString*)reuseIdentifier {
+  self = [super initWithReuseIdentifier:reuseIdentifier];
+  if (self) {
+    // Labels, set font sizes using dynamic type.
+    _titleLabel = [[UILabel alloc] init];
+    _titleLabel.font =
+        [UIFont preferredFontForTextStyle:UIFontTextStyleHeadline];
+    _subtitleLabel = [[UILabel alloc] init];
+    _subtitleLabel.font =
+        [UIFont preferredFontForTextStyle:UIFontTextStyleCaption1];
+    _subtitleLabel.textColor = [UIColor lightGrayColor];
+
+    // Vertical StackView.
+    UIStackView* verticalStack = [[UIStackView alloc]
+        initWithArrangedSubviews:@[ _titleLabel, _subtitleLabel ]];
+    verticalStack.axis = UILayoutConstraintAxisVertical;
+    verticalStack.spacing = kTableViewVerticalLabelStackSpacing;
+
+    // Disclosure ImageView.
+    UIImageView* disclosureImageView = [[UIImageView alloc]
+        initWithImage:[UIImage imageNamed:@"table_view_cell_chevron"]];
+    [disclosureImageView
+        setContentHuggingPriority:UILayoutPriorityDefaultHigh
+                          forAxis:UILayoutConstraintAxisHorizontal];
+
+    // Horizontal StackView.
+    UIStackView* horizontalStack = [[UIStackView alloc]
+        initWithArrangedSubviews:@[ verticalStack, disclosureImageView ]];
+    horizontalStack.axis = UILayoutConstraintAxisHorizontal;
+    horizontalStack.spacing = kTableViewCellViewSpacing;
+    horizontalStack.translatesAutoresizingMaskIntoConstraints = NO;
+    horizontalStack.alignment = UIStackViewAlignmentCenter;
+
+    // Add subviews to View Hierarchy.
+    [self.contentView addSubview:horizontalStack];
+
+    // Set and activate constraints.
+    [NSLayoutConstraint activateConstraints:@[
+      // Horizontal Stack Constraints.
+      [horizontalStack.leadingAnchor
+          constraintEqualToAnchor:self.contentView.leadingAnchor
+                         constant:kTableViewCellViewSpacing],
+      [horizontalStack.trailingAnchor
+          constraintEqualToAnchor:self.contentView.trailingAnchor
+                         constant:-kTableViewCellViewSpacing],
+      [horizontalStack.topAnchor
+          constraintGreaterThanOrEqualToAnchor:self.contentView.topAnchor
+                                      constant:kTableViewCellViewSpacing],
+      [horizontalStack.bottomAnchor
+          constraintLessThanOrEqualToAnchor:self.contentView.bottomAnchor
+                                   constant:-kTableViewCellViewSpacing],
+      [horizontalStack.centerYAnchor
+          constraintEqualToAnchor:self.contentView.centerYAnchor]
+    ]];
+  }
+  return self;
+}
+
+- (void)animateHighlight {
+  UIColor* originalBackgroundColor = self.contentView.backgroundColor;
+  self.cellAnimator = [[UIViewPropertyAnimator alloc]
+      initWithDuration:kTableViewCellSelectionAnimationDuration
+                 curve:UIViewAnimationCurveLinear
+            animations:^{
+              self.contentView.backgroundColor =
+                  UIColorFromRGB(kTableViewHighlightedCellColor,
+                                 kTableViewHighlightedCellColorAlpha);
+            }];
+  __weak TableViewDisclosureHeaderFooterView* weakSelf = self;
+  [self.cellAnimator addCompletion:^(UIViewAnimatingPosition finalPosition) {
+    weakSelf.contentView.backgroundColor = originalBackgroundColor;
+  }];
+  [self.cellAnimator startAnimation];
+}
+
+- (void)prepareForReuse {
+  [super prepareForReuse];
+  if (self.cellAnimator.isRunning)
+    [self.cellAnimator stopAnimation:YES];
+}
+
+@end

ios/chrome/browser/ui/table_view/cells/table_view_text_header_footer_item.mm

@@ -5,19 +5,14 @@
 #import "ios/chrome/browser/ui/table_view/cells/table_view_text_header_footer_item.h"
 
 #include "base/mac/foundation_util.h"
+#import "ios/chrome/browser/ui/table_view/cells/table_view_cells_constants.h"
 #import "ios/chrome/browser/ui/table_view/chrome_table_view_styler.h"
+#import "ios/chrome/browser/ui/uikit_ui_util.h"
 
 #if !defined(__has_feature) || !__has_feature(objc_arc)
 #error "This file requires ARC support."
 #endif
 
-namespace {
-// The inner insets of the View content.
-const CGFloat kMargin = 16;
-
-// The vertical spacing between text labels.
-const CGFloat kVerticalSpacing = 2.0;
-}
 
 @implementation TableViewTextHeaderFooterItem
 @synthesize subtitleText = _subtitleText;
@@ -76,7 +71,7 @@ const CGFloat kVerticalSpacing = 2.0;
     UIStackView* verticalStack = [[UIStackView alloc]
         initWithArrangedSubviews:@[ _textLabel, _subtitleLabel ]];
     verticalStack.axis = UILayoutConstraintAxisVertical;
-    verticalStack.spacing = kVerticalSpacing;
+    verticalStack.spacing = kTableViewVerticalLabelStackSpacing;
     verticalStack.translatesAutoresizingMaskIntoConstraints = NO;
 
     // Container View.
@@ -92,16 +87,16 @@ const CGFloat kVerticalSpacing = 2.0;
       // Container Constraints.
       [containerView.leadingAnchor
           constraintEqualToAnchor:self.contentView.leadingAnchor
-                         constant:kMargin],
+                         constant:kTableViewCellViewSpacing],
       [containerView.trailingAnchor
           constraintEqualToAnchor:self.contentView.trailingAnchor
-                         constant:-kMargin],
+                         constant:-kTableViewCellViewSpacing],
       [containerView.topAnchor
           constraintGreaterThanOrEqualToAnchor:self.contentView.topAnchor
-                                      constant:kMargin],
+                                      constant:kTableViewCellViewSpacing],
       [containerView.bottomAnchor
           constraintLessThanOrEqualToAnchor:self.contentView.bottomAnchor
-                                   constant:-kMargin],
+                                   constant:-kTableViewCellViewSpacing],
       [containerView.centerYAnchor
           constraintEqualToAnchor:self.contentView.centerYAnchor],
       // Vertical StackView Constraints.
@@ -120,11 +115,12 @@ const CGFloat kVerticalSpacing = 2.0;
 - (void)animateHighlight {
   UIColor* originalBackgroundColor = self.contentView.backgroundColor;
   self.cellAnimator = [[UIViewPropertyAnimator alloc]
-      initWithDuration:0.15
+      initWithDuration:kTableViewCellSelectionAnimationDuration
                  curve:UIViewAnimationCurveLinear
             animations:^{
               self.contentView.backgroundColor =
-                  [[UIColor lightGrayColor] colorWithAlphaComponent:0.5];
+                  UIColorFromRGB(kTableViewHighlightedCellColor,
+                                 kTableViewHighlightedCellColorAlpha);
             }];
   __weak TableViewTextHeaderFooterView* weakSelf = self;
   [self.cellAnimator addCompletion:^(UIViewAnimatingPosition finalPosition) {