[IOS][Language] Language Settings - Add language page.

Add language page allows the user to select a supported language to add to
the list of user preferred languages. Existing accepts languages are
excluded from the available options.

screenshot: https://drive.google.com/file/d/1gV24hPwP1Gpiw_whOW45GQGmfJn_byEi/view?usp=sharing

Bug: 957688
Change-Id: I63b261061cc867a1c7d5cd2373cb948eec1581f7
Reviewed-on: https://chromium-review.googlesource.com/c/chromium/src/+/1611911Reviewed-by: Peter Lee <pkl@chromium.org>
Reviewed-by: Sergio Collazos <sczs@chromium.org>
Commit-Queue: Moe Ahmadi <mahmadi@chromium.org>
Cr-Commit-Position: refs/heads/master@{#660843}

ios/chrome/browser/ui/settings/BUILD.gn

@@ -42,6 +42,8 @@ source_set("settings") {
   sources = [
     "about_chrome_table_view_controller.h",
     "about_chrome_table_view_controller.mm",
+    "add_language_table_view_controller.h",
+    "add_language_table_view_controller.mm",
     "bandwidth_management_table_view_controller.h",
     "bandwidth_management_table_view_controller.mm",
     "block_popups_table_view_controller.h",

ios/chrome/browser/ui/settings/add_language_table_view_controller.h

+// Copyright 2019 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#ifndef IOS_CHROME_BROWSER_UI_SETTINGS_ADD_LANGUAGE_TABLE_VIEW_CONTROLLER_H_
+#define IOS_CHROME_BROWSER_UI_SETTINGS_ADD_LANGUAGE_TABLE_VIEW_CONTROLLER_H_
+
+#import "ios/chrome/browser/ui/settings/settings_root_table_view_controller.h"
+
+@class AddLanguageTableViewController;
+@protocol LanguageSettingsDataSource;
+
+// Protocol used by AddLanguageTableViewController to communicate to its
+// delegate.
+@protocol AddLanguageTableViewControllerDelegate
+
+// Informs the delegate that user selected a language with the given code.
+- (void)addLanguageTableViewController:
+            (AddLanguageTableViewController*)tableViewController
+                 didSelectLanguageCode:(const std::string&)languageCode;
+
+@end
+
+// Controller for the UI that allows the user to select a supported language to
+// add to the accept languages list.
+@interface AddLanguageTableViewController : SettingsRootTableViewController
+
+// The designated initializer. |dataSource| and |delegate| must not be nil.
+// |delegate| will not be retained.
+- (instancetype)initWithDataSource:(id<LanguageSettingsDataSource>)dataSource
+                          delegate:(id<AddLanguageTableViewControllerDelegate>)
+                                       delegate NS_DESIGNATED_INITIALIZER;
+- (instancetype)initWithTableViewStyle:(UITableViewStyle)style
+                           appBarStyle:
+                               (ChromeTableViewControllerStyle)appBarStyle
+    NS_UNAVAILABLE;
+
+// Called when the list of supported languages changes so that the view
+// controller can update its model from |dataSource|.
+- (void)supportedLanguagesListChanged;
+
+@end
+
+#endif  // IOS_CHROME_BROWSER_UI_SETTINGS_ADD_LANGUAGE_TABLE_VIEW_CONTROLLER_H_

ios/chrome/browser/ui/settings/add_language_table_view_controller.mm

+// Copyright 2019 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "ios/chrome/browser/ui/settings/add_language_table_view_controller.h"
+
+#include "base/mac/foundation_util.h"
+#import "ios/chrome/browser/ui/list_model/list_item+Controller.h"
+#import "ios/chrome/browser/ui/settings/cells/language_item.h"
+#import "ios/chrome/browser/ui/settings/language_settings_data_source.h"
+#include "ios/chrome/browser/ui/ui_feature_flags.h"
+#import "ios/chrome/browser/ui/util/uikit_ui_util.h"
+#include "ios/chrome/grit/ios_strings.h"
+#include "ui/base/l10n/l10n_util_mac.h"
+
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
+namespace {
+
+NSString* const kAddLanguageTableViewAccessibilityIdentifier =
+    @"add_language_table_view";
+
+typedef NS_ENUM(NSInteger, SectionIdentifier) {
+  SectionIdentifierLanguages = kSectionIdentifierEnumZero,
+};
+
+typedef NS_ENUM(NSInteger, ItemType) {
+  ItemTypeLanguage = kItemTypeEnumZero,  // This is a repeating type.
+};
+
+}  // namespace
+
+@interface AddLanguageTableViewController ()
+
+// The data source passed to this instance.
+@property(nonatomic, strong) id<LanguageSettingsDataSource> dataSource;
+
+// The delegate passed to this instance.
+@property(nonatomic, weak) id<AddLanguageTableViewControllerDelegate> delegate;
+
+@end
+
+@implementation AddLanguageTableViewController
+
+- (instancetype)initWithDataSource:(id<LanguageSettingsDataSource>)dataSource
+                          delegate:(id<AddLanguageTableViewControllerDelegate>)
+                                       delegate {
+  DCHECK(dataSource);
+  DCHECK(delegate);
+  UITableViewStyle style = base::FeatureList::IsEnabled(kSettingsRefresh)
+                               ? UITableViewStylePlain
+                               : UITableViewStyleGrouped;
+  self = [super initWithTableViewStyle:style
+                           appBarStyle:ChromeTableViewControllerStyleNoAppBar];
+  if (self) {
+    _dataSource = dataSource;
+    _delegate = delegate;
+  }
+  return self;
+}
+
+#pragma mark - UIViewController
+
+- (void)viewDidLoad {
+  [super viewDidLoad];
+
+  self.title =
+      l10n_util::GetNSString(IDS_IOS_LANGUAGE_SETTINGS_ADD_LANGUAGE_TITLE);
+  self.shouldHideDoneButton = YES;
+  self.tableView.accessibilityIdentifier =
+      kAddLanguageTableViewAccessibilityIdentifier;
+
+  [self loadModel];
+}
+
+#pragma mark - ChromeTableViewController
+
+- (void)loadModel {
+  [super loadModel];
+
+  [self.tableViewModel addSectionWithIdentifier:SectionIdentifierLanguages];
+  [self populateLanguagesSection];
+}
+
+#pragma mark - UITableViewDelegate
+
+- (void)tableView:(UITableView*)tableView
+    didSelectRowAtIndexPath:(NSIndexPath*)indexPath {
+  LanguageItem* languageItem = base::mac::ObjCCastStrict<LanguageItem>(
+      [self.tableViewModel itemAtIndexPath:indexPath]);
+
+  [self.delegate addLanguageTableViewController:self
+                          didSelectLanguageCode:languageItem.languageCode];
+}
+
+#pragma mark - Public methods
+
+- (void)supportedLanguagesListChanged {
+  // Update the model and the table view.
+  [self updateLanguagesSection];
+}
+
+#pragma mark - Helper methods
+
+- (void)populateLanguagesSection {
+  TableViewModel* model = self.tableViewModel;
+
+  // Languages items.
+  [[self.dataSource supportedLanguagesItems]
+      enumerateObjectsUsingBlock:^(LanguageItem* item, NSUInteger index,
+                                   BOOL* stop) {
+        item.type = ItemTypeLanguage;
+        [model addItem:item toSectionWithIdentifier:SectionIdentifierLanguages];
+      }];
+}
+
+- (void)updateLanguagesSection {
+  // Update the model.
+  [self.tableViewModel
+      deleteAllItemsFromSectionWithIdentifier:SectionIdentifierLanguages];
+  [self populateLanguagesSection];
+
+  // Update the table view.
+  NSUInteger index = [self.tableViewModel
+      sectionForSectionIdentifier:SectionIdentifierLanguages];
+  [self.tableView reloadSections:[NSIndexSet indexSetWithIndex:index]
+                withRowAnimation:UITableViewRowAnimationNone];
+}
+
+@end

ios/chrome/browser/ui/settings/language_settings_commands.h

@@ -21,6 +21,10 @@
             downward:(BOOL)downward
           withOffset:(NSUInteger)offset;
 
+// Informs the receiver to add the language with the given code to the list of
+// accept languages.
+- (void)addLanguage:(const std::string&)languageCode;
+
 // Informs the receiver to remove the language with the given code from the list
 // of accept languages.
 - (void)removeLanguage:(const std::string&)languageCode;

ios/chrome/browser/ui/settings/language_settings_data_source.h

@@ -18,6 +18,10 @@
 // Returns the accept languages list ordered according to the user prefs.
 - (NSArray<LanguageItem*>*)acceptLanguagesItems;
 
+// Returns the supported languages list excluding the accept languages. This
+// list is sorted alphabetically based on display names in the current locale.
+- (NSArray<LanguageItem*>*)supportedLanguagesItems;
+
 // Returns whether or not Translate is enabled.
 - (BOOL)translateEnabled;
 

ios/chrome/browser/ui/settings/language_settings_mediator.mm

@@ -169,6 +169,32 @@
   return acceptLanguages;
 }
 
+- (NSArray<LanguageItem*>*)supportedLanguagesItems {
+  // Get the accept languages.
+  std::vector<std::string> acceptLanguageCodes;
+  _translatePrefs->GetLanguageList(&acceptLanguageCodes);
+
+  // Get the supported languages.
+  std::vector<translate::TranslateLanguageInfo> languages;
+  translate::TranslatePrefs::GetLanguageInfoList(
+      GetApplicationContext()->GetApplicationLocale(),
+      _translatePrefs->IsTranslateAllowedByPolicy(), &languages);
+
+  NSMutableArray<LanguageItem*>* supportedLanguages =
+      [NSMutableArray arrayWithCapacity:languages.size()];
+  for (const auto& language : languages) {
+    // Ignore languages already in the accept languages list.
+    if (std::find(acceptLanguageCodes.begin(), acceptLanguageCodes.end(),
+                  language.code) != acceptLanguageCodes.end()) {
+      continue;
+    }
+    LanguageItem* languageItem = [self languageItemFromLanguage:language];
+    languageItem.accessibilityTraits |= UIAccessibilityTraitButton;
+    [supportedLanguages addObject:languageItem];
+  }
+  return supportedLanguages;
+}
+
 - (BOOL)translateEnabled {
   return self.translateEnabledPref.value;
 }
@@ -198,6 +224,10 @@
                                      languageCodes);
 }
 
+- (void)addLanguage:(const std::string&)languageCode {
+  _translatePrefs->AddToLanguageList(languageCode, /*force_blocked=*/false);
+}
+
 - (void)removeLanguage:(const std::string&)languageCode {
   _translatePrefs->RemoveFromLanguageList(languageCode);
 }

ios/chrome/browser/ui/settings/language_settings_table_view_controller.mm

@@ -7,6 +7,7 @@
 #include "base/logging.h"
 #include "base/mac/foundation_util.h"
 #import "ios/chrome/browser/ui/list_model/list_item+Controller.h"
+#import "ios/chrome/browser/ui/settings/add_language_table_view_controller.h"
 #import "ios/chrome/browser/ui/settings/cells/language_item.h"
 #import "ios/chrome/browser/ui/settings/cells/settings_cells_constants.h"
 #import "ios/chrome/browser/ui/settings/cells/settings_switch_cell.h"
@@ -49,6 +50,7 @@ typedef NS_ENUM(NSInteger, ItemType) {
 }  // namespace
 
 @interface LanguageSettingsTableViewController () <
+    AddLanguageTableViewControllerDelegate,
     LanguageDetailsTableViewControllerDelegate>
 
 // The data source passed to this instance.
@@ -63,6 +65,10 @@ typedef NS_ENUM(NSInteger, ItemType) {
 // A reference to the Translate switch item for quick access.
 @property(nonatomic, weak) SettingsSwitchItem* translateSwitchItem;
 
+// A reference to the presented AddLanguageTableViewController, if any.
+@property(nonatomic, weak)
+    AddLanguageTableViewController* addLanguageTableViewController;
+
 @end
 
 @implementation LanguageSettingsTableViewController
@@ -175,16 +181,36 @@ typedef NS_ENUM(NSInteger, ItemType) {
     didSelectRowAtIndexPath:(NSIndexPath*)indexPath {
   [super tableView:tableView didSelectRowAtIndexPath:indexPath];
 
-  TableViewItem* item = [self.tableViewModel itemAtIndexPath:indexPath];
-  if (item.type == ItemTypeLanguage) {
-    LanguageItem* languageItem = base::mac::ObjCCastStrict<LanguageItem>(item);
-    languageItem.canOfferTranslate =
-        [self canOfferTranslateForLanguage:languageItem];
-    LanguageDetailsTableViewController* viewController =
-        [[LanguageDetailsTableViewController alloc]
-            initWithLanguageItem:languageItem
+  ItemType itemType =
+      (ItemType)[self.tableViewModel itemTypeForIndexPath:indexPath];
+  switch (itemType) {
+    case ItemTypeLanguage: {
+      LanguageItem* languageItem = base::mac::ObjCCastStrict<LanguageItem>(
+          [self.tableViewModel itemAtIndexPath:indexPath]);
+      languageItem.canOfferTranslate =
+          [self canOfferTranslateForLanguage:languageItem];
+      LanguageDetailsTableViewController* viewController =
+          [[LanguageDetailsTableViewController alloc]
+              initWithLanguageItem:languageItem
+                          delegate:self];
+      [self.navigationController pushViewController:viewController
+                                           animated:YES];
+      break;
+    }
+    case ItemTypeAddLanguage: {
+      AddLanguageTableViewController* viewController =
+          [[AddLanguageTableViewController alloc]
+              initWithDataSource:self.dataSource
                         delegate:self];
-    [self.navigationController pushViewController:viewController animated:YES];
+      [self.navigationController pushViewController:viewController
+                                           animated:YES];
+      self.addLanguageTableViewController = viewController;
+      break;
+    }
+    case ItemTypeHeader:
+    case ItemTypeTranslateSwitch:
+      // Not handled.
+      break;
   }
 }
 
@@ -278,7 +304,9 @@ typedef NS_ENUM(NSInteger, ItemType) {
         cellForRowAtIndexPath:(NSIndexPath*)indexPath {
   UITableViewCell* cell = [super tableView:tableView
                      cellForRowAtIndexPath:indexPath];
-  switch ([self.tableViewModel itemTypeForIndexPath:indexPath]) {
+  ItemType itemType =
+      (ItemType)[self.tableViewModel itemTypeForIndexPath:indexPath];
+  switch (itemType) {
     case ItemTypeTranslateSwitch: {
       SettingsSwitchCell* switchCell =
           base::mac::ObjCCastStrict<SettingsSwitchCell>(cell);
@@ -287,10 +315,30 @@ typedef NS_ENUM(NSInteger, ItemType) {
                       forControlEvents:UIControlEventValueChanged];
       break;
     }
+    case ItemTypeHeader:
+    case ItemTypeLanguage:
+    case ItemTypeAddLanguage:
+      // Not handled.
+      break;
   }
   return cell;
 }
 
+#pragma mark - AddLanguageTableViewControllerDelegate
+
+- (void)addLanguageTableViewController:
+            (AddLanguageTableViewController*)tableViewController
+                 didSelectLanguageCode:(const std::string&)languageCode {
+  // Inform the command handler.
+  [self.commandHandler addLanguage:languageCode];
+
+  // Update the model and the table view.
+  [self updateLanguagesSection];
+
+  [self.navigationController popViewControllerAnimated:YES];
+  self.addLanguageTableViewController = nil;
+}
+
 #pragma mark - LanguageDetailsTableViewControllerDelegate
 
 - (void)languageDetailsTableViewController:
@@ -327,6 +375,9 @@ typedef NS_ENUM(NSInteger, ItemType) {
   if (self.isEditing)
     return;
 
+  // Inform the presented AddLanguageTableViewController to update itself.
+  [self.addLanguageTableViewController supportedLanguagesListChanged];
+
   // Update the model and the table view.
   [self updateLanguagesSection];
 }