Add ruleset indexing action as data_dep to telemetry tests

This allows telemetry to have access to an indexed ruleset, without
having to specify one in the source tree (which would need to be
updated every time the format version changes).

Follow-ups will copy this into telemetry's user-data-dir.

Bug: 823982
Change-Id: Iba551b1cd6137d73bed8dfbb0bc69d00f32be7ab
Reviewed-on: https://chromium-review.googlesource.com/1052860Reviewed-by: Josh Karlin <jkarlin@chromium.org>
Reviewed-by: Ned Nguyen <nednguyen@google.com>
Commit-Queue: Charlie Harrison <csharrison@chromium.org>
Cr-Commit-Position: refs/heads/master@{#557855}

components/subresource_filter/tools/BUILD.gn

@@ -2,7 +2,7 @@
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
-import("//build/config/chromecast_build.gni")
+import("//build/compiled_action.gni")
 
 static_library("tools_lib") {
   sources = [
@@ -40,7 +40,8 @@ source_set("unit_tests") {
     "//url",
   ]
 }
-if (!is_ios && !is_android && !is_chromecast && !is_fuchsia) {
+
+if (!is_ios) {
   executable("subresource_filter_tool") {
     # Production code should not depend on this.
     testonly = true
@@ -67,13 +68,53 @@ if (!is_ios && !is_android && !is_chromecast && !is_fuchsia) {
     ]
   }
 
+  executable("ruleset_converter") {
+    sources = [
+      "ruleset_converter/main.cc",
+    ]
+    deps = [
+      "ruleset_converter:support",
+      "//base",
+      "//build/config:exe_and_shlib_deps",
+      "//third_party/protobuf:protobuf_lite",
+    ]
+  }
+
   group("subresource_filter_tools") {
     # Production code should not depend on this.
     testonly = true
     deps = [
+      ":ruleset_converter",
       ":subresource_filter_tool",
       ":subresource_indexing_tool",
-      "ruleset_converter",
+    ]
+  }
+
+  # This action compiles the indexing tool using the host's toolchain, and
+  # generates an indexed ruleset using the existing unindexed ruleset in the
+  # source tree.
+  compiled_action("index_ruleset") {
+    testonly = true
+    tool = ":subresource_indexing_tool"
+
+    outputs = [
+      "$target_gen_dir/GeneratedRulesetData",
+    ]
+
+    inputs = [
+      # Make sure the inputs are system-absolute, as base::File cannot open files with ".." components.
+      rebase_path(
+          "//components/subresource_filter/core/common/perftests/data/UnindexedRules_7.54",
+          "",
+          "/"),
+    ]
+    deps = [
+      ":subresource_indexing_tool",
+    ]
+
+    args = [
+      inputs[0],
+      rebase_path("$target_gen_dir/GeneratedRulesetData", root_build_dir),
     ]
   }
 }

components/subresource_filter/tools/ruleset_converter/BUILD.gn

@@ -2,8 +2,6 @@
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
-import("//build/config/chromecast_build.gni")
-
 source_set("support") {
   sources = [
     "//third_party/protobuf:protobuf_lite",
@@ -42,17 +40,3 @@ source_set("unit_tests") {
     "//testing/gtest",
   ]
 }
-
-if (!is_ios && !is_android && !is_chromecast && !is_fuchsia) {
-  executable("ruleset_converter") {
-    sources = [
-      "main.cc",
-    ]
-    deps = [
-      ":support",
-      "//base",
-      "//build/config:exe_and_shlib_deps",
-      "//third_party/protobuf:protobuf_lite",
-    ]
-  }
-}

tools/perf/BUILD.gn

@@ -28,9 +28,19 @@ group("perf") {
     # For image_decoding.measurement
     "//chrome/test/data/image_decoding/",
 
+    # For ad tagging ruleset
+    "$root_gen_dir/components/subresource_filter/tools/",
+
     # For Pylib used by VR tests
     "//build/android/pylib/",
   ]
+
+  # Runs a script which generates the ad tagging ruleset.
+  if (!is_ios) {
+    data_deps = [
+      "//components/subresource_filter/tools:index_ruleset",
+    ]
+  }
 }
 
 if (is_android) {
@@ -69,7 +79,17 @@ group("perf_without_chrome") {
     # For image_decoding.measurement
     "//chrome/test/data/image_decoding/",
 
+    # For ad tagging ruleset
+    "$root_gen_dir/components/subresource_filter/tools/",
+
     # For Pylib used by VR tests
     "//build/android/pylib/",
   ]
+
+  # Runs a script which generates the ad tagging ruleset.
+  if (!is_ios) {
+    data_deps = [
+      "//components/subresource_filter/tools:index_ruleset",
+    ]
+  }
 }