[iOS][Password Check] Reauthentication before revealing the password

This change adds reauthentication mechanism before revealing password on
Password Details Screen. Reauth will be requested before showing,
editing or copying password. Password editing and copying to be done in
the future CLs.

Bug: 1075494
Change-Id: Idbebddb9dcdb0928af16e115d69c6fe28860c872
Reviewed-on: https://chromium-review.googlesource.com/c/chromium/src/+/2302753
Commit-Queue: Viktor Semeniuk <vsemeniuk@google.com>
Reviewed-by: Gauthier Ambard <gambard@chromium.org>
Cr-Commit-Position: refs/heads/master@{#791791}

ios/chrome/browser/ui/settings/password/BUILD.gn

@@ -38,6 +38,7 @@ source_set("password") {
     "//ios/chrome/browser",
     "//ios/chrome/browser",
     "//ios/chrome/browser/browser_state",
+    "//ios/chrome/browser/main:public",
     "//ios/chrome/browser/passwords",
     "//ios/chrome/browser/signin",
     "//ios/chrome/browser/sync",
@@ -138,6 +139,7 @@ source_set("unit_tests") {
     "//ios/chrome/app/strings",
     "//ios/chrome/app/strings",
     "//ios/chrome/browser/browser_state:test_support",
+    "//ios/chrome/browser/main:test_support",
     "//ios/chrome/browser/passwords",
     "//ios/chrome/browser/ui/settings/cells",
     "//ios/chrome/browser/ui/table_view:test_support",

ios/chrome/browser/ui/settings/password/password_details/BUILD.gn

@@ -19,12 +19,15 @@ source_set("password_details") {
     "//components/url_formatter",
     "//ios/chrome/app/strings",
     "//ios/chrome/browser",
+    "//ios/chrome/browser/main:public",
     "//ios/chrome/browser/passwords",
     "//ios/chrome/browser/ui:feature_flags",
+    "//ios/chrome/browser/ui/alert_coordinator",
     "//ios/chrome/browser/ui/commands",
     "//ios/chrome/browser/ui/coordinators:chrome_coordinators",
     "//ios/chrome/browser/ui/table_view",
     "//ios/chrome/common/ui/colors",
+    "//ios/chrome/common/ui/reauthentication",
     "//ios/chrome/common/ui/util",
     "//ios/web",
     "//ui/base",
@@ -63,6 +66,7 @@ source_set("password_details_ui") {
     "//ios/chrome/browser/ui/table_view/cells:cells_constants",
     "//ios/chrome/browser/ui/util",
     "//ios/chrome/common/ui/colors",
+    "//ios/chrome/common/ui/reauthentication",
     "//ios/chrome/common/ui/util",
     "//ui/base",
   ]
@@ -85,6 +89,7 @@ source_set("unit_tests") {
     "//ios/chrome/app/strings:ios_chromium_strings_grit",
     "//ios/chrome/app/strings:ios_strings_grit",
     "//ios/chrome/browser/browser_state:test_support",
+    "//ios/chrome/browser/main:test_support",
     "//ios/chrome/browser/passwords",
     "//ios/chrome/browser/ui/settings/cells",
     "//ios/chrome/browser/ui/table_view:test_support",
@@ -92,6 +97,7 @@ source_set("unit_tests") {
     "//ios/chrome/browser/ui/table_view/cells:cells_constants",
     "//ios/chrome/browser/ui/util",
     "//ios/chrome/common/ui/colors",
+    "//ios/chrome/common/ui/reauthentication",
     "//ios/chrome/test/app:test_support",
     "//ios/web/public/test",
     "//testing/gmock",

ios/chrome/browser/ui/settings/password/password_details/password_details_coordinator.h

@@ -8,8 +8,10 @@
 #import "ios/chrome/browser/ui/coordinators/chrome_coordinator.h"
 
 @protocol ApplicationCommands;
+class Browser;
 class IOSChromePasswordCheckManager;
 @protocol PasswordDetailsCoordinatorDelegate;
+@class ReauthenticationModule;
 
 namespace autofill {
 struct PasswordForm;
@@ -21,9 +23,10 @@ struct PasswordForm;
 - (instancetype)
     initWithBaseNavigationController:
         (UINavigationController*)navigationController
+                             browser:(Browser*)browser
                             password:(const autofill::PasswordForm&)password
+                        reauthModule:(ReauthenticationModule*)reauthModule
                 passwordCheckManager:(IOSChromePasswordCheckManager*)manager
-                          dispatcher:(id<ApplicationCommands>)dispatcher
     NS_DESIGNATED_INITIALIZER;
 
 - (instancetype)initWithBaseViewController:(UIViewController*)viewController
@@ -32,6 +35,9 @@ struct PasswordForm;
 // Delegate.
 @property(nonatomic, weak) id<PasswordDetailsCoordinatorDelegate> delegate;
 
+// Dispatcher.
+@property(nonatomic, weak) id<ApplicationCommands> dispatcher;
+
 @end
 
 #endif  // IOS_CHROME_BROWSER_UI_SETTINGS_PASSWORD_PASSWORD_DETAILS_PASSWORD_DETAILS_COORDINATOR_H_

ios/chrome/browser/ui/settings/password/password_details/password_details_coordinator.mm

@@ -6,12 +6,19 @@
 
 #include "base/mac/foundation_util.h"
 #include "components/autofill/core/common/password_form.h"
+#include "components/strings/grit/components_strings.h"
+#import "ios/chrome/browser/main/browser.h"
+#import "ios/chrome/browser/ui/alert_coordinator/alert_coordinator.h"
+#import "ios/chrome/browser/ui/commands/application_commands.h"
+#import "ios/chrome/browser/ui/commands/open_new_tab_command.h"
 #import "ios/chrome/browser/ui/settings/password/password_details/password_details_consumer.h"
 #import "ios/chrome/browser/ui/settings/password/password_details/password_details_coordinator_delegate.h"
 #import "ios/chrome/browser/ui/settings/password/password_details/password_details_handler.h"
 #import "ios/chrome/browser/ui/settings/password/password_details/password_details_mediator.h"
 #import "ios/chrome/browser/ui/settings/password/password_details/password_details_view_controller.h"
 #include "ios/chrome/browser/ui/ui_feature_flags.h"
+#import "ios/chrome/common/ui/reauthentication/reauthentication_module.h"
+#include "ios/chrome/grit/ios_strings.h"
 #include "ui/base/l10n/l10n_util.h"
 
 #if !defined(__has_feature) || !__has_feature(objc_arc)
@@ -31,8 +38,12 @@
 // Main mediator for this coordinator.
 @property(nonatomic, strong) PasswordDetailsMediator* mediator;
 
-// Dispatcher.
-@property(nonatomic, weak) id<ApplicationCommands> dispatcher;
+// Module containing the reauthentication mechanism for viewing and copying
+// passwords.
+@property(nonatomic, weak) ReauthenticationModule* reauthenticationModule;
+
+// Modal alert for interactions with password.
+@property(nonatomic, strong) AlertCoordinator* alertCoordinator;
 
 @end
 
@@ -43,19 +54,20 @@
 - (instancetype)
     initWithBaseNavigationController:
         (UINavigationController*)navigationController
+                             browser:(Browser*)browser
                             password:(const autofill::PasswordForm&)password
-                passwordCheckManager:(IOSChromePasswordCheckManager*)manager
-                          dispatcher:(id<ApplicationCommands>)dispatcher {
-  self = [super initWithBaseViewController:navigationController browser:nil];
+                        reauthModule:(ReauthenticationModule*)reauthModule
+                passwordCheckManager:(IOSChromePasswordCheckManager*)manager {
+  self = [super initWithBaseViewController:navigationController
+                                   browser:browser];
   if (self) {
     DCHECK(navigationController);
     DCHECK(manager);
-    DCHECK(dispatcher);
 
     _baseNavigationController = navigationController;
     _password = password;
     _manager = manager;
-    _dispatcher = dispatcher;
+    _reauthenticationModule = reauthModule;
   }
   return self;
 }
@@ -73,6 +85,7 @@
   self.mediator.consumer = self.viewController;
   self.viewController.handler = self;
   self.viewController.commandsDispatcher = self.dispatcher;
+  self.viewController.reauthModule = self.reauthenticationModule;
 
   [self.baseNavigationController pushViewController:self.viewController
                                            animated:YES];
@@ -90,4 +103,34 @@
   [self.delegate passwordDetailsCoordinatorDidRemove:self];
 }
 
+- (void)showPasscodeDialog {
+  NSString* title =
+      l10n_util::GetNSString(IDS_IOS_SETTINGS_SET_UP_SCREENLOCK_TITLE);
+  NSString* message =
+      l10n_util::GetNSString(IDS_IOS_SETTINGS_SET_UP_SCREENLOCK_CONTENT);
+  self.alertCoordinator = [[AlertCoordinator alloc]
+      initWithBaseViewController:self.baseViewController
+                         browser:self.browser
+                           title:title
+                         message:message];
+
+  __weak __typeof(self) weakSelf = self;
+  OpenNewTabCommand* command =
+      [OpenNewTabCommand commandWithURLFromChrome:GURL(kPasscodeArticleURL)];
+
+  [self.alertCoordinator addItemWithTitle:l10n_util::GetNSString(IDS_OK)
+                                   action:nil
+                                    style:UIAlertActionStyleCancel];
+
+  [self.alertCoordinator
+      addItemWithTitle:l10n_util::GetNSString(
+                           IDS_IOS_SETTINGS_SET_UP_SCREENLOCK_LEARN_HOW)
+                action:^{
+                  [weakSelf.dispatcher closeSettingsUIAndOpenURL:command];
+                }
+                 style:UIAlertActionStyleDefault];
+
+  [self.alertCoordinator start];
+}
+
 @end

ios/chrome/browser/ui/settings/password/password_details/password_details_handler.h

@@ -11,6 +11,10 @@
 // Called when the view controller was dismissed.
 - (void)passwordDetailsViewControllerDidDisappear;
 
+// Shows a dialog offering the user to set a passcode in order to see the
+// password.
+- (void)showPasscodeDialog;
+
 @end
 
 #endif  // IOS_CHROME_BROWSER_UI_SETTINGS_PASSWORD_PASSWORD_DETAILS_PASSWORD_DETAILS_HANDLER_H_

ios/chrome/browser/ui/settings/password/password_details/password_details_view_controller.h

@@ -11,6 +11,7 @@
 @protocol ApplicationCommands;
 @protocol PasswordDetailsHandler;
 @protocol PasswordDetailsViewControllerDelegate;
+@protocol ReauthenticationProtocol;
 
 // Screen which shows password details and allows to edit it.
 @interface PasswordDetailsViewController
@@ -25,6 +26,10 @@
 // Dispatcher for this ViewController.
 @property(nonatomic, weak) id<ApplicationCommands> commandsDispatcher;
 
+// Module containing the reauthentication mechanism for interections
+// with password.
+@property(nonatomic, weak) id<ReauthenticationProtocol> reauthModule;
+
 @end
 
 #endif  // IOS_CHROME_BROWSER_UI_SETTINGS_PASSWORD_PASSWORD_DETAILS_PASSWORD_DETAILS_VIEW_CONTROLLER_H_

ios/chrome/browser/ui/settings/password/password_details/password_details_view_controller.mm

@@ -5,7 +5,9 @@
 #import "ios/chrome/browser/ui/settings/password/password_details/password_details_view_controller.h"
 
 #include "base/mac/foundation_util.h"
+#include "base/metrics/histogram_macros.h"
 #include "base/strings/sys_string_conversions.h"
+#include "components/password_manager/core/browser/password_manager_metrics_util.h"
 #import "ios/chrome/browser/ui/commands/application_commands.h"
 #import "ios/chrome/browser/ui/commands/open_new_tab_command.h"
 #import "ios/chrome/browser/ui/settings/cells/settings_image_detail_text_item.h"
@@ -19,6 +21,7 @@
 #import "ios/chrome/browser/ui/table_view/cells/table_view_text_item.h"
 #import "ios/chrome/common/ui/colors/UIColor+cr_semantic_colors.h"
 #import "ios/chrome/common/ui/colors/semantic_color_names.h"
+#import "ios/chrome/common/ui/reauthentication/reauthentication_module.h"
 #include "ios/chrome/grit/ios_chromium_strings.h"
 #include "ios/chrome/grit/ios_strings.h"
 #include "ui/base/l10n/l10n_util_mac.h"
@@ -29,6 +32,9 @@
 
 namespace {
 
+using password_manager::metrics_util::LogPasswordSettingsReauthResult;
+using password_manager::metrics_util::ReauthResult;
+
 // Padding used between the image and the text labels.
 const CGFloat kWarningIconSize = 20;
 
@@ -45,6 +51,12 @@ typedef NS_ENUM(NSInteger, ItemType) {
   ItemTypeChangePasswordRecommendation,
 };
 
+typedef NS_ENUM(NSInteger, ReauthenticationReason) {
+  ReauthenticationReasonShow = 0,
+  ReauthenticationReasonCopy,
+  ReauthenticationReasonEdit,
+};
+
 }  // namespace
 
 @interface PasswordDetailsViewController ()
@@ -78,8 +90,13 @@ typedef NS_ENUM(NSInteger, ItemType) {
 #pragma mark - ChromeTableViewController
 
 - (void)editButtonPressed {
-  // TODO:(crbug.com/1075494) - Request reauth if user clicked edit and password
-  // was not shown.
+  // Request reauthentication before revealing password during editing.
+  // Editing mode will be entered on successful reauth.
+  if (!self.tableView.editing && !self.isPasswordShown) {
+    [self attemptToShowPasswordFor:ReauthenticationReasonEdit];
+    return;
+  }
+
   [super editButtonPressed];
 
   if (!self.tableView.editing) {
@@ -88,13 +105,7 @@ typedef NS_ENUM(NSInteger, ItemType) {
                           didEditPasswordDetails:self.password];
   }
 
-  [self loadModel];
-  [self reconfigureCellsForItems:
-            [self.tableViewModel
-                itemsInSectionWithIdentifier:SectionIdentifierPassword]];
-  [self reconfigureCellsForItems:
-            [self.tableViewModel
-                itemsInSectionWithIdentifier:SectionIdentifierCompromisedInfo]];
+  [self reloadData];
 }
 
 - (void)loadModel {
@@ -314,20 +325,134 @@ typedef NS_ENUM(NSInteger, ItemType) {
   return newImage;
 }
 
+// Shows reauthentication dialog if needed. If the reauthentication is
+// successful reveals the password.
+- (void)attemptToShowPasswordFor:(ReauthenticationReason)reason {
+  // If password was already shown (before editing or copying) we don't need to
+  // request reauth again.
+  if (self.isPasswordShown) {
+    [self showPasswordFor:reason];
+    return;
+  }
+
+  if ([self.reauthModule canAttemptReauth]) {
+    __weak __typeof(self) weakSelf = self;
+    void (^showPasswordHandler)(ReauthenticationResult) =
+        ^(ReauthenticationResult result) {
+          PasswordDetailsViewController* strongSelf = weakSelf;
+          if (!strongSelf)
+            return;
+          [strongSelf logPasswordSettingsReauthResult:result];
+
+          if (result == ReauthenticationResult::kFailure)
+            return;
+
+          [strongSelf showPasswordFor:reason];
+        };
+
+    [self.reauthModule
+        attemptReauthWithLocalizedReason:[self getLocalizedStringFor:reason]
+                    canReusePreviousAuth:YES
+                                 handler:showPasswordHandler];
+  } else {
+    [self.handler showPasscodeDialog];
+  }
+}
+
+// Reveals password to the user.
+- (void)showPasswordFor:(ReauthenticationReason)reason {
+  switch (reason) {
+    case ReauthenticationReasonShow:
+      self.passwordShown = YES;
+      self.passwordTextItem.textFieldValue = self.password.password;
+      self.passwordTextItem.identifyingIcon =
+          [[UIImage imageNamed:@"infobar_hide_password_icon"]
+              imageWithRenderingMode:UIImageRenderingModeAlwaysTemplate];
+      [self reconfigureCellsForItems:@[ self.passwordTextItem ]];
+      break;
+    case ReauthenticationReasonCopy:
+      // TODO:(crbug.com/1075494) - Implement copy password functionality.
+      break;
+    case ReauthenticationReasonEdit:
+      // Called super because we want to update only |tableView.editing|.
+      [super editButtonPressed];
+      [self reloadData];
+      break;
+  }
+  [self logPasswordAccessWith:reason];
+}
+
+// Returns localized reason for reauthentication dialog.
+- (NSString*)getLocalizedStringFor:(ReauthenticationReason)reason {
+  switch (reason) {
+    case ReauthenticationReasonShow:
+      return l10n_util::GetNSString(
+          IDS_IOS_SETTINGS_PASSWORD_REAUTH_REASON_SHOW);
+    case ReauthenticationReasonCopy:
+      return l10n_util::GetNSString(
+          IDS_IOS_SETTINGS_PASSWORD_REAUTH_REASON_COPY);
+    case ReauthenticationReasonEdit:
+      // TODO:(crbug.com/1075494) - Add custom string for edit.
+      return l10n_util::GetNSString(
+          IDS_IOS_SETTINGS_PASSWORD_REAUTH_REASON_SHOW);
+  }
+}
+
 #pragma mark - Actions
 
 // Called when the user tapped on the show/hide button near password.
 - (void)didTapShowHideButton:(UIButton*)buttonView {
-  // TODO:(crbug.com/1075494) - Request reauth before revealing the password.
-  self.passwordShown = !self.passwordShown;
-  self.passwordTextItem.textFieldValue =
-      [self isPasswordShown] ? self.password.password : kMaskedPassword;
-  NSString* image = self.isPasswordShown ? @"infobar_hide_password_icon"
-                                         : @"infobar_reveal_password_icon";
-  self.passwordTextItem.identifyingIcon = [[UIImage imageNamed:image]
-      imageWithRenderingMode:UIImageRenderingModeAlwaysTemplate];
-
-  [self reconfigureCellsForItems:@[ self.passwordTextItem ]];
+  if (self.isPasswordShown) {
+    self.passwordShown = NO;
+    self.passwordTextItem.textFieldValue = kMaskedPassword;
+    self.passwordTextItem.identifyingIcon =
+        [[UIImage imageNamed:@"infobar_reveal_password_icon"]
+            imageWithRenderingMode:UIImageRenderingModeAlwaysTemplate];
+    [self reconfigureCellsForItems:@[ self.passwordTextItem ]];
+  } else {
+    [self attemptToShowPasswordFor:ReauthenticationReasonShow];
+  }
+}
+
+#pragma mark - Metrics
+
+// Logs metrics for the given reauthentication |result| (success, failure or
+// skipped).
+- (void)logPasswordSettingsReauthResult:(ReauthenticationResult)result {
+  switch (result) {
+    case ReauthenticationResult::kSuccess:
+      LogPasswordSettingsReauthResult(ReauthResult::kSuccess);
+      break;
+    case ReauthenticationResult::kFailure:
+      LogPasswordSettingsReauthResult(ReauthResult::kFailure);
+      break;
+    case ReauthenticationResult::kSkipped:
+      LogPasswordSettingsReauthResult(ReauthResult::kSkipped);
+      break;
+  }
+}
+
+- (void)logPasswordAccessWith:(ReauthenticationReason)reason {
+  switch (reason) {
+    case ReauthenticationReasonShow:
+      UMA_HISTOGRAM_ENUMERATION(
+          "PasswordManager.AccessPasswordInSettings",
+          password_manager::metrics_util::ACCESS_PASSWORD_VIEWED,
+          password_manager::metrics_util::ACCESS_PASSWORD_COUNT);
+      break;
+    case ReauthenticationReasonCopy:
+      UMA_HISTOGRAM_ENUMERATION(
+          "PasswordManager.AccessPasswordInSettings",
+          password_manager::metrics_util::ACCESS_PASSWORD_COPIED,
+          password_manager::metrics_util::ACCESS_PASSWORD_COUNT);
+      break;
+    case ReauthenticationReasonEdit:
+      UMA_HISTOGRAM_ENUMERATION(
+          "PasswordManager.AccessPasswordInSettings",
+          password_manager::metrics_util::ACCESS_PASSWORD_EDITED,
+          password_manager::metrics_util::ACCESS_PASSWORD_COUNT);
+      break;
+  }
 }
 
 @end

ios/chrome/browser/ui/settings/password/password_details/password_detials_view_controller_unittest.mm

@@ -6,6 +6,7 @@
 
 #include <memory>
 
+#include "base/mac/foundation_util.h"
 #include "base/strings/utf_string_conversions.h"
 #include "components/autofill/core/common/password_form.h"
 #include "ios/chrome/browser/browser_state/test_chrome_browser_state.h"
@@ -17,8 +18,10 @@
 #import "ios/chrome/browser/ui/table_view/cells/table_view_cells_constants.h"
 #import "ios/chrome/browser/ui/table_view/cells/table_view_text_edit_item.h"
 #import "ios/chrome/browser/ui/table_view/chrome_table_view_controller_test.h"
+#import "ios/chrome/common/ui/reauthentication/reauthentication_module.h"
 #include "ios/chrome/grit/ios_chromium_strings.h"
 #include "ios/chrome/grit/ios_strings.h"
+#include "ios/chrome/test/app/password_test_util.h"
 #include "ios/web/public/test/web_task_environment.h"
 #include "testing/gtest/include/gtest/gtest.h"
 #include "testing/gtest_mac.h"
@@ -39,6 +42,9 @@
 - (void)passwordDetailsViewControllerDidDisappear {
 }
 
+- (void)showPasscodeDialog {
+}
+
 @end
 
 // Test class that conforms to PasswordDetailsViewControllerDelegate in order to
@@ -62,6 +68,8 @@ class PasswordDetailsViewControllerTest : public ChromeTableViewControllerTest {
   PasswordDetailsViewControllerTest() {
     handler_ = [[FakePasswordDetailsHandler alloc] init];
     delegate_ = [[FakePasswordDetailsDelegate alloc] init];
+    reauthentication_module_ = [[MockReauthenticationModule alloc] init];
+    reauthentication_module_.expectedResult = ReauthenticationResult::kSuccess;
   }
 
   ChromeTableViewController* InstantiateController() override {
@@ -70,10 +78,11 @@ class PasswordDetailsViewControllerTest : public ChromeTableViewControllerTest {
             initWithStyle:UITableViewStylePlain];
     controller.handler = handler_;
     controller.delegate = delegate_;
+    controller.reauthModule = reauthentication_module_;
     return controller;
   }
 
-  void ShowPassword(bool isCompromised = false) {
+  void SetPassword(bool isCompromised = false) {
     auto form = autofill::PasswordForm();
     form.url = GURL("http://www.example.com/");
     form.action = GURL("http://www.example.com/accounts/Login");
@@ -111,10 +120,12 @@ class PasswordDetailsViewControllerTest : public ChromeTableViewControllerTest {
 
   FakePasswordDetailsHandler* handler() { return handler_; }
   FakePasswordDetailsDelegate* delegate() { return delegate_; }
+  MockReauthenticationModule* reauth() { return reauthentication_module_; }
 
  private:
   FakePasswordDetailsHandler* handler_;
   FakePasswordDetailsDelegate* delegate_;
+  MockReauthenticationModule* reauthentication_module_;
 };
 
 // Tests PasswordDetailsViewController is set up with appropriate items
@@ -129,7 +140,7 @@ TEST_F(PasswordDetailsViewControllerTest, TestModel) {
 
 // Tests that password is displayed properly.
 TEST_F(PasswordDetailsViewControllerTest, TestPassword) {
-  ShowPassword();
+  SetPassword();
   EXPECT_EQ(1, NumberOfSections());
   EXPECT_EQ(3, NumberOfItemsInSection(0));
 
@@ -141,7 +152,7 @@ TEST_F(PasswordDetailsViewControllerTest, TestPassword) {
 
 // Tests that compromised password is displayed properly.
 TEST_F(PasswordDetailsViewControllerTest, TestCompromisedPassword) {
-  ShowPassword(true);
+  SetPassword(true);
   EXPECT_EQ(2, NumberOfSections());
   EXPECT_EQ(3, NumberOfItemsInSection(0));
   EXPECT_EQ(2, NumberOfItemsInSection(1));
@@ -155,3 +166,72 @@ TEST_F(PasswordDetailsViewControllerTest, TestCompromisedPassword) {
   CheckDetailItemTextWithId(IDS_IOS_CHANGE_COMPROMISED_PASSWORD_DESCRIPTION, 1,
                             1);
 }
+
+// Tests that password is shown/hidden.
+TEST_F(PasswordDetailsViewControllerTest, TestShowHidePassword) {
+  SetPassword();
+
+  CheckEditCellText(kMaskedPassword, 0, 2);
+
+  NSIndexPath* indexOfPassword = [NSIndexPath indexPathForRow:2 inSection:0];
+  TableViewTextEditCell* textFieldCell =
+      base::mac::ObjCCastStrict<TableViewTextEditCell>(
+          [controller().tableView cellForRowAtIndexPath:indexOfPassword]);
+  [textFieldCell.identifyingIconButton
+      sendActionsForControlEvents:UIControlEventTouchUpInside];
+
+  CheckEditCellText(@"test", 0, 2);
+  EXPECT_NSEQ(
+      l10n_util::GetNSString(IDS_IOS_SETTINGS_PASSWORD_REAUTH_REASON_SHOW),
+      reauth().localizedReasonForAuthentication);
+
+  [textFieldCell.identifyingIconButton
+      sendActionsForControlEvents:UIControlEventTouchUpInside];
+  CheckEditCellText(kMaskedPassword, 0, 2);
+}
+
+// Tests that passwords was not shown in case reauth failed.
+TEST_F(PasswordDetailsViewControllerTest, TestShowPasswordReauthFailed) {
+  SetPassword();
+
+  CheckEditCellText(kMaskedPassword, 0, 2);
+
+  reauth().expectedResult = ReauthenticationResult::kFailure;
+  NSIndexPath* indexOfPassword = [NSIndexPath indexPathForRow:2 inSection:0];
+  TableViewTextEditCell* textFieldCell =
+      base::mac::ObjCCastStrict<TableViewTextEditCell>(
+          [controller().tableView cellForRowAtIndexPath:indexOfPassword]);
+  [textFieldCell.identifyingIconButton
+      sendActionsForControlEvents:UIControlEventTouchUpInside];
+
+  CheckEditCellText(kMaskedPassword, 0, 2);
+}
+
+// Tests that password was revealed during editing.
+TEST_F(PasswordDetailsViewControllerTest, TestPasswordShownDuringEditing) {
+  SetPassword();
+  CheckEditCellText(kMaskedPassword, 0, 2);
+
+  PasswordDetailsViewController* passwordDetails =
+      base::mac::ObjCCastStrict<PasswordDetailsViewController>(controller());
+  [passwordDetails editButtonPressed];
+  EXPECT_TRUE(passwordDetails.tableView.editing);
+  CheckEditCellText(@"test", 0, 2);
+
+  [passwordDetails editButtonPressed];
+  EXPECT_FALSE(passwordDetails.tableView.editing);
+  CheckEditCellText(kMaskedPassword, 0, 2);
+}
+
+// Tests that editing mode was not entered because reauth failed.
+TEST_F(PasswordDetailsViewControllerTest, TestEditingReauthFailed) {
+  SetPassword();
+  CheckEditCellText(kMaskedPassword, 0, 2);
+
+  reauth().expectedResult = ReauthenticationResult::kFailure;
+  PasswordDetailsViewController* passwordDetails =
+      base::mac::ObjCCastStrict<PasswordDetailsViewController>(controller());
+  [passwordDetails editButtonPressed];
+  EXPECT_FALSE(passwordDetails.tableView.editing);
+  CheckEditCellText(kMaskedPassword, 0, 2);
+}

ios/chrome/browser/ui/settings/password/password_issues_coordinator.h

@@ -8,8 +8,10 @@
 #import "ios/chrome/browser/ui/coordinators/chrome_coordinator.h"
 
 @protocol ApplicationCommands;
+class Browser;
 class IOSChromePasswordCheckManager;
 @class PasswordIssuesCoordinator;
+@class ReauthenticationModule;
 
 // Delegate for PasswordIssuesCoordinator.
 @protocol PasswordIssuesCoordinatorDelegate
@@ -25,6 +27,7 @@ class IOSChromePasswordCheckManager;
 
 - (instancetype)initWithBaseNavigationController:
                     (UINavigationController*)navigationController
+                                         browser:(Browser*)browser
                             passwordCheckManager:
                                 (IOSChromePasswordCheckManager*)manager
     NS_DESIGNATED_INITIALIZER;
@@ -32,6 +35,9 @@ class IOSChromePasswordCheckManager;
 - (instancetype)initWithBaseViewController:(UIViewController*)viewController
                                    browser:(Browser*)browser NS_UNAVAILABLE;
 
+// Reauthentication module used by password details coordinator.
+@property(nonatomic, strong) ReauthenticationModule* reauthModule;
+
 @property(nonatomic, weak) id<PasswordIssuesCoordinatorDelegate> delegate;
 
 @property(nonatomic, weak) id<ApplicationCommands> dispatcher;

ios/chrome/browser/ui/settings/password/password_issues_coordinator.mm

@@ -5,6 +5,7 @@
 #import "ios/chrome/browser/ui/settings/password/password_issues_coordinator.h"
 
 #include "base/mac/foundation_util.h"
+#import "ios/chrome/browser/main/browser.h"
 #import "ios/chrome/browser/ui/settings/password/password_details/password_details_coordinator.h"
 #import "ios/chrome/browser/ui/settings/password/password_details/password_details_coordinator_delegate.h"
 #import "ios/chrome/browser/ui/settings/password/password_issue_with_form.h"
@@ -13,6 +14,7 @@
 #import "ios/chrome/browser/ui/settings/password/password_issues_presenter.h"
 #import "ios/chrome/browser/ui/settings/password/password_issues_table_view_controller.h"
 #include "ios/chrome/browser/ui/ui_feature_flags.h"
+#import "ios/chrome/common/ui/reauthentication/reauthentication_module.h"
 #include "ui/base/l10n/l10n_util.h"
 
 #if !defined(__has_feature) || !__has_feature(objc_arc)
@@ -42,9 +44,11 @@
 
 - (instancetype)initWithBaseNavigationController:
                     (UINavigationController*)navigationController
+                                         browser:(Browser*)browser
                             passwordCheckManager:
                                 (IOSChromePasswordCheckManager*)manager {
-  self = [super initWithBaseViewController:navigationController browser:nil];
+  self = [super initWithBaseViewController:navigationController
+                                   browser:browser];
   if (self) {
     _baseNavigationController = navigationController;
     _manager = manager;
@@ -66,6 +70,13 @@
 
   self.mediator =
       [[PasswordIssuesMediator alloc] initWithPasswordCheckManager:_manager];
+  // If reauthentication module was not provided, coordinator will create its
+  // own.
+  if (!self.reauthModule) {
+    self.reauthModule = [[ReauthenticationModule alloc]
+        initWithSuccessfulReauthTimeAccessor:self.mediator];
+  }
+
   self.mediator.consumer = self.viewController;
   self.viewController.presenter = self;
 
@@ -95,9 +106,11 @@
   DCHECK(!self.passwordDetails);
   self.passwordDetails = [[PasswordDetailsCoordinator alloc]
       initWithBaseNavigationController:self.baseNavigationController
+                               browser:self.browser
                               password:form
-                  passwordCheckManager:_manager
-                            dispatcher:self.dispatcher];
+                          reauthModule:self.reauthModule
+                  passwordCheckManager:_manager];
+  self.passwordDetails.dispatcher = self.dispatcher;
   self.passwordDetails.delegate = self;
   [self.passwordDetails start];
 }

ios/chrome/browser/ui/settings/password/password_issues_mediator.h

@@ -7,11 +7,13 @@
 
 #import <Foundation/Foundation.h>
 
+#import "ios/chrome/common/ui/reauthentication/reauthentication_module.h"
+
 class IOSChromePasswordCheckManager;
 @protocol PasswordIssuesConsumer;
 
 // This mediator fetches and organises the credentials for its consumer.
-@interface PasswordIssuesMediator : NSObject
+@interface PasswordIssuesMediator : NSObject <SuccessfulReauthTimeAccessor>
 
 - (instancetype)initWithPasswordCheckManager:
     (IOSChromePasswordCheckManager*)manager NS_DESIGNATED_INITIALIZER;

ios/chrome/browser/ui/settings/password/password_issues_mediator.mm

@@ -20,6 +20,12 @@
   std::vector<password_manager::CredentialWithPassword> _compromisedCredentials;
 }
 
+// Object storing the time of the previous successful re-authentication.
+// This is meant to be used by the |ReauthenticationModule| for keeping
+// re-authentications valid for a certain time interval within the scope
+// of the Password Issues Screen.
+@property(nonatomic, strong, readonly) NSDate* successfulReauthTime;
+
 @end
 
 @implementation PasswordIssuesMediator
@@ -69,4 +75,14 @@
   [self.consumer setPasswordIssues:passwords];
 }
 
+#pragma mark SuccessfulReauthTimeAccessor
+
+- (void)updateSuccessfulReauthTime {
+  _successfulReauthTime = [[NSDate alloc] init];
+}
+
+- (NSDate*)lastSuccessfulReauthTime {
+  return [self successfulReauthTime];
+}
+
 @end

ios/chrome/browser/ui/settings/password/passwords_table_view_controller.h

@@ -10,16 +10,15 @@
 #import "ios/chrome/browser/ui/settings/settings_navigation_controller.h"
 #import "ios/chrome/browser/ui/settings/settings_root_table_view_controller.h"
 
-class ChromeBrowserState;
+class Browser;
 @protocol ReauthenticationProtocol;
 @class PasswordExporter;
 
 @interface PasswordsTableViewController
     : SettingsRootTableViewController <SettingsControllerProtocol>
 
-// The designated initializer. |browserState| must not be nil.
-- (instancetype)initWithBrowserState:(ChromeBrowserState*)browserState
-    NS_DESIGNATED_INITIALIZER;
+// The designated initializer. |browser| must not be nil.
+- (instancetype)initWithBrowser:(Browser*)browser NS_DESIGNATED_INITIALIZER;
 
 - (instancetype)initWithStyle:(UITableViewStyle)style NS_UNAVAILABLE;
 

ios/chrome/browser/ui/settings/password/passwords_table_view_controller.mm

@@ -32,6 +32,7 @@
 #include "components/url_formatter/url_formatter.h"
 #include "ios/chrome/browser/application_context.h"
 #include "ios/chrome/browser/browser_state/chrome_browser_state.h"
+#import "ios/chrome/browser/main/browser.h"
 #include "ios/chrome/browser/passwords/ios_chrome_password_check_manager.h"
 #include "ios/chrome/browser/passwords/ios_chrome_password_check_manager_factory.h"
 #include "ios/chrome/browser/passwords/ios_chrome_password_store_factory.h"
@@ -213,6 +214,8 @@ std::vector<std::unique_ptr<autofill::PasswordForm>> CopyOf(
   password_manager::DuplicatesMap _savedPasswordDuplicates;
   // Map containing duplicates of blocked passwords.
   password_manager::DuplicatesMap _blockedPasswordDuplicates;
+  // The browser where the screen is being displayed.
+  Browser* _browser;
   // The current Chrome browser state.
   ChromeBrowserState* _browserState;
   // Authentication Service Observer.
@@ -252,14 +255,15 @@ std::vector<std::unique_ptr<autofill::PasswordForm>> CopyOf(
 
 #pragma mark - Initialization
 
-- (instancetype)initWithBrowserState:(ChromeBrowserState*)browserState {
-  DCHECK(browserState);
+- (instancetype)initWithBrowser:(Browser*)browser {
+  DCHECK(browser);
   UITableViewStyle style = base::FeatureList::IsEnabled(kSettingsRefresh)
                                ? UITableViewStylePlain
                                : UITableViewStyleGrouped;
   self = [super initWithStyle:style];
   if (self) {
-    _browserState = browserState;
+    _browser = browser;
+    _browserState = browser->GetBrowserState();
     _reauthenticationModule = [[ReauthenticationModule alloc]
         initWithSuccessfulReauthTimeAccessor:self];
     _passwordExporter = [[PasswordExporter alloc]
@@ -1197,9 +1201,11 @@ std::vector<std::unique_ptr<autofill::PasswordForm>> CopyOf(
   DCHECK(!_passwordIssuesCoordinator);
   _passwordIssuesCoordinator = [[PasswordIssuesCoordinator alloc]
       initWithBaseNavigationController:self.navigationController
+                               browser:_browser
                   passwordCheckManager:_passwordCheck.get()];
   _passwordIssuesCoordinator.delegate = self;
   _passwordIssuesCoordinator.dispatcher = self.dispatcher;
+  _passwordIssuesCoordinator.reauthModule = _reauthenticationModule;
   [_passwordIssuesCoordinator start];
 }
 

ios/chrome/browser/ui/settings/password/passwords_table_view_controller_unittest.mm

@@ -18,7 +18,7 @@
 #include "components/password_manager/core/browser/password_manager_test_utils.h"
 #include "components/password_manager/core/browser/test_password_store.h"
 #include "components/password_manager/core/common/password_manager_features.h"
-#include "ios/chrome/browser/browser_state/test_chrome_browser_state.h"
+#include "ios/chrome/browser/main/test_browser.h"
 #include "ios/chrome/browser/passwords/ios_chrome_bulk_leak_check_service_factory.h"
 #include "ios/chrome/browser/passwords/ios_chrome_password_check_manager.h"
 #include "ios/chrome/browser/passwords/ios_chrome_password_store_factory.h"
@@ -90,18 +90,17 @@ class PasswordsTableViewControllerTest
           password_manager::features::kPasswordCheck);
     }
 
-    TestChromeBrowserState::Builder test_cbs_builder;
-    chrome_browser_state_ = test_cbs_builder.Build();
+    browser_ = std::make_unique<TestBrowser>();
     ChromeTableViewControllerTest::SetUp();
     IOSChromePasswordStoreFactory::GetInstance()->SetTestingFactory(
-        chrome_browser_state_.get(),
+        browser_->GetBrowserState(),
         base::BindRepeating(
             &password_manager::BuildPasswordStore<web::BrowserState,
                                                   TestPasswordStore>));
 
     IOSChromeBulkLeakCheckServiceFactory::GetInstance()
         ->SetTestingFactoryAndUse(
-            chrome_browser_state_.get(),
+            browser_->GetBrowserState(),
             base::BindLambdaForTesting([](web::BrowserState*) {
               return std::unique_ptr<KeyedService>(
                   std::make_unique<MockBulkLeakCheckService>());
@@ -129,19 +128,19 @@ class PasswordsTableViewControllerTest
   TestPasswordStore& GetTestStore() {
     return *static_cast<TestPasswordStore*>(
         IOSChromePasswordStoreFactory::GetForBrowserState(
-            chrome_browser_state_.get(), ServiceAccessType::EXPLICIT_ACCESS)
+            browser_->GetBrowserState(), ServiceAccessType::EXPLICIT_ACCESS)
             .get());
   }
 
   MockBulkLeakCheckService& GetMockPasswordCheckService() {
     return *static_cast<MockBulkLeakCheckService*>(
         IOSChromeBulkLeakCheckServiceFactory::GetForBrowserState(
-            chrome_browser_state_.get()));
+            browser_->GetBrowserState()));
   }
 
   ChromeTableViewController* InstantiateController() override {
-    return [[PasswordsTableViewController alloc]
-        initWithBrowserState:chrome_browser_state_.get()];
+    return
+        [[PasswordsTableViewController alloc] initWithBrowser:browser_.get()];
   }
 
   void ChangePasswordCheckState(PasswordCheckUIState state) {
@@ -275,7 +274,7 @@ class PasswordsTableViewControllerTest
   void RunUntilIdle() { task_environment_.RunUntilIdle(); }
 
   web::WebTaskEnvironment task_environment_;
-  std::unique_ptr<TestChromeBrowserState> chrome_browser_state_;
+  std::unique_ptr<TestBrowser> browser_;
   base::test::ScopedFeatureList scoped_feature_list_;
 };
 

ios/chrome/browser/ui/settings/settings_navigation_controller.mm

@@ -143,8 +143,7 @@ NSString* const kSettingsDoneButtonId = @"kSettingsDoneButtonId";
                                           delegate {
   DCHECK(browser);
   PasswordsTableViewController* controller =
-      [[PasswordsTableViewController alloc]
-          initWithBrowserState:browser->GetBrowserState()];
+      [[PasswordsTableViewController alloc] initWithBrowser:browser];
   controller.dispatcher = [delegate handlerForSettings];
 
   SettingsNavigationController* nc = [[SettingsNavigationController alloc]
@@ -522,8 +521,7 @@ NSString* const kSettingsDoneButtonId = @"kSettingsDoneButtonId";
 - (void)showSavedPasswordsSettingsFromViewController:
     (UIViewController*)baseViewController {
   PasswordsTableViewController* controller =
-      [[PasswordsTableViewController alloc]
-          initWithBrowserState:self.browser->GetBrowserState()];
+      [[PasswordsTableViewController alloc] initWithBrowser:self.browser];
   controller.dispatcher = [self.settingsNavigationDelegate handlerForSettings];
   [self pushViewController:controller animated:YES];
 }

ios/chrome/browser/ui/settings/settings_table_view_controller.mm

@@ -886,8 +886,8 @@ NSString* kDevViewSourceKey = @"DevViewSource";
     case ItemTypePasswords:
       base::RecordAction(
           base::UserMetricsAction("Options_ShowPasswordManager"));
-      controller = [[PasswordsTableViewController alloc]
-          initWithBrowserState:_browserState];
+      controller =
+          [[PasswordsTableViewController alloc] initWithBrowser:_browser];
       break;
     case ItemTypeAutofillCreditCard:
       base::RecordAction(base::UserMetricsAction("AutofillCreditCardsViewed"));