[iOS] Create ReadingListToolbarButtonManager.

This class is responsible for deciding what toolbar buttons should be
displayed for the UITableView-based ReadingList implementation.

Bug: 805209, 805211
Cq-Include-Trybots: luci.chromium.try:ios-simulator-full-configs;master.tryserver.chromium.mac:ios-simulator-cronet
Change-Id: Ic619f746d4ecd52a700f57efc959c587c4976803
Reviewed-on: https://chromium-review.googlesource.com/1106970Reviewed-by: Gauthier Ambard <gambard@chromium.org>
Reviewed-by: Sergio Collazos <sczs@chromium.org>
Commit-Queue: Kurt Horimoto <kkhorimoto@chromium.org>
Cr-Commit-Position: refs/heads/master@{#571211}

ios/chrome/browser/ui/reading_list/BUILD.gn

@@ -74,6 +74,9 @@ source_set("reading_list_ui") {
     "reading_list_toolbar.mm",
     "reading_list_toolbar_button.h",
     "reading_list_toolbar_button.mm",
+    "reading_list_toolbar_button_commands.h",
+    "reading_list_toolbar_button_manager.h",
+    "reading_list_toolbar_button_manager.mm",
     "reading_list_ui_distillation_status.h",
     "reading_list_view_controller.h",
     "reading_list_view_controller.mm",

ios/chrome/browser/ui/reading_list/reading_list_toolbar_button_commands.h

+// Copyright 2018 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#ifndef IOS_CHROME_BROWSER_UI_READING_LIST_READING_LIST_TOOLBAR_BUTTON_COMMANDS_H_
+#define IOS_CHROME_BROWSER_UI_READING_LIST_READING_LIST_TOOLBAR_BUTTON_COMMANDS_H_
+
+#import <Foundation/Foundation.h>
+
+// Commands sent by reading list toolbar buttons.
+@protocol ReadingListToolbarButtonCommands<NSObject>
+
+// Called when the "Edit" button is tapped.
+- (void)enterReadingListEditMode;
+// Called when the "Cancel" button is tapped.
+- (void)exitReadingListEditMode;
+// Called when the "Delete Read" button is tapped.
+- (void)deleteAllReadReadingListItems;
+// Called when the "Delete" button is tapped.
+- (void)deleteSelectedReadingListItems;
+// Called when the "Mark Read" button is tapped.
+- (void)markSelectedReadingListItemsRead;
+// Called when the "Mark Unread" button is tapped.
+- (void)markSelectedReadingListItemsUnread;
+// Called when the "Mark..." button is tapped.  Handlers of this command should
+// confirm whether the selected items should be marked as read or unread, then
+// perform the disambiguated action.
+- (void)markSelectedReadingListItemsAfterConfirmation;
+// Called when the "Mark All..." button is tapped.  Handlers of this command
+// should confirm whether the items should be marked as read or unread, then
+// perform the disambiguated action.
+- (void)markAllReadingListItemsAfterConfirmation;
+
+@end
+
+#endif  // IOS_CHROME_BROWSER_UI_READING_LIST_READING_LIST_TOOLBAR_BUTTON_COMMANDS_H_

ios/chrome/browser/ui/reading_list/reading_list_toolbar_button_manager.h

+// Copyright 2018 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#ifndef IOS_CHROME_BROWSER_UI_READING_LIST_READING_LIST_TOOLBAR_BUTTON_MANAGER_H_
+#define IOS_CHROME_BROWSER_UI_READING_LIST_READING_LIST_TOOLBAR_BUTTON_MANAGER_H_
+
+#import <UIKit/UIKit.h>
+
+@class ActionSheetCoordinator;
+@protocol ReadingListToolbarButtonCommands;
+
+// Enum type describing the items that are currently selected.
+enum class ReadingListSelectionState {
+  NONE,
+  ONLY_READ_ITEMS,
+  ONLY_UNREAD_ITEMS,
+  READ_AND_UNREAD_ITEMS
+};
+
+// State object that manages the buttons that should be displayed in the toolbar
+// at the bottom of the reading list.
+@interface ReadingListToolbarButtonManager : NSObject
+
+// The selection state of the reading list view.
+@property(nonatomic, assign) ReadingListSelectionState selectionState;
+// Whether the reading list has any read items.
+@property(nonatomic, assign) BOOL hasReadItems;
+// Whether the reading list is being edited.
+@property(nonatomic, assign, getter=isEditing) BOOL editing;
+
+// Whether the toolbar buttons have changed since the last |-buttonItems| call.
+@property(nonatomic, readonly) BOOL buttonItemsUpdated;
+
+// The handler for toolbar button actions.
+@property(nonatomic, weak) id<ReadingListToolbarButtonCommands> commandHandler;
+
+// Returns an array of button items that should be displayed for the current
+// state.  The buttons are be set up to send ReadingListToolbarButtonCommands
+// to |self.commandHandler|.
+- (NSArray<UIBarButtonItem*>*)buttonItems;
+
+// Returns an empty ActionSheetCoordinator anchored to the mark button with no
+// message and no title.
+- (ActionSheetCoordinator*)markButtonConfirmationWithBaseViewController:
+    (UIViewController*)viewController;
+
+@end
+
+#endif  // IOS_CHROME_BROWSER_UI_READING_LIST_READING_LIST_TOOLBAR_BUTTON_MANAGER_H_

ios/chrome/browser/ui/reading_list/reading_list_toolbar_button_manager.mm

+// Copyright 2018 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "ios/chrome/browser/ui/reading_list/reading_list_toolbar_button_manager.h"
+
+#include "base/logging.h"
+#import "ios/chrome/browser/ui/alert_coordinator/action_sheet_coordinator.h"
+#import "ios/chrome/browser/ui/reading_list/reading_list_toolbar_button_commands.h"
+#include "ios/chrome/grit/ios_strings.h"
+#include "ui/base/l10n/l10n_util_mac.h"
+
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
+namespace {
+// Returns the title to use for the "Mark" button for |state|.
+NSString* GetMarkButtonTitleForSelectionState(ReadingListSelectionState state) {
+  switch (state) {
+    case ReadingListSelectionState::NONE:
+      return l10n_util::GetNSString(IDS_IOS_READING_LIST_MARK_ALL_BUTTON);
+    case ReadingListSelectionState::ONLY_READ_ITEMS:
+      return l10n_util::GetNSString(IDS_IOS_READING_LIST_MARK_UNREAD_BUTTON);
+    case ReadingListSelectionState::ONLY_UNREAD_ITEMS:
+      return l10n_util::GetNSString(IDS_IOS_READING_LIST_MARK_READ_BUTTON);
+    case ReadingListSelectionState::READ_AND_UNREAD_ITEMS:
+      return l10n_util::GetNSString(IDS_IOS_READING_LIST_MARK_BUTTON);
+  }
+}
+}  // namespace
+
+@interface ReadingListToolbarButtonManager () {
+  // The button items corresponding to the current state.
+  NSMutableArray<UIBarButtonItem*>* _buttonItems;
+}
+
+// The possible button items that may be returned by the |-buttonItems|.
+@property(nonatomic, strong, readonly) UIBarButtonItem* editButton;
+@property(nonatomic, strong, readonly) UIBarButtonItem* deleteButton;
+@property(nonatomic, strong, readonly) UIBarButtonItem* deleteAllReadButton;
+@property(nonatomic, strong, readonly) UIBarButtonItem* cancelButton;
+@property(nonatomic, strong, readonly) UIBarButtonItem* markButton;
+
+// Whether the corresponding button items should be returned in |-buttonItems|.
+@property(nonatomic, readonly) BOOL shouldShowEditButton;
+@property(nonatomic, readonly) BOOL shouldShowDeleteButton;
+@property(nonatomic, readonly) BOOL shouldShowDeleteAllReadButton;
+@property(nonatomic, readonly) BOOL shouldShowCancelButton;
+@property(nonatomic, readonly) BOOL shouldShowMarkButton;
+
+@end
+
+@implementation ReadingListToolbarButtonManager
+@synthesize selectionState = _selectionState;
+@synthesize hasReadItems = _hasReadItems;
+@synthesize editing = _editing;
+@synthesize commandHandler = _commandHandler;
+@synthesize editButton = _editButton;
+@synthesize deleteButton = _deleteButton;
+@synthesize deleteAllReadButton = _deleteAllReadButton;
+@synthesize cancelButton = _cancelButton;
+@synthesize markButton = _markButton;
+
+- (instancetype)init {
+  if (self = [super init]) {
+    _selectionState = ReadingListSelectionState::NONE;
+
+    _editButton = [[UIBarButtonItem alloc]
+        initWithTitle:l10n_util::GetNSString(IDS_IOS_READING_LIST_EDIT_BUTTON)
+                style:UIBarButtonItemStylePlain
+               target:nil
+               action:@selector(enterReadingListEditMode)];
+
+    _deleteButton = [[UIBarButtonItem alloc]
+        initWithTitle:l10n_util::GetNSString(IDS_IOS_READING_LIST_DELETE_BUTTON)
+                style:UIBarButtonItemStylePlain
+               target:nil
+               action:@selector(deleteSelectedReadingListItems)];
+    _deleteButton.tintColor = [UIColor redColor];
+
+    _deleteAllReadButton = [[UIBarButtonItem alloc]
+        initWithTitle:l10n_util::GetNSString(
+                          IDS_IOS_READING_LIST_DELETE_ALL_READ_BUTTON)
+                style:UIBarButtonItemStylePlain
+               target:nil
+               action:@selector(deleteAllReadReadingListItems)];
+    _deleteAllReadButton.tintColor = [UIColor redColor];
+
+    _cancelButton = [[UIBarButtonItem alloc]
+        initWithTitle:l10n_util::GetNSString(IDS_IOS_READING_LIST_CANCEL_BUTTON)
+                style:UIBarButtonItemStyleDone
+               target:nil
+               action:@selector(exitReadingListEditMode)];
+
+    _markButton = [[UIBarButtonItem alloc]
+        initWithTitle:GetMarkButtonTitleForSelectionState(self.selectionState)
+                style:UIBarButtonItemStylePlain
+               target:self
+               action:@selector(markButtonWasTapped)];
+  }
+  return self;
+}
+
+#pragma mark - Accessors
+
+- (void)setSelectionState:(ReadingListSelectionState)selectionState {
+  if (_selectionState == selectionState)
+    return;
+  BOOL hadSelectedItems = _selectionState != ReadingListSelectionState::NONE;
+  _selectionState = selectionState;
+  _markButton.title = GetMarkButtonTitleForSelectionState(_selectionState);
+  // Check whether selection status has changed to or from NONE.
+  if ((_selectionState != ReadingListSelectionState::NONE) != hadSelectedItems)
+    _buttonItems = nil;
+}
+
+- (void)setHasReadItems:(BOOL)hasReadItems {
+  if (_hasReadItems == hasReadItems)
+    return;
+  BOOL didShowDeleteAllReadButton = self.shouldShowDeleteAllReadButton;
+  _hasReadItems = hasReadItems;
+  // Check whether the delete all read button visiblity has changed due to the
+  // new value of self.hasReadItems.
+  if (didShowDeleteAllReadButton != self.shouldShowDeleteAllReadButton)
+    _buttonItems = nil;
+}
+
+- (void)setEditing:(BOOL)editing {
+  if (_editing == editing)
+    return;
+  _editing = editing;
+  // Entering and exiting edit mode always updates the button items.
+  _buttonItems = nil;
+  // Selected cells are unselected when exiting edit mode.
+  if (!_editing)
+    self.selectionState = ReadingListSelectionState::NONE;
+}
+
+- (BOOL)buttonItemsUpdated {
+  // When the changes to the values of this class's public properties require
+  // an updated buttons array, |_buttonItems| will be reset to nil.  Subsequent
+  // calls to |-buttonItems| will regenerate the correct button item array.
+  return !_buttonItems;
+}
+
+- (void)setCommandHandler:(id<ReadingListToolbarButtonCommands>)commandHandler {
+  if (_commandHandler == commandHandler)
+    return;
+  _commandHandler = commandHandler;
+  self.editButton.target = _commandHandler;
+  self.deleteButton.target = _commandHandler;
+  self.deleteAllReadButton.target = _commandHandler;
+  self.cancelButton.target = _commandHandler;
+}
+
+- (BOOL)shouldShowEditButton {
+  return !self.editing;
+}
+
+- (BOOL)shouldShowDeleteButton {
+  BOOL showDeleteButton =
+      self.editing && self.selectionState != ReadingListSelectionState::NONE;
+  // If the delete button is shown, then the delete all button should be hidden.
+  DCHECK(!showDeleteButton || !self.shouldShowDeleteAllReadButton);
+  return showDeleteButton;
+}
+
+- (BOOL)shouldShowDeleteAllReadButton {
+  BOOL showDeleteAllReadButton =
+      self.editing && self.selectionState == ReadingListSelectionState::NONE &&
+      self.hasReadItems;
+  // If the delete all read button is shown, then the delete should be hidden.
+  DCHECK(!showDeleteAllReadButton || !self.shouldShowDeleteButton);
+  return showDeleteAllReadButton;
+}
+
+- (BOOL)shouldShowCancelButton {
+  return self.editing;
+}
+
+- (BOOL)shouldShowMarkButton {
+  return self.editing;
+}
+
+#pragma mark - Public
+
+- (NSArray<UIBarButtonItem*>*)buttonItems {
+  if (_buttonItems)
+    return _buttonItems;
+  _buttonItems = [[NSMutableArray alloc] init];
+  if (self.shouldShowEditButton)
+    [_buttonItems addObject:self.editButton];
+  if (self.shouldShowDeleteButton)
+    [_buttonItems addObject:self.deleteButton];
+  if (self.shouldShowDeleteAllReadButton)
+    [_buttonItems addObject:self.deleteAllReadButton];
+  if (self.shouldShowMarkButton)
+    [_buttonItems addObject:self.markButton];
+  if (self.shouldShowCancelButton)
+    [_buttonItems addObject:self.cancelButton];
+  [self addSpacersToItems:_buttonItems];
+  return _buttonItems;
+}
+
+- (ActionSheetCoordinator*)markButtonConfirmationWithBaseViewController:
+    (UIViewController*)viewController {
+  return [[ActionSheetCoordinator alloc]
+      initWithBaseViewController:viewController
+                           title:nil
+                         message:nil
+                   barButtonItem:self.markButton];
+}
+
+#pragma mark - Private
+
+// Called when the "Mark" button was tapped.
+- (void)markButtonWasTapped {
+  switch (self.selectionState) {
+    case ReadingListSelectionState::NONE:
+      [self.commandHandler markAllReadingListItemsAfterConfirmation];
+      break;
+    case ReadingListSelectionState::ONLY_READ_ITEMS:
+      [self.commandHandler markSelectedReadingListItemsUnread];
+      break;
+    case ReadingListSelectionState::ONLY_UNREAD_ITEMS:
+      [self.commandHandler markSelectedReadingListItemsRead];
+      break;
+    case ReadingListSelectionState::READ_AND_UNREAD_ITEMS:
+      [self.commandHandler markSelectedReadingListItemsAfterConfirmation];
+      break;
+  }
+}
+
+// Inserts spacer button items between the items in |items|, right aligning the
+// buttons if they appear alone.
+- (void)addSpacersToItems:(NSMutableArray<UIBarButtonItem*>*)items {
+  NSMutableArray<UIBarButtonItem*>* spacers = [NSMutableArray array];
+  NSMutableIndexSet* indexes = [NSMutableIndexSet indexSet];
+  NSUInteger itemCount = items.count;
+  // If there's a single item, add the spacer at index 0 to right-align the
+  // button.  Otherwise, add the first spacer at index 1 to add space between
+  // the first and second buttons.
+  NSUInteger firstIndex = itemCount == 1 ? 0 : 1;
+  for (NSUInteger i = 0; i < itemCount - firstIndex; ++i) {
+    [spacers addObject:[[UIBarButtonItem alloc]
+                           initWithBarButtonSystemItem:
+                               UIBarButtonSystemItemFlexibleSpace
+                                                target:nil
+                                                action:nil]];
+    [indexes addIndex:firstIndex + 2 * i];
+  }
+  [items insertObjects:spacers atIndexes:indexes];
+}
+
+@end