Refactor payments test sources into their own build rules.

This keeps the payments specific dependencies clear and
avoids adding bloat to the already very large chrome/test/BUILD.gn.

Change-Id: I2242d5faec3166fe66b47909efaf6f4965846f42
Reviewed-on: https://chromium-review.googlesource.com/c/chromium/src/+/2086684
Commit-Queue: Danyao Wang <danyao@chromium.org>
Reviewed-by: Sahel Sharify <sahel@chromium.org>
Reviewed-by: John Budorick <jbudorick@chromium.org>
Cr-Commit-Position: refs/heads/master@{#748238}

chrome/browser/payments/BUILD.gn

+# Copyright 2020 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+source_set("browsertests") {
+  testonly = true
+
+  sources = [
+    "empty_parameters_browsertest.cc",
+    "has_enrolled_instrument_browsertest.cc",
+    "has_enrolled_instrument_query_quota_browsertest.cc",
+    "journey_logger_browsertest.cc",
+    "payment_handler_change_shipping_address_option_browsertest.cc",
+    "payment_handler_enable_delegations_browsertest.cc",
+    "payment_handler_exploit_browsertest.cc",
+    "payment_handler_just_in_time_installation_browsertest.cc",
+    "payment_request_can_make_payment_browsertest.cc",
+    "payment_request_can_make_payment_event_browsertest.cc",
+    "sec_fetch_site_browsertest.cc",
+  ]
+
+  defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
+
+  deps = [
+    "//base/test:test_support",
+    "//chrome/test:test_support",
+    "//chrome/test/payments:test_support",
+    "//components/payments/content",
+    "//components/payments/core:test_support",
+    "//components/ukm:test_support",
+  ]
+
+  if (is_android) {
+    sources += [
+      "expandable_payment_handler_browsertest.cc",
+      "hybrid_request_skip_ui_browsertest.cc",
+    ]
+  }
+
+  if (!is_android) {
+    sources += [
+      "manifest_verifier_browsertest.cc",
+      "payment_manifest_parser_browsertest.cc",
+      "service_worker_payment_app_finder_browsertest.cc",
+      "site_per_process_payments_browsertest.cc",
+    ]
+
+    deps += [
+      "//chrome/test:test_support_ui",
+      "//components/payments/content:utils",
+      "//components/payments/content/utility",
+      "//components/permissions:permissions",
+    ]
+  }
+}
+
+source_set("unittests") {
+  testonly = true
+
+  sources = [ "payment_handler_permission_context_unittest.cc" ]
+
+  deps = [
+    "//chrome/test:test_support",
+    "//components/content_settings/core/test:test_support",
+    "//components/permissions:permissions",
+  ]
+
+  if (is_android) {
+    sources += [
+      "android/android_payment_app_finder_unittest.cc",
+      "android/payment_manifest_verifier_unittest.cc",
+    ]
+
+    deps += [ "//chrome/android:native_j_unittests_jni_headers" ]
+  }
+}

chrome/browser/payments/has_enrolled_instrument_browsertest.cc

@@ -7,8 +7,8 @@
 #include "base/test/metrics/histogram_tester.h"
 #include "base/test/scoped_feature_list.h"
 #include "build/build_config.h"
-#include "chrome/browser/payments/personal_data_manager_test_util.h"
 #include "chrome/test/payments/payment_request_platform_browsertest_base.h"
+#include "chrome/test/payments/personal_data_manager_test_util.h"
 #include "components/payments/core/features.h"
 #include "components/payments/core/journey_logger.h"
 #include "testing/gtest/include/gtest/gtest.h"

chrome/browser/payments/payment_request_can_make_payment_browsertest.cc

@@ -10,10 +10,10 @@
 #include "base/strings/utf_string_conversions.h"
 #include "base/test/scoped_feature_list.h"
 #include "chrome/browser/autofill/personal_data_manager_factory.h"
-#include "chrome/browser/payments/personal_data_manager_test_util.h"
 #include "chrome/browser/profiles/profile.h"
 #include "chrome/test/base/chrome_test_utils.h"
 #include "chrome/test/payments/payment_request_platform_browsertest_base.h"
+#include "chrome/test/payments/personal_data_manager_test_util.h"
 #include "components/autofill/core/browser/autofill_test_utils.h"
 #include "components/autofill/core/browser/data_model/credit_card.h"
 #include "components/autofill/core/browser/personal_data_manager.h"

chrome/test/BUILD.gn

@@ -154,10 +154,6 @@ static_library("test_support") {
     "logging/win/mof_data_parser.h",
     "logging/win/test_log_collector.cc",
     "logging/win/test_log_collector.h",
-    "payments/payment_request_platform_browsertest_base.h",
-    "payments/payment_request_test_controller.h",
-    "payments/test_event_waiter.cc",
-    "payments/test_event_waiter.h",
   ]
 
   configs += [ "//build/config:precompiled_headers" ]
@@ -239,12 +235,6 @@ static_library("test_support") {
   ]
 
   if (is_android) {
-    sources += [
-      "payments/android/payment_request_test_bridge.cc",
-      "payments/android/payment_request_test_bridge.h",
-      "payments/payment_request_test_controller_android.cc",
-    ]
-    deps += [ ":test_support_jni_headers" ]
     if (enable_vr) {
       public_deps += [ "//chrome/browser/android/vr:test_support" ]
 
@@ -266,7 +256,6 @@ static_library("test_support") {
       "base/dialog_test_browser_window.h",
       "base/test_browser_window.cc",
       "base/test_browser_window.h",
-      "payments/payment_request_test_controller_desktop.cc",
       "pixel/browser_skia_gold_pixel_diff.cc",
       "pixel/browser_skia_gold_pixel_diff.h",
     ]
@@ -515,6 +504,7 @@ if (is_android) {
       "//chrome:chrome_android_core",
       "//chrome/android:app_hooks_java",
       "//chrome/browser/metrics:test_support",
+      "//chrome/browser/payments:browsertests",
       "//chrome/browser/profiling_host:profiling_browsertests",
       "//components/crash/android:crashpad_main",
       "//components/games/core/test:test_support",
@@ -536,26 +526,10 @@ if (is_android) {
       "../browser/engagement/important_sites_util_browsertest.cc",
       "../browser/games/games_service_browsertest.cc",
       "../browser/metrics/metrics_service_user_demographics_browsertest.cc",
-      "../browser/payments/empty_parameters_browsertest.cc",
-      "../browser/payments/expandable_payment_handler_browsertest.cc",
-      "../browser/payments/has_enrolled_instrument_browsertest.cc",
-      "../browser/payments/has_enrolled_instrument_query_quota_browsertest.cc",
-      "../browser/payments/hybrid_request_skip_ui_browsertest.cc",
-      "../browser/payments/journey_logger_browsertest.cc",
-      "../browser/payments/payment_handler_change_shipping_address_option_browsertest.cc",
-      "../browser/payments/payment_handler_enable_delegations_browsertest.cc",
-      "../browser/payments/payment_handler_exploit_browsertest.cc",
-      "../browser/payments/payment_handler_just_in_time_installation_browsertest.cc",
-      "../browser/payments/payment_request_can_make_payment_browsertest.cc",
-      "../browser/payments/payment_request_can_make_payment_event_browsertest.cc",
-      "../browser/payments/personal_data_manager_test_util.cc",
-      "../browser/payments/personal_data_manager_test_util.h",
-      "../browser/payments/sec_fetch_site_browsertest.cc",
       "../browser/profiles/profile_browsertest_android.cc",
       "../browser/ssl/crlset_browsertest.cc",
       "android/browsertests_apk/android_browsertests_jni_onload.cc",
       "base/android/android_browser_test_browsertest_android.cc",
-      "payments/payment_request_platform_browsertest_base.cc",
     ]
 
     data = [
@@ -692,6 +666,7 @@ if (!is_android) {
       "//chrome/browser/image_decoder:browser_tests",
       "//chrome/browser/metrics:test_support",
       "//chrome/browser/notifications/scheduler/test:test_support",
+      "//chrome/browser/payments:browsertests",
       "//chrome/browser/profiling_host:profiling_browsertests",
       "//chrome/browser/web_applications:browser_tests",
       "//chrome/renderer",
@@ -1936,23 +1911,6 @@ if (!is_android) {
     }
     if (toolkit_views) {
       sources += [
-        "../browser/payments/empty_parameters_browsertest.cc",
-        "../browser/payments/has_enrolled_instrument_browsertest.cc",
-        "../browser/payments/has_enrolled_instrument_query_quota_browsertest.cc",
-        "../browser/payments/journey_logger_browsertest.cc",
-        "../browser/payments/manifest_verifier_browsertest.cc",
-        "../browser/payments/payment_handler_change_shipping_address_option_browsertest.cc",
-        "../browser/payments/payment_handler_enable_delegations_browsertest.cc",
-        "../browser/payments/payment_handler_exploit_browsertest.cc",
-        "../browser/payments/payment_handler_just_in_time_installation_browsertest.cc",
-        "../browser/payments/payment_manifest_parser_browsertest.cc",
-        "../browser/payments/payment_request_can_make_payment_browsertest.cc",
-        "../browser/payments/payment_request_can_make_payment_event_browsertest.cc",
-        "../browser/payments/personal_data_manager_test_util.cc",
-        "../browser/payments/personal_data_manager_test_util.h",
-        "../browser/payments/sec_fetch_site_browsertest.cc",
-        "../browser/payments/service_worker_payment_app_finder_browsertest.cc",
-        "../browser/payments/site_per_process_payments_browsertest.cc",
         "../browser/ui/global_error/global_error_browsertest.cc",
         "../browser/ui/global_error/global_error_service_browsertest.cc",
         "../browser/ui/media_router/presentation_receiver_window_controller_browsertest.cc",
@@ -2061,7 +2019,6 @@ if (!is_android) {
         "../browser/ui/views/translate/translate_bubble_view_browsertest.cc",
         "../browser/ui/views/translate/translate_language_browsertest.cc",
         "../browser/ui/views/web_apps/web_app_uninstall_dialog_browsertest.cc",
-        "payments/payment_request_platform_browsertest_base.cc",
       ]
       if (!is_chromeos) {
         sources += [
@@ -3302,7 +3259,6 @@ test("unit_tests") {
     "../browser/page_load_metrics/observers/ukm_page_load_metrics_observer_unittest.cc",
     "../browser/password_manager/chrome_password_manager_client_unittest.cc",
     "../browser/password_manager/password_store_x_unittest.cc",
-    "../browser/payments/payment_handler_permission_context_unittest.cc",
     "../browser/performance_hints/performance_hints_observer_unittest.cc",
     "../browser/performance_manager/decorators/frame_priority_decorator_unittest.cc",
     "../browser/performance_manager/decorators/frozen_frame_aggregator_unittest.cc",
@@ -3703,6 +3659,7 @@ test("unit_tests") {
     "//chrome/browser/media/router:unittests",
     "//chrome/browser/notifications:unit_tests",
     "//chrome/browser/paint_preview/services:unit_tests",
+    "//chrome/browser/payments:unittests",
     "//chrome/browser/updates/announcement_notification:unit_tests",
     "//chrome/common:test_support",
     "//chrome/common/media_router:test_support",
@@ -3877,8 +3834,6 @@ test("unit_tests") {
       "../browser/password_manager/password_generation_controller_impl_unittest.cc",
       "../browser/password_manager/save_password_infobar_delegate_android_unittest.cc",
       "../browser/password_manager/update_password_infobar_delegate_android_unittest.cc",
-      "../browser/payments/android/android_payment_app_finder_unittest.cc",
-      "../browser/payments/android/payment_manifest_verifier_unittest.cc",
       "../browser/permissions/permission_prompt_android_unittest.cc",
       "../browser/tabmodel/tab_persistent_store_unittest.cc",
       "../browser/toolbar/toolbar_security_icon_unittest.cc",

chrome/test/payments/BUILD.gn

+# Copyright 2020 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+static_library("test_support") {
+  testonly = true
+
+  sources = [
+    "payment_request_platform_browsertest_base.cc",
+    "payment_request_platform_browsertest_base.h",
+    "payment_request_test_controller.h",
+    "personal_data_manager_test_util.cc",
+    "personal_data_manager_test_util.h",
+    "test_event_waiter.cc",
+    "test_event_waiter.h",
+  ]
+
+  deps = [
+    "//chrome/browser",
+    "//chrome/test:test_support",
+    "//components/autofill/core/browser:test_support",
+    "//components/payments/content",
+    "//components/payments/content:utils",
+    "//content/test:test_support",
+    "//net:test_support",
+  ]
+
+  if (is_android) {
+    sources += [
+      "android/payment_request_test_bridge.cc",
+      "android/payment_request_test_bridge.h",
+      "payment_request_test_controller_android.cc",
+    ]
+
+    deps += [
+      "//chrome/test:test_support_jni_headers",
+      "//chrome/test:test_support_ui_android",
+    ]
+  }
+
+  if (!is_android) {
+    sources += [ "payment_request_test_controller_desktop.cc" ]
+
+    deps += [ "//chrome/test:test_support_ui" ]
+  }
+}

chrome/test/payments/payment_request_platform_browsertest_base.h

@@ -15,8 +15,8 @@
 #include "base/run_loop.h"
 #include "base/strings/string16.h"
 #include "build/build_config.h"
-#include "chrome/browser/payments/personal_data_manager_test_util.h"
 #include "chrome/test/payments/payment_request_test_controller.h"
+#include "chrome/test/payments/personal_data_manager_test_util.h"
 #include "chrome/test/payments/test_event_waiter.h"
 #include "components/autofill/core/browser/autofill_test_utils.h"
 #include "content/public/browser/web_contents.h"

chrome/browser/payments/personal_data_manager_test_util.cc → chrome/test/payments/personal_data_manager_test_util.cc

@@ -2,8 +2,9 @@
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
-#include "chrome/browser/payments/personal_data_manager_test_util.h"
+#include "chrome/test/payments/personal_data_manager_test_util.h"
 
+#include "base/run_loop.h"
 #include "base/strings/utf_string_conversions.h"
 #include "chrome/browser/autofill/personal_data_manager_factory.h"
 #include "chrome/browser/profiles/profile.h"
@@ -12,7 +13,7 @@
 #include "components/autofill/core/browser/data_model/credit_card.h"
 #include "components/autofill/core/browser/personal_data_manager.h"
 #include "components/autofill/core/browser/personal_data_manager_observer.h"
-#include "content/public/test/browser_test_utils.h"
+#include "testing/gtest/include/gtest/gtest.h"
 
 namespace payments {
 namespace test {

chrome/browser/payments/personal_data_manager_test_util.h → chrome/test/payments/personal_data_manager_test_util.h

@@ -2,8 +2,8 @@
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
-#ifndef CHROME_BROWSER_PAYMENTS_PERSONAL_DATA_MANAGER_TEST_UTIL_H_
-#define CHROME_BROWSER_PAYMENTS_PERSONAL_DATA_MANAGER_TEST_UTIL_H_
+#ifndef CHROME_TEST_PAYMENTS_PERSONAL_DATA_MANAGER_TEST_UTIL_H_
+#define CHROME_TEST_PAYMENTS_PERSONAL_DATA_MANAGER_TEST_UTIL_H_
 
 namespace autofill {
 class AutofillProfile;
@@ -30,4 +30,4 @@ void AddCreditCard(content::BrowserContext* browser_context,
 }  // namespace test
 }  // namespace payments
 
-#endif  // CHROME_BROWSER_PAYMENTS_PERSONAL_DATA_MANAGER_TEST_UTIL_H_
+#endif  // CHROME_TEST_PAYMENTS_PERSONAL_DATA_MANAGER_TEST_UTIL_H_