Do more work on content/browser GN build

Adds support for the devtools generated resources.

Still doesn't compile, but getting closer.

R=scottmg@chromium.org

Review URL: https://codereview.chromium.org/304223009

git-svn-id: svn://svn.chromium.org/chrome/trunk/src@274026 0039d316-1c4b-4281-b951-d872f2087c98

BUILD.gn

@@ -33,6 +33,7 @@ group("root") {
     "//components/translate:translate_core_browser",
     "//components/translate:translate_core_common",
     "//components/url_matcher",
+    #"//content/public/browser",  # Exists but doesn't build yet.
     "//content/public/common",
     "//content/public/renderer",
     "//crypto",

content/browser/BUILD.gn

@@ -33,6 +33,9 @@ source_set("browser") {
 
   deps = [
     "//base",
+    "//cc",
+    "//content:resources",
+    "//content/browser/devtools:resources",
     "//crypto",
     "//google_apis",
     "//net",
@@ -52,6 +55,7 @@ source_set("browser") {
     "//ui/gfx",
     "//ui/gfx/geometry",
     "//ui/resources",
+    "//ui/snapshot",
     "//ui/surface",
     "//webkit:resources",
     "//webkit:strings",
@@ -59,12 +63,10 @@ source_set("browser") {
     "//webkit/common",
     "//webkit/common:storage",
     # TODO(GYP)
-    #"//ui/snapshot",
     #'browser/service_worker/service_worker_proto.gyp:database_proto',
     #'browser/speech/proto/speech_proto.gyp:speech_proto',
     #'browser/devtools/devtools_resources.gyp:devtools_resources',
     #'content_common_mojo_bindings',
-    #'../cc/cc.gyp:cc',
     #'../mojo/mojo.gyp:mojo_cpp_bindings',
     #'../mojo/mojo.gyp:mojo_js_bindings',
     #'../mojo/mojo.gyp:mojo_service_provider_bindings',

content/browser/devtools/BUILD.gn

+# Copyright 2014 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//tools/grit/grit_rule.gni")
+
+# In GYP: devtools_resources target.
+group("resources") {
+  deps = [
+    ":devtools_resources",
+    ":devtools_protocol_constants",
+  ]
+}
+
+# In GYP: devtools_resources action in the devtools_resources target.
+action("devtools_resources") {
+  visibility = ":resources"
+
+  # This can't use grit_rule.gni because the grd file is generated at build
+  # time, so the trick of using grit_info to get the real inputs/outputs at GYP
+  # time isn't possible.
+  script = "//tools/grit/grit.py"
+
+  grdfile = "$root_gen_dir/devtools/devtools_resources.grd"
+
+  source_prereqs = [ grdfile ] +
+    rebase_path(exec_script("//tools/grit/grit_info.py", [ "--inputs" ],
+                            "list lines"),
+                ".", "//")
+
+  out_dir = "$root_gen_dir/webkit"
+  outputs = [
+    "$out_dir/grit/devtools_resources.h",
+    "$out_dir/devtools_resources.pak",
+    "$out_dir/grit/devtools_resources_map.cc",
+    "$out_dir/grit/devtools_resources_map.h",
+  ]
+
+  args = [
+    "-i", rebase_path(grdfile, root_build_dir), "build",
+    "-f", rebase_path("//tools/gritsettings/resource_ids", root_build_dir),
+    "-o", rebase_path(out_dir, root_build_dir),
+    "-D", "SHARED_INTERMEDIATE_DIR=" +
+      rebase_path(root_gen_dir, root_build_dir),
+  ] + grit_defines
+
+  deps = [
+    # This is the action that generates out .grd input file.
+    "//third_party/WebKit/public:blink_generate_devtools_grd",
+  ]
+}
+
+action("devtools_protocol_constants") {
+  visibility = ":resources"
+
+  script = "//content/public/browser/devtools_protocol_constants_generator.py"
+
+  blink_protocol = "//third_party/WebKit/Source/devtools/protocol.json"
+  browser_protocol = "browser_protocol.json"
+  source_prereqs = [ blink_protocol, browser_protocol ]
+
+  outputs = [
+    "$target_gen_dir/devtools_protocol_constants.cc",
+    "$target_gen_dir/devtools_protocol_constants.h",
+  ]
+
+  args = [ "content" ] + rebase_path(outputs, root_build_dir) + [
+    rebase_path(blink_protocol, root_build_dir),
+    rebase_path(browser_protocol, root_build_dir),
+  ]
+}

content/public/browser/BUILD.gn

@@ -2,8 +2,16 @@
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
+import("//content/browser/browser.gni")
+
 source_set("browser") {
+  sources = rebase_path(content_browser_gypi_values.public_browser_sources,
+                        ".", "//content")
+
+  configs += [ "//content:content_implementation" ]
+
   deps = [
     "//content/browser",
+    "//skia",
   ]
 }